1 files changed, 63 insertions, 0 deletions
diff --git a/app-editors/vis/vis-0.6.ebuild b/app-editors/vis/vis-0.6.ebuild
new file mode 100644
index 000000000000..7a2ce6eaaa69
--- /dev/null
+++ b/app-editors/vis/vis-0.6.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PTV=0.4
+
+DESCRIPTION="modern, legacy free, simple yet efficient vim-like editor"
+HOMEPAGE="https://github.com/martanne/vis"
+SRC_URI="https://github.com/martanne/vis/releases/download/v${PV}/${P}.tar.gz
+	test? ( https://github.com/martanne/vis-test/releases/download/v${MY_PTV}/vis-test-${MY_PTV}.tar.gz )"
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+ncurses selinux test tre"
+RESTRICT="!test? ( test )"
+
+# - Known to also work with NetBSD curses
+# - ::lua package done for using >=dev-lang/lua-5.2
+# which is needed for syntax highlighting and settings but masked in ::gentoo
+DEPEND="dev-libs/libtermkey
+	ncurses? ( sys-libs/ncurses:0= )
+	tre? ( dev-libs/tre:= )"
+RDEPEND="${DEPEND}
+	app-eselect/eselect-vi"
+
+src_prepare() {
+	if use test; then
+		rm -r test || die
+		mv "${WORKDIR}/vis-test-${MY_PTV}" test || die
+
+		# https://bugs.gentoo.org/722014 https://github.com/martanne/vis-test/pull/22
+		sed -i 's;./ccan-config > config.h;./ccan-config "${CC}" ${CFLAGS} > config.h;' test/core/Makefile || die
+	fi
+
+	sed -i 's|STRIP?=.*|STRIP=true|' Makefile || die
+	sed -i 's|${DOCPREFIX}/vis|${DOCPREFIX}|' Makefile || die
+	sed -i 's|DOCUMENTATION = LICENSE|DOCUMENTATION =|' Makefile || die
+
+	default
+}
+
+src_configure() {
+	./configure \
+		--prefix="${EPREFIX}"/usr \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable ncurses curses) \
+		$(use_enable selinux) \
+		$(use_enable tre) || die
+}
+
+update_symlinks() {
+	einfo "Calling eselect vi update --if-unset"
+	eselect vi update --if-unset
+}
+
+pkg_postrm() {
+	update_symlinks
+}
+
+pkg_postinst() {
+	update_symlinks
+}