gentoo auto-resync : 18:07:2023 - 00:58:24

3 files changed, 151 insertions, 2 deletions

diff --git a/x11-wm/herbstluftwm/Manifest b/x11-wm/herbstluftwm/Manifest
index 13c3154e20e2..4b5cc4733ef3 100644
--- a/x11-wm/herbstluftwm/Manifest
+++ b/x11-wm/herbstluftwm/Manifest
@@ -1,4 +1,5 @@
 DIST herbstluftwm-0.9.5.tar.gz 556773 BLAKE2B db851f02ce249be74f0104dd0b335fb1ed50b4a19e5f7de17cdc34b7eba99ac2f348c5a4a4e0afd2c68576f650029203c735ccb293a60d321769d56f746d6593 SHA512 a85fd1ab16b873f512d6965cc4a93524e3ed4a15079d0d4ee54012e217bd41db3b54729c1b30ee361c34b38799f95bc537099056ba7a5f791bf2be6724bc92c3
 EBUILD herbstluftwm-0.9.5-r1.ebuild 3242 BLAKE2B d28d4dd3aabea977348879cef55e1c6dce4424fa495c9b1e9f0d45fb03416c15944d03c0eee0dd160c548fe8d4e7382b68b41569a996b11d7f80a94451639f52 SHA512 d209b8184de9f9bb93fd2f23cddc0f51ec2f69bdcc398e3d5f4d792205f382bca39e0395c02cbcc7105753d1b5ea5cb4a84a3141fcf24deada3f4bbf6e18b367
-EBUILD herbstluftwm-9999.ebuild 3406 BLAKE2B 8fbd649e820dfc4aeef6dcf270f8465760acb4d4155e6b3a783a4e6e09e154a02383478cdda776224dc1420d7f45d8365e0614f53315bf05a90e3baeecac2250 SHA512 a0f3e12ac7c1535c0092ab40f36faa42038355f15d3f8651acb182b86118d8efb8935594a31c75cfa350781de63a158d194bedf910721b9e85bdd098138b4613
+EBUILD herbstluftwm-0.9.5-r2.ebuild 3279 BLAKE2B 82a7098f308a24139a63f8efae652643e1374cf29dbb667441eb1a5b53f3714293b3851adceeae6365239336267dfc4a435adb3d91aed01e4253082990dbadc5 SHA512 945c3361cf014c8000ef90f3e1ed2aeb7e1ed16e11632be8598a411ad75046fe25c5d7ff44c5858b3e4d3cb335514e72f7fad07a85f90408917b9e81ae92a456
+EBUILD herbstluftwm-9999.ebuild 3441 BLAKE2B 7d3d428d9d58ec30c1fd4fc978849b2e61c06dcc4e4a92a17a718ae8271e44f9be261596189231bc35979f190d0cc0e5dcce660bb7c3f1d04bd0ead6847ce5f4 SHA512 eef931f1d2ecc3b84892c3605ef597e5fc4092b805c3326be003700cfccf4fac2d61fdcf32ba224eba2948d81b5f5d64044dfd293bbc16bea3e6406a7bf709be
 MISC metadata.xml 337 BLAKE2B 7ef28bc6ce30abb6c2f44524b4dd05a479cd5ca2b98901ffe570b870d0b98f94589cd1d3f197ee7e3fd90f4c73144e1dc44996df8b1b3ec28ce6950578ada74e SHA512 6e7cb80e1870901554ac0c2a4947cceb4e6284ccc84714bb0f42dbfa69cab5b32a8bd34fd384731b9462535d7e80feef606030be3e03babc80828a980050f333
diff --git a/x11-wm/herbstluftwm/herbstluftwm-0.9.5-r2.ebuild b/x11-wm/herbstluftwm/herbstluftwm-0.9.5-r2.ebuild
new file mode 100644
index 000000000000..31baa0f5fafc
--- /dev/null
+++ b/x11-wm/herbstluftwm/herbstluftwm-0.9.5-r2.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_OPTIONAL=1
+
+inherit cmake desktop distutils-r1
+
+DESCRIPTION="A manual tiling window manager for X"
+HOMEPAGE="https://herbstluftwm.org/"
+
+if [[ "${PV}" == "9999" ]] || [[ -n "${EGIT_COMMIT_ID}" ]]; then
+	EGIT_REPO_URI="https://github.com/herbstluftwm/herbstluftwm"
+	inherit git-r3
+else
+	SRC_URI="https://herbstluftwm.org/tarballs/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="+doc python test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXft
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libXrender
+"
+DEPEND="
+	${COMMON_DEPEND}
+	test? (
+		dev-python/ewmh
+		dev-python/python-xlib
+		x11-apps/xsetroot
+		x11-base/xorg-server[xephyr,xvfb]
+		x11-misc/xdotool
+		x11-terms/xterm
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	app-shells/bash
+	python? ( ${PYTHON_DEPS} )
+"
+BDEPEND="
+	${DISTUTILS_DEPS}
+	virtual/pkgconfig
+"
+
+if [[ -n "${EGIT_REPO_URI}" ]]; then
+	# Herbstluftwm tarballs ship with pre-compiled documentation, only
+	# if we build from git asciidoc is needed.
+	BDEPEND+=" doc? ( app-text/asciidoc )"
+fi
+
+src_prepare() {
+	# Do not install LICENSE and respect CMAKE_INSTALL_DOCDIR.
+	sed -i \
+		-e '/^install.*LICENSEDIR/d' \
+		-e '/set(DOCDIR / s#.*#set(DOCDIR ${CMAKE_INSTALL_DOCDIR})#' \
+		CMakeLists.txt || die
+	cmake_src_prepare
+
+	if use python; then
+		pushd "${S}"/python > /dev/null || die
+		distutils-r1_src_prepare
+		popd > /dev/null || die
+	fi
+}
+
+src_configure() {
+	# Ensure that 'python3' is in PATH. #765118
+	python_setup
+
+	local mycmakeargs=(
+		-DWITH_DOCUMENTATION=$(usex doc)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use python; then
+		pushd python > /dev/null || die
+		distutils-r1_src_compile
+		popd >/dev/null || die
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	if ! use doc; then
+		rm -r "${ED}"/usr/share/doc/${PF}/examples || die
+	fi
+
+	if use python; then
+		pushd python > /dev/null || die
+		distutils-r1_src_install
+		popd > /dev/null || die
+	fi
+
+	# The man pages exists in src_install either in non-live ebuilds,
+	# since they are then shipped pre-compiled in herbstluftwm's
+	# release tarbal. Or they exist in live ebuilds if the 'doc' USE
+	# flag is enabled.
+	if [[ "${PV}" != 9999 ]] || use doc; then
+		local man_pages=(
+			herbstluftwm.1
+			herbstclient.1
+			herbstluftwm-tutorial.7
+		)
+		for man_page in "${man_pages[@]}"; do
+			doman "doc/${man_page}"
+		done
+	fi
+
+	# Do not only install the herbstluftwm.desktop file in xsessions/ but
+	# also in applications/. This allows herbstluftwm to be used as
+	# window manager of a Gnome flashback session.
+	domenu "${ED}"/usr/share/xsessions/herbstluftwm.desktop
+}
+
+distutils_enable_tests pytest
+
+src_test() {
+	ln -s "${BUILD_DIR}/herbstclient" || die "Could not symlink herbstclient"
+	ln -s "${BUILD_DIR}/herbstluftwm" || die "Could not symlink herbstluftwm"
+
+	pushd python > /dev/null || die
+	distutils_install_for_testing
+	popd > /dev/null || die
+
+	# Ensure PYTHONPATH is exported, see https://bugs.gentoo.org/801658.
+	export PYTHONPATH
+	python_test
+}
diff --git a/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild b/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
index 051f9ba720c9..7c5b5aaecbda 100644
--- a/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
+++ b/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
@@ -4,6 +4,7 @@
 EAPI=8
 
 PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
 DISTUTILS_OPTIONAL=1
 
 inherit cmake distutils-r1
@@ -51,7 +52,7 @@ RDEPEND="
 	python? ( ${PYTHON_DEPS} )
 "
 BDEPEND="
-	${PYTHON_DEPS}
+	${DISTUTILS_DEPS}
 	virtual/pkgconfig
 "