1 files changed, 0 insertions, 84 deletions
diff --git a/dev-libs/capstone/capstone-3.0.5_rc2-r1.ebuild b/dev-libs/capstone/capstone-3.0.5_rc2-r1.ebuild
deleted file mode 100644
index 17f8b6cd3aff..000000000000
--- a/dev-libs/capstone/capstone-3.0.5_rc2-r1.ebuild
+++ /dev/null
@@ -1,84 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-DISTUTILS_OPTIONAL=1
-PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
-
-inherit distutils-r1 toolchain-funcs
-
-DESCRIPTION="disassembly/disassembler framework + bindings"
-HOMEPAGE="http://www.capstone-engine.org/"
-SRC_URI="https://github.com/aquynh/${PN}/archive/${PV/_rc/-rc}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0/3" # libcapstone.so.3
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-
-IUSE="python"
-RDEPEND="python? ( ${PYTHON_DEPS} )"
-DEPEND="${RDEPEND}
-	python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
-"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-CVE-2017-6952.patch
-	"${FILESDIR}"/${P}-FLAGS.patch
-)
-
-S=${WORKDIR}/${P/_rc/-rc}
-
-wrap_python() {
-	if use python; then
-		pushd bindings/python >/dev/null || die
-		distutils-r1_${1} "$@"
-		popd >/dev/null
-	fi
-}
-
-src_prepare() {
-	default
-
-	wrap_python ${FUNCNAME}
-}
-
-src_configure() {
-	{
-		cat <<-EOF
-		# Gentoo overrides:
-		#   verbose build
-		V = 1
-		#   toolchain
-		AR = $(tc-getAR)
-		CC = $(tc-getCC)
-		RANLIB = $(tc-getRANLIB)
-		#  toolchain flags
-		CFLAGS = ${CFLAGS}
-		LDFLAGS = ${LDFLAGS}
-		#  libs
-		LIBDIRARCH = $(get_libdir)
-		EOF
-	} >> config.mk || die
-
-	wrap_python ${FUNCNAME}
-}
-
-src_compile() {
-	default
-
-	wrap_python ${FUNCNAME}
-}
-
-src_test() {
-	default
-
-	wrap_python ${FUNCNAME}
-}
-
-src_install() {
-	default
-
-	wrap_python ${FUNCNAME}
-}