reinit the tree, so we can have metadata

4 files changed, 132 insertions, 0 deletions

diff --git a/xfce-extra/xfce4-power-manager/Manifest b/xfce-extra/xfce4-power-manager/Manifest
new file mode 100644
index 000000000000..7cad2ca5ca13
--- /dev/null
+++ b/xfce-extra/xfce4-power-manager/Manifest
@@ -0,0 +1,6 @@
+DIST xfce4-power-manager-1.6.0.tar.bz2 1171114 SHA256 bde3157e06ab31ff23648d163d53ee5095f7819544a9f48d3a96d57829857f2b SHA512 1b3628793a8bfb7a487fc4f1182769b0d7a90784aa4ef7800997dd7e9a061d938493b8c5653672b293fb018dd5b5209bb83caa16310c1de370413f98d8af1053 WHIRLPOOL 74a8a9857f7a2b42035e4d409bb6ee00e8e29dd547076191ae4c757f213546195b98c76a9520c1903b1f59310d243556820f794967704f946dc6723837a93f0b
+EBUILD xfce4-power-manager-1.6.0-r1.ebuild 1473 SHA256 ebf8bda79d16014a328b1ccbc79a521d0eaa9af6faf3bba4e4f79866cf9e56b8 SHA512 4645fff22b1654c778ba5b5c23e858a9b4fd10ccefd3f00753606b3fbd386adffb17182791210774abc54151870c9823b9fca92d7fa73e36602bcce2cf1882af WHIRLPOOL a5739e1e8bca89c409acf75262bf80af4dee3cda5ae0b2460e623a740f9609188872daec5b453c07dfe65087fe367d2503c783e28e94a4cfecb0b5d4367f5448
+EBUILD xfce4-power-manager-1.6.0.ebuild 1347 SHA256 743f55f4f8dca6c3f8b95b096c54d2f45b379b453bfc27a32d4a197e267ab804 SHA512 bb8c9f8f13147d2b316bfec53b57d75d7f6a37447281df1a92a045b7090b73598085c28e48201a92ed8d2870b206c8e6a416cb50b0bc9bb0acd900a7d4d53d25 WHIRLPOOL f485eb7df0f0efd3761a4700249081b51cba1ebb360f7c6616edd8917a008d211034908dc867e37123febb0010e99bacdfe93669ead3aa5bbd098351f310c766
+MISC ChangeLog 3733 SHA256 c27ae29db1f97a6523b065511b8f98f10223c6ff803be795c0b2c28fa9e58f6c SHA512 a9b57cbd18fbdbfcd027b6d7949ad7081ff3e660d6679fa0deac55fd87913beb7ded9cc2cfffa41cd29cfeaf7cb9d68c5a8ad75f8feaf63b19e52b9b7d245453 WHIRLPOOL 2c730173aadd1d2398045b4e25847253e0711e6afff26a9b35864d4a8f8fe3816612b943187dcfeac7dfd2b36b565ffd120123c88d6e8aa620dde313c0ea9b8f
+MISC ChangeLog-2015 17136 SHA256 072b7bd7d3bd95b36abf67defcedf1f5c96f48d00899b3f8d9184792172d248b SHA512 7a5a917893fc48120ec85745e9a0f96c7073892c6c9d6104c1ec2f31942df287f58d6f488778922faae5a10cf16e99c457deeeb9cae5e49f1ba6a5f4f574ad9b WHIRLPOOL 749d872c3b41212115de42c325d1e832d1982379f750468604fa169296ee94a176a6d0422adb8596cdcbb18661afe14be0513cf32f82b34a5f8097e4f2533e6c
+MISC metadata.xml 360 SHA256 3481a0c86444ffef5b685ade0827f8580e321da211a88d14d04c0dda7f0da995 SHA512 bca73ff003a0d3845fc354775332c0edd0558ff5bcf27c562cc8c4f96e95210f197698d76b0ea898aa6ff4a12e5e22a589b62d28e196e679d4046e56f66ea744 WHIRLPOOL 42d4bea825fe4fdaa4982a39bb99c4d8fc92a6255b9cb3c6739bfbc867c13eb758a115d6124a15e7be06de51c05d2094f5b36f158d90995d68805be2ff9c91ee
diff --git a/xfce-extra/xfce4-power-manager/metadata.xml b/xfce-extra/xfce4-power-manager/metadata.xml
new file mode 100644
index 000000000000..468e985aae47
--- /dev/null
+++ b/xfce-extra/xfce4-power-manager/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>xfce@gentoo.org</email>
+    <name>XFCE Team</name>
+  </maintainer>
+  <use>
+    <flag name='panel-plugin'>Build the power management plugin for
+      the XFCE panel</flag>
+  </use>
+</pkgmetadata>
diff --git a/xfce-extra/xfce4-power-manager/xfce4-power-manager-1.6.0-r1.ebuild b/xfce-extra/xfce4-power-manager/xfce4-power-manager-1.6.0-r1.ebuild
new file mode 100644
index 000000000000..a082a0dc16f4
--- /dev/null
+++ b/xfce-extra/xfce4-power-manager/xfce4-power-manager-1.6.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2-utils
+
+DESCRIPTION="Power manager for the Xfce desktop environment"
+HOMEPAGE="https://goodies.xfce.org/projects/applications/xfce4-power-manager"
+SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="debug kernel_linux networkmanager +panel-plugin policykit systemd"
+
+COMMON_DEPEND=">=dev-libs/glib-2.42:=
+	>=sys-power/upower-0.99.0
+	sys-power/pm-utils
+	>=x11-libs/gtk+-3.14:3=
+	>=x11-libs/libnotify-0.7:=
+	x11-libs/libX11:=
+	x11-libs/libXScrnSaver:=
+	>=x11-libs/libXrandr-1.2:=
+	x11-libs/libXext:=
+	x11-libs/libXtst:=
+	>=xfce-base/xfconf-4.12:=
+	>=xfce-base/libxfce4ui-4.12:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.12:=
+	panel-plugin? ( >=xfce-base/xfce4-panel-4.12:= )
+	policykit? (
+		>=sys-auth/polkit-0.112
+		!systemd? ( sys-auth/consolekit )
+	)"
+RDEPEND="${COMMON_DEPEND}
+	networkmanager? ( net-misc/networkmanager )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	x11-proto/xproto"
+
+src_configure() {
+	local myconf=(
+		$(use_enable policykit polkit)
+		$(use_enable networkmanager network-manager)
+		$(use_enable panel-plugin xfce4panel)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/xfce-extra/xfce4-power-manager/xfce4-power-manager-1.6.0.ebuild b/xfce-extra/xfce4-power-manager/xfce4-power-manager-1.6.0.ebuild
new file mode 100644
index 000000000000..20e63050f19d
--- /dev/null
+++ b/xfce-extra/xfce4-power-manager/xfce4-power-manager-1.6.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="Power manager for the Xfce desktop environment"
+HOMEPAGE="https://goodies.xfce.org/projects/applications/xfce4-power-manager"
+SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm ppc ppc64 x86"
+IUSE="debug kernel_linux networkmanager policykit systemd +xfce_plugins_power"
+
+COMMON_DEPEND=">=dev-libs/glib-2.42:=
+	>=sys-power/upower-0.99.0
+	sys-power/pm-utils
+	>=x11-libs/gtk+-3.14:3=
+	>=x11-libs/libnotify-0.7
+	x11-libs/libX11:=
+	x11-libs/libXScrnSaver:=
+	>=x11-libs/libXrandr-1.2:=
+	x11-libs/libXext:=
+	x11-libs/libXtst:=
+	>=xfce-base/xfconf-4.12:=
+	>=xfce-base/libxfce4ui-4.12:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.12:=
+	policykit? (
+		>=sys-auth/polkit-0.112
+		!systemd? ( sys-auth/consolekit )
+		)
+	xfce_plugins_power? ( >=xfce-base/xfce4-panel-4.12:= )"
+RDEPEND="${COMMON_DEPEND}
+	networkmanager? ( net-misc/networkmanager )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	x11-proto/xproto"
+
+pkg_setup() {
+	XFCONF=(
+		$(use_enable policykit polkit)
+		$(use_enable networkmanager network-manager)
+		$(use_enable xfce_plugins_power xfce4panel)
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS NEWS README TODO )
+}