gentoo auto-resync : 07:08:2024 - 12:37:20

3 files changed, 164 insertions, 10 deletions

diff --git a/x11-misc/sddm/Manifest b/x11-misc/sddm/Manifest
index 1198cd736ddb..7c33b68be215 100644
--- a/x11-misc/sddm/Manifest
+++ b/x11-misc/sddm/Manifest
@@ -5,8 +5,9 @@ DIST sddm-0.18.1-patchset.tar.xz 7860 BLAKE2B b79738c58f19ebac24dd790ba7613d85ae
 DIST sddm-0.18.1.tar.xz 3402972 BLAKE2B 99ab43d374e9a3d318f692a6d496d8a6d68927af3c8e8fc2208d7355ec90649a14758b39f5733dd32f942ed569de88085576d4f5f8666f4f97079e0fb6dcb99e SHA512 ff0637600cda2f4da1f643f047f8ee822bd9651ae4ccbb614b9804175c97360ada7af93e07a7b63832f014ef6e7d1b5380ab2b8959f8024ea520fa5ff17efd60
 DIST sddm-0.21.0-pam.tar.xz 676 BLAKE2B 06a79f74a5833eca9877df4be8639311382d13061b21aa3627e6c4b07725878ded62221fca943440bacc143f6be2a23b2e0a2124012ff2c9fac82e1eded11144 SHA512 6d91eef2434346f7707122454522cf19f104994ac95d562417f6060a92b4e6c9792bebcccabac8290479200b4ba02fc4d92c6098c435c7ceda796d619d8913c2
 DIST sddm-0.21.0.tar.gz 3557266 BLAKE2B 849cb8b06b9510e5366ea28ef322c242db7d5a77d94c0a5a727f468209880a717055ad8b0c2f5a857852202a4d6bc1f68281fe0e0ab3c6a32327b5a4219af3a0 SHA512 2e8e460e7f318f20a406dcbb1a9fa1dc78b6a5b8d888bfbbaae22b9c642dbc49cf2ac682b4ea9ed847bbafa9bdc361ba08795e59cad970088b370caaaa70f458
-DIST sddm-0.21.0_p20240302.tar.gz 3555893 BLAKE2B 2c0d6b5185088750f3e656f593b1f9cd212e76d250c6285e03c8d86fad99412dce4a784dd8dfdd8cf7759552101ce36971b6c292f8ce51e9aecc3e9a1a785daa SHA512 0e0a143ec2007b09c406773ff81a5d722b9a7fadd0c5c6c8ef23d67623c16f8327cf54617dcc273b0b690ca5447b6707ff1dd48a8a563a6efed8d9aac70bd522
+DIST sddm-0.21.0_p20240723.tar.gz 3557578 BLAKE2B b92feb20a39eaf34822b077fcb8b89a100ff65814f9b523b2a1a0ffd3592edf2e86fa8fbdfcd8b592756a0b4baf0b085e8c7b4ad2aaa2f08b90e25e580df9925 SHA512 1ea2f758099f86086aebf05a77b176227475c1eb9c21c77bc99b9bb5a2882ce087e020ae6a11585b793fe09a3567e0ea4d0c1632a5823b7be83e33882964de48
 EBUILD sddm-0.18.1-r8.ebuild 4014 BLAKE2B 9905d591d59827c1097c9cafa56f399d1f9099fa7a69fb3c9966d797355d2c03ed647d69e9309c369a820cfc15345e2cb4d98596507c4c1b9ffaf4c45101938b SHA512 2015d988c8b12066e7ee9e410b151a5677a8ea2663840ae04162db132ceca79f7699026bd2d8ac198996ece2499d8fb4071af0e708900525104b3c294adb5379
 EBUILD sddm-0.21.0.ebuild 4035 BLAKE2B d3259f31587e7226764e3ac25bd2f1ebd5f8a96ae497a5c12c202a06cc4be8acec675e083bd7409d0743b709c1d09d5834c7d9273b9e6ae2fa721c0b1117888b SHA512 ef4eedf18db0cd96927e93b9f56281798a933b9588f97c71c4fa149a59bd99a40df4afbeeffa1e8836cbb0ccfcab43980e92453afee0d49d197f093b651a6c67
-EBUILD sddm-0.21.0_p20240302.ebuild 3975 BLAKE2B d3950de6724ff910ec834aab889a46bd015c68993b9642b763c6e934e52cc19dc019172d3a13d9ceb0a64ef8c1f31a9d57e5199d2fd7787e694750ffffa0b1ee SHA512 d7adca51a6a89773c6923caf37b1bcb1afc99f3f4d840ce320130fe22229fcd9f97df696db6bbea1bd113b59516fd0dfa455b9cf984091aaece2b936a332b0f5
+EBUILD sddm-0.21.0_p20240723-r10.ebuild 3903 BLAKE2B bf64698b9511ccd01ccc611aff856a978f94073b73b39cfd583e0ef7eeb7b0d18a0fcc238d734bb87c833405c56ab56fb736f03e792da685c961ea8e392e9f2d SHA512 fe271a5a01b4e2fcbfc186c08b4c95d00fc7fc3339ace23893346327ee5f0d30a4c9223ddf37b217166a1099943dc715a327a8806ceae6a96bb02e8f02b6a9bb
+EBUILD sddm-0.21.0_p20240723.ebuild 4102 BLAKE2B 77014de4ecc7b89990f130ba371a34c13d15335e253cd9551cbe58fbfacf8fd396b7270272d3121866fc8e6139a7bf0c89666f76cd846ba2fccfa9a28163839d SHA512 588dd8a4bd72aed8ef0e917331e4e681ba122a20047785537f3e68fb11412edf9717b9ea6bb09df2896bbb7412d8dd4a290195903b2c092178519ecfd4e0f02f
 MISC metadata.xml 722 BLAKE2B fc34c0b25b7f3e6ab876c99a30f475dc90cc4b319f497a2ba4bd2beac1dc1189d3d9611999c0c3b078254db23c4c9b2ef0416da41e706c1a1db96d5bbec28177 SHA512 c1fa48632080e295272df6e7ceb7c0a1ad64a41155c7d53d91728f072cb7abf618e7bf4d5cced2ca0b198bbbf5ed1e72c5bfc9ea9d590064e5f5494747d32b0d
diff --git a/x11-misc/sddm/sddm-0.21.0_p20240302.ebuild b/x11-misc/sddm/sddm-0.21.0_p20240723-r10.ebuild
index 744f832c4ac8..33c2a0b2a519 100644
--- a/x11-misc/sddm/sddm-0.21.0_p20240302.ebuild
+++ b/x11-misc/sddm/sddm-0.21.0_p20240723-r10.ebuild
@@ -8,13 +8,13 @@ if [[ ${PV} == *9999* ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
 else
-	COMMIT=ae072f901671b68861da9577e3e12e350a9053d5
+	COMMIT=4ec29a8bba033d475f197693fac6cb0c383a1da2
 	SRC_URI="https://github.com/${PN}/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
 	S="${WORKDIR}/${PN}-${COMMIT}"
-	KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
 fi
 
-QTMIN=6.7.1
+QTMIN=6.7.2
 inherit cmake linux-info optfeature pam systemd tmpfiles
 
 DESCRIPTION="Simple Desktop Display Manager"
@@ -28,7 +28,7 @@ IUSE="+elogind systemd test +X"
 REQUIRED_USE="^^ ( elogind systemd )"
 RESTRICT="!test? ( test )"
 
-COMMON_DEPEND="
+DEPEND="
 	acct-group/sddm
 	acct-user/sddm
 	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network]
@@ -42,10 +42,7 @@ COMMON_DEPEND="
 	)
 	systemd? ( sys-apps/systemd:=[pam] )
 "
-DEPEND="${COMMON_DEPEND}
-	test? ( >=dev-qt/qtbase-${QTMIN}:6 )
-"
-RDEPEND="${COMMON_DEPEND}
+RDEPEND="${DEPEND}
 	X? ( x11-base/xorg-server )
 	!systemd? ( gui-libs/display-manager-init )
 "
diff --git a/x11-misc/sddm/sddm-0.21.0_p20240723.ebuild b/x11-misc/sddm/sddm-0.21.0_p20240723.ebuild
new file mode 100644
index 000000000000..65b6f5a1fd1a
--- /dev/null
+++ b/x11-misc/sddm/sddm-0.21.0_p20240723.ebuild
@@ -0,0 +1,156 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PAM_TAR="${PN}-0.21.0-pam"
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	COMMIT=4ec29a8bba033d475f197693fac6cb0c383a1da2
+	SRC_URI="https://github.com/${PN}/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${COMMIT}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+QTMIN=5.15.12
+inherit cmake linux-info optfeature pam systemd tmpfiles
+
+DESCRIPTION="Simple Desktop Display Manager"
+HOMEPAGE="https://github.com/sddm/sddm"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${PAM_TAR}.tar.xz"
+
+LICENSE="GPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0 public-domain"
+SLOT="0"
+IUSE="+elogind systemd test"
+
+REQUIRED_USE="^^ ( elogind systemd )"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	acct-group/sddm
+	acct-user/sddm
+	>=dev-qt/qtcore-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	sys-libs/pam
+	x11-libs/libXau
+	x11-libs/libxcb:=
+	elogind? (
+		sys-auth/elogind[pam]
+		sys-power/upower
+	)
+	systemd? ( sys-apps/systemd:=[pam] )
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( >=dev-qt/qttest-${QTMIN}:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	x11-base/xorg-server
+	!systemd? ( gui-libs/display-manager-init )
+"
+BDEPEND="
+	dev-python/docutils
+	>=dev-build/cmake-3.25.0
+	>=dev-qt/linguist-tools-${QTMIN}:5
+	kde-frameworks/extra-cmake-modules:0
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Downstream patches
+	"${FILESDIR}/${PN}-0.20.0-respect-user-flags.patch"
+	"${FILESDIR}/${PN}-0.21.0-Xsession.patch" # bug 611210
+)
+
+pkg_setup() {
+	local CONFIG_CHECK="~DRM"
+	use kernel_linux && linux-info_pkg_setup
+}
+
+src_unpack() {
+	[[ ${PV} == *9999* ]] && git-r3_src_unpack
+	default
+}
+
+src_prepare() {
+	touch 01gentoo.conf || die
+
+cat <<-EOF >> 01gentoo.conf
+[General]
+# Remove qtvirtualkeyboard as InputMethod default
+InputMethod=
+EOF
+
+	cmake_src_prepare
+
+	if ! use test; then
+		sed -e "/^find_package/s/ Test//" -i CMakeLists.txt || die
+		cmake_comment_add_subdirectory test
+	fi
+
+	if use systemd; then
+		sed -e "/pam_elogind.so/s/elogind/systemd/" \
+			-i "${WORKDIR}"/${PAM_TAR}/${PN}-greeter.pam || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_MAN_PAGES=ON
+		-DBUILD_WITH_QT6=OFF # default theme (and others) not yet compatible
+		-DDBUS_CONFIG_FILENAME="org.freedesktop.sddm.conf"
+		-DRUNTIME_DIR=/run/sddm
+		-DSYSTEMD_TMPFILES_DIR="/usr/lib/tmpfiles.d"
+		-DNO_SYSTEMD=$(usex !systemd)
+		-DUSE_ELOGIND=$(usex elogind)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	insinto /etc/sddm.conf.d/
+	doins "${S}"/01gentoo.conf
+
+	# with systemd logs are sent to journald, so no point to bother in that case
+	if ! use systemd; then
+		insinto /etc/logrotate.d
+		newins "${FILESDIR}/sddm.logrotate" sddm
+	fi
+
+	newpamd "${WORKDIR}"/${PAM_TAR}/${PN}.pam ${PN}
+	newpamd "${WORKDIR}"/${PAM_TAR}/${PN}-autologin.pam ${PN}-autologin
+	newpamd "${WORKDIR}"/${PAM_TAR}/${PN}-greeter.pam ${PN}-greeter
+}
+
+pkg_postinst() {
+	tmpfiles_process "${PN}.conf"
+
+	elog "NOTE: If SDDM startup appears to hang then entropy pool is too low."
+	elog "This can be fixed by configuring one of the following:"
+	elog "  - Enable CONFIG_RANDOM_TRUST_CPU in linux kernel"
+	elog "  - # emerge sys-apps/haveged && rc-update add haveged boot"
+	elog "  - # emerge sys-apps/rng-tools && rc-update add rngd boot"
+	elog
+	elog "SDDM example config can be shown with:"
+	elog "  ${EROOT}/usr/bin/sddm --example-config"
+	elog "Use ${EROOT}/etc/sddm.conf.d/ directory to override specific options."
+	elog
+	elog "For more information on how to configure SDDM, please visit the wiki:"
+	elog "  https://wiki.gentoo.org/wiki/SDDM"
+	if has_version x11-drivers/nvidia-drivers; then
+		elog
+		elog "  Nvidia GPU owners in particular should pay attention"
+		elog "  to the troubleshooting section."
+	fi
+
+	optfeature "Weston DisplayServer support (EXPERIMENTAL)" "dev-libs/weston[kiosk]"
+	optfeature "KWin DisplayServer support (EXPERIMENTAL)" "kde-plasma/kwin"
+
+	systemd_reenable sddm.service
+}