1 files changed, 65 insertions, 0 deletions
diff --git a/app-crypt/acme/acme-2.11.1.ebuild b/app-crypt/acme/acme-2.11.1.ebuild
new file mode 100644
index 000000000000..e0b51cdd5244
--- /dev/null
+++ b/app-crypt/acme/acme-2.11.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+PARENT_PN="certbot"
+PARENT_P="${PARENT_PN}-${PV}"
+
+if [[ "${PV}" == *9999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/certbot/certbot.git"
+	EGIT_SUBMODULES=()
+	EGIT_CHECKOUT_DIR="${WORKDIR}/${PARENT_P}"
+else
+	SRC_URI="
+		https://github.com/certbot/certbot/archive/v${PV}.tar.gz
+			-> ${PARENT_P}.gh.tar.gz
+	"
+	KEYWORDS="amd64 arm arm64 ~ppc64 ~riscv x86"
+fi
+
+DESCRIPTION="An implementation of the ACME protocol"
+HOMEPAGE="
+	https://github.com/certbot/certbot
+	https://pypi.org/project/acme/
+	https://letsencrypt.org/
+"
+
+S="${WORKDIR}/${PARENT_P}/${PN}"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+BDEPEND="
+	test? (
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+# The requirement is really 17.5.0 but easier to require latest stable >= 23.1.1
+# to avoid broken 23.1.0.
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.2.1[${PYTHON_USEDEP}]
+	>=dev-python/josepy-1.13.0[${PYTHON_USEDEP}]
+	<dev-python/josepy-2[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-23.1.1[${PYTHON_USEDEP}]
+	dev-python/pyrfc3339[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2019.3[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.3.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}