1 files changed, 61 insertions, 0 deletions
diff --git a/app-benchmarks/sysbench/sysbench-1.0.19.ebuild b/app-benchmarks/sysbench/sysbench-1.0.19.ebuild
new file mode 100644
index 000000000000..bad79a67a164
--- /dev/null
+++ b/app-benchmarks/sysbench/sysbench-1.0.19.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools pax-utils
+
+DESCRIPTION="System performance benchmark"
+HOMEPAGE="https://github.com/akopytov/sysbench"
+SRC_URI="https://github.com/akopytov/sysbench/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="aio mysql postgres test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="aio? ( dev-libs/libaio )
+	mysql? ( dev-db/mysql-connector-c:= )
+	postgres? ( dev-db/postgresql:= )
+	dev-lang/luajit:2"
+DEPEND="${RDEPEND}
+	dev-libs/concurrencykit
+	dev-libs/libxslt
+	test? ( dev-util/cram )"
+BDEPEND="sys-devel/libtool
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# remove bundled libs
+	rm -r third_party/luajit/luajit third_party/concurrency_kit/ck third_party/cram || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable aio)
+		$(use_with mysql)
+		$(use_with postgres pgsql)
+		--without-attachsql
+		--without-drizzle
+		--without-oracle
+		--with-system-luajit
+		--with-system-ck
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	emake check test
+}
+
+src_install() {
+	default
+
+	pax-mark m "${ED}"/usr/bin/${PN}
+}