1 files changed, 41 insertions, 0 deletions
diff --git a/dev-lang/nasm/nasm-2.12.01.ebuild b/dev-lang/nasm/nasm-2.12.01.ebuild
new file mode 100644
index 000000000000..5d34b024847a
--- /dev/null
+++ b/dev-lang/nasm/nasm-2.12.01.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit flag-o-matic
+
+DESCRIPTION="groovy little assembler"
+HOMEPAGE="http://www.nasm.us/"
+SRC_URI="http://www.nasm.us/pub/nasm/releasebuilds/${PV/_}/${P/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="amd64 ~ia64 x86 ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc"
+
+DEPEND="dev-lang/perl
+	doc? ( app-text/ghostscript-gpl sys-apps/texinfo )"
+RDEPEND=""
+
+S=${WORKDIR}/${P/_}
+
+src_configure() {
+	strip-flags
+	econf
+}
+
+src_compile() {
+	emake nasmlib.o
+	emake all
+	use doc && emake doc
+}
+
+src_install() {
+	emake INSTALLROOT="${D}" install install_rdf
+	dodoc AUTHORS CHANGES ChangeLog README TODO
+	if use doc ; then
+		doinfo doc/info/*
+		dohtml doc/html/*
+		dodoc doc/nasmdoc.*
+	fi
+}