summaryrefslogtreecommitdiff
path: root/app-emacs/emacs-common
diff options
context:
space:
mode:
Diffstat (limited to 'app-emacs/emacs-common')
-rw-r--r--app-emacs/emacs-common/Manifest5
-rw-r--r--app-emacs/emacs-common/emacs-common-1.6-r4.ebuild104
-rw-r--r--app-emacs/emacs-common/emacs-common-1.8.ebuild103
-rw-r--r--app-emacs/emacs-common/metadata.xml12
4 files changed, 224 insertions, 0 deletions
diff --git a/app-emacs/emacs-common/Manifest b/app-emacs/emacs-common/Manifest
new file mode 100644
index 000000000000..1b0cfe8864c7
--- /dev/null
+++ b/app-emacs/emacs-common/Manifest
@@ -0,0 +1,5 @@
+DIST emacs-common-1.8.tar.xz 61352 BLAKE2B 084cf06c03db231c92d0074a2e633d209257941b2840c2c745462050e694756f97679c7078357d9eab7b2fcfb85b00ab390d65254ddd106d0ef1a1fd723b2c4c SHA512 85c4b826c0691fd24f260750f4c3f9ecc3b59d11b4dafcae608e1a2546c064b240084974962b0727ac8183b8f5b0891cf47add901461f77ee275a129341b2b13
+DIST emacs-common-gentoo-1.6.tar.xz 61224 BLAKE2B 70e4f30c26c9098fdb02a53cab5d60cb611143d8bac6947707f3c7596b5a81ceb513b5a0809ee90f351472824f1d4216720c02cadb51d25b3dfce5e436e02bdf SHA512 a7daed2241d778ab283482ecc016801e25084eed10fcbbc50e187d5f842df5a0d278a77f94ae950b086c8651e8ca1a18f89c11dffdde9cf9168755288aae926a
+EBUILD emacs-common-1.6-r4.ebuild 2884 BLAKE2B e4a0abd806c807511afaf5442ef0f7f925f11a331197108b87760ff795cc9149ebc9be3f236f55a8127ee1400dfe373a2afefd71768f945882f807ba5b1edca2 SHA512 d7b30bdf7d642534605618b9f73677b4d1ecc9a5a970eafcf91c86f1e8819eb58356d5debfe93ad8dc25b660f89e7a17d4a81cc9a80d32e03eaff6e148a9eb70
+EBUILD emacs-common-1.8.ebuild 2895 BLAKE2B efad77e6d07629efd12b0ffade40c817fc22918b88c6787eede21a67b36a156b9656f598385af311925699e1a8c13901384ee15e1ebb261e269fba453cc62bf2 SHA512 047c1e3f21238458293f8c4f39908a1a586502424f0540a8d37b15961cc708303092bf8f51e66443535d74a355c14406f0bfa283fee730865767bb8af7eb6bdd
+MISC metadata.xml 360 BLAKE2B e7e420afb7a8377bffcf2a23f3954bbf4cc80fcd19a8514733e2e0164f4235271e21dc860bf77cb9cfcd1a4026ef3dafe97a10dc397e2d8e6f001f02bf6e9bc7 SHA512 d57f8f097617229f774b06437aaa83595aab2a6d9321d51b97dac8bd56fa94db396c7bdca538570f0912390e25ae8643c5adc374908757f67f1422fa1f872605
diff --git a/app-emacs/emacs-common/emacs-common-1.6-r4.ebuild b/app-emacs/emacs-common/emacs-common-1.6-r4.ebuild
new file mode 100644
index 000000000000..ebc8a1b9774e
--- /dev/null
+++ b/app-emacs/emacs-common/emacs-common-1.6-r4.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit elisp-common desktop xdg-utils readme.gentoo-r1
+
+MY_P="emacs-common-gentoo-${PV}"
+DESCRIPTION="Common files needed by all GNU Emacs versions"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+SRC_URI="https://dev.gentoo.org/~ulm/emacs/${MY_P}.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
+IUSE="games gui"
+
+RDEPEND="games? ( acct-group/gamestat )"
+DEPEND="${RDEPEND}"
+PDEPEND=">=app-editors/emacs-23.1:*"
+
+src_install() {
+ insinto "${SITELISP}"
+ doins subdirs.el
+ newins site-gentoo.el{,.orig}
+
+ keepdir /etc/emacs
+ insinto /etc/emacs
+ doins site-start.el
+
+ if use games; then
+ keepdir /var/games/emacs
+ fowners 0:gamestat /var/games/emacs
+ fperms g+w /var/games/emacs
+ fi
+
+ if use gui; then
+ local i
+ domenu emacs.desktop emacsclient.desktop
+
+ pushd icons || die
+ newicon sink.png emacs-sink.png
+ newicon emacs25_48.png emacs.png
+ for i in 16 24 32 48 128; do
+ [[ ${i} -le 48 ]] && newicon -s ${i} emacs22_${i}.png emacs22.png
+ newicon -s ${i} emacs23_${i}.png emacs23.png
+ newicon -s ${i} emacs25_${i}.png emacs.png
+ done
+ doicon -s scalable emacs23.svg
+ newicon -s scalable emacs25.svg emacs.svg
+ popd
+ fi
+
+ DOC_CONTENTS="All site initialisation for Gentoo-installed packages is
+ added to ${SITELISP}/site-gentoo.el. In order for this site
+ initialisation to be loaded for all users automatically, a default
+ site startup file /etc/emacs/site-start.el is installed. You are
+ responsible for maintenance of this file.
+ \n\nAlternatively, individual users can add the following command:
+ \n\n(require 'site-gentoo)
+ \n\nto their ~/.emacs initialisation files, or, for greater
+ flexibility, users may load single package-specific initialisation
+ files from the ${SITELISP}/site-gentoo.d/ directory."
+ readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+ # make sure that site-gentoo.el exists since site-start.el requires it
+ if [[ ! -f ${ED}${SITELISP}/site-gentoo.el ]]; then #554518
+ mv "${ED}${SITELISP}"/site-gentoo.el{.orig,} || die
+ fi
+ if [[ -d ${EROOT}${SITELISP} ]]; then
+ elisp-site-regen
+ cp "${EROOT}${SITELISP}/site-gentoo.el" "${ED}${SITELISP}/" || die
+ fi
+
+ if use games; then
+ local f
+ for f in /var/games/emacs/{snake,tetris}-scores; do
+ if [[ -e ${EROOT}${f} ]]; then
+ cp "${EROOT}${f}" "${ED}${f}" || die
+ fi
+ touch "${ED}${f}" || die
+ chgrp gamestat "${ED}${f}" || die
+ chmod g+w "${ED}${f}" || die
+ done
+ fi
+}
+
+pkg_postinst() {
+ if use gui; then
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ fi
+ readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+ if use gui; then
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ fi
+}
diff --git a/app-emacs/emacs-common/emacs-common-1.8.ebuild b/app-emacs/emacs-common/emacs-common-1.8.ebuild
new file mode 100644
index 000000000000..314ea5c739ad
--- /dev/null
+++ b/app-emacs/emacs-common/emacs-common-1.8.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit elisp-common desktop xdg-utils readme.gentoo-r1
+
+DESCRIPTION="Common files needed by all GNU Emacs versions"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
+IUSE="games gui"
+
+RDEPEND="games? ( acct-group/gamestat )"
+DEPEND="${RDEPEND}"
+PDEPEND=">=app-editors/emacs-23.1:*"
+
+src_install() {
+ insinto "${SITELISP}"
+ sed -e "s:@libdir@:$(get_libdir):g" subdirs.el.in | newins - subdirs.el
+ assert
+ newins site-gentoo.el{,.orig}
+
+ keepdir /etc/emacs
+ insinto /etc/emacs
+ doins site-start.el
+
+ if use games; then
+ keepdir /var/games/emacs
+ fowners 0:gamestat /var/games/emacs
+ fperms g+w /var/games/emacs
+ fi
+
+ if use gui; then
+ local i
+ domenu emacs.desktop emacsclient.desktop
+
+ pushd icons || die
+ newicon sink.png emacs-sink.png
+ newicon emacs25_48.png emacs.png
+ for i in 16 24 32 48 128; do
+ [[ ${i} -le 48 ]] && newicon -s ${i} emacs22_${i}.png emacs22.png
+ newicon -s ${i} emacs23_${i}.png emacs23.png
+ newicon -s ${i} emacs25_${i}.png emacs.png
+ done
+ doicon -s scalable emacs23.svg
+ newicon -s scalable emacs25.svg emacs.svg
+ popd
+ fi
+
+ DOC_CONTENTS="All site initialisation for Gentoo-installed packages is
+ added to ${SITELISP}/site-gentoo.el. In order for this site
+ initialisation to be loaded for all users automatically, a default
+ site startup file /etc/emacs/site-start.el is installed. You are
+ responsible for maintenance of this file.
+ \n\nAlternatively, individual users can add the following command:
+ \n\n(require 'site-gentoo)
+ \n\nto their ~/.emacs initialisation files, or, for greater
+ flexibility, users may load single package-specific initialisation
+ files from the ${SITELISP}/site-gentoo.d/ directory."
+ readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+ # make sure that site-gentoo.el exists since site-start.el requires it
+ if [[ ! -f ${ED}${SITELISP}/site-gentoo.el ]]; then #554518
+ mv "${ED}${SITELISP}"/site-gentoo.el{.orig,} || die
+ fi
+ if [[ -d ${EROOT}${SITELISP} ]]; then
+ elisp-site-regen
+ cp "${EROOT}${SITELISP}/site-gentoo.el" "${ED}${SITELISP}/" || die
+ fi
+
+ if use games; then
+ local f
+ for f in /var/games/emacs/{snake,tetris}-scores; do
+ if [[ -e ${EROOT}${f} ]]; then
+ cp "${EROOT}${f}" "${ED}${f}" || die
+ fi
+ touch "${ED}${f}" || die
+ chgrp gamestat "${ED}${f}" || die
+ chmod g+w "${ED}${f}" || die
+ done
+ fi
+}
+
+pkg_postinst() {
+ if use gui; then
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ fi
+ readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+ if use gui; then
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ fi
+}
diff --git a/app-emacs/emacs-common/metadata.xml b/app-emacs/emacs-common/metadata.xml
new file mode 100644
index 000000000000..cdc9b75d52a0
--- /dev/null
+++ b/app-emacs/emacs-common/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+ <email>gnu-emacs@gentoo.org</email>
+ <name>Gentoo GNU Emacs project</name>
+</maintainer>
+<stabilize-allarches/>
+<use>
+ <flag name="games">Support shared score files for games</flag>
+</use>
+</pkgmetadata>
generated by cgit v1.2.3 (git 2.25.1) at 2025-01-15 11:01:11 +0000