gentoo resync : 16.09.2020

1 files changed, 54 insertions, 0 deletions

diff --git a/x11-misc/xautolock/xautolock-2.2_p7.ebuild b/x11-misc/xautolock/xautolock-2.2_p7.ebuild
new file mode 100644
index 000000000000..1abba4868157
--- /dev/null
+++ b/x11-misc/xautolock/xautolock-2.2_p7.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs
+
+DESCRIPTION="An automatic X screen-locker/screen-saver"
+HOMEPAGE="http://www.ibiblio.org/pub/Linux/X11/screensavers/"
+
+DEB_REVISION="$(ver_cut 4)"
+SRC_URI="
+	http://www.ibiblio.org/pub/Linux/X11/screensavers/${P/_p*/}.tgz
+	mirror://debian/pool/main/x/${PN}/${PN}_${PV/_p*/}-${DEB_REVISION}.debian.tar.xz
+"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~sparc ~x86"
+
+RDEPEND="
+	x11-libs/libXScrnSaver
+"
+DEPEND="
+	${RDEPEND}
+	app-text/rman
+	x11-base/xorg-proto
+	x11-misc/imake
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.2_p5_p1-waitpid.patch
+)
+S=${WORKDIR}/${P/_p*}
+
+src_prepare() {
+	mv "${WORKDIR}"/debian/patches/14-do-not-use-union-wait-type.patch{,.skip} || die
+	eapply "${WORKDIR}"/debian/patches/*.patch
+	default
+}
+
+src_configure() {
+	xmkmf || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CDEBUGFLAGS="${CFLAGS}" \
+		EXTRA_LDOPTIONS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin xautolock
+	newman xautolock.man xautolock.1
+	dodoc Changelog Readme Todo
+}