1 files changed, 36 insertions, 0 deletions
diff --git a/app-emacs/gnuplot-mode/gnuplot-mode-0.8.0.ebuild b/app-emacs/gnuplot-mode/gnuplot-mode-0.8.0.ebuild
new file mode 100644
index 000000000000..f65814319ab7
--- /dev/null
+++ b/app-emacs/gnuplot-mode/gnuplot-mode-0.8.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit elisp readme.gentoo-r1
+
+DESCRIPTION="Gnuplot mode for Emacs"
+HOMEPAGE="https://github.com/emacsorphanage/gnuplot"
+SRC_URI="https://github.com/emacsorphanage/${PN%-mode}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+S="${WORKDIR}/${PN%-mode}-${PV}"
+
+LICENSE="GPL-3+ gnuplot"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ppc ppc64 ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="doc"
+
+BDEPEND="doc? ( virtual/latex-base )"
+RDEPEND="sci-visualization/gnuplot[-emacs(-)]"
+
+SITEFILE="50${PN}-gentoo.el"
+DOCS=(CHANGELOG.org README.org)
+DOC_CONTENTS="Please see ${SITELISP}/${PN}/gnuplot.el for the complete
+	documentation."
+
+src_compile() {
+	elisp_src_compile
+	use doc && { pdflatex gpelcard || die; }
+}
+
+src_install() {
+	elisp_src_install
+	doinfo gnuplot.info
+	use doc && dodoc gpelcard.pdf
+}