1 files changed, 45 insertions, 0 deletions
diff --git a/dev-java/bcel/bcel-6.0_rc3.ebuild b/dev-java/bcel/bcel-6.0_rc3.ebuild
new file mode 100644
index 000000000000..0dcfd4552f2e
--- /dev/null
+++ b/dev-java/bcel/bcel-6.0_rc3.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+MY_PV="${PV//./_}"
+MY_PV="${MY_PV/rc/RC}"
+MY_P="BCEL_${MY_PV}"
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="The Byte Code Engineering Library: analyze, create, manipulate Java class files"
+HOMEPAGE="http://commons.apache.org/bcel/"
+SRC_URI="https://github.com/apache/commons-${PN}/archive/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+RDEPEND=">=virtual/jre-1.5"
+DEPEND=">=virtual/jdk-1.5
+	test? ( dev-java/junit:4 )"
+
+S="${WORKDIR}/commons-${PN}-${MY_P}/src"
+JAVA_SRC_DIR="main/java"
+
+src_install() {
+	java-pkg-simple_src_install
+	dodoc ../{NOTICE,README,RELEASE-NOTES}.txt
+}
+
+src_test() {
+	cd test/java || die
+
+	local CP=".:${S}/${PN}.jar:$(java-pkg_getjars junit-4)"
+	local TESTS=$(find * -name "*TestCase.java" ! -name "Abstract*")
+	TESTS="${TESTS//.java}"
+	TESTS="${TESTS//\//.}"
+
+	ejavac -g -cp "${CP}" -d . $(find * -name "*.java")
+	ejunit4 -classpath "${CP}" ${TESTS}
+}