summaryrefslogtreecommitdiff
path: root/dev-libs/efl
diff options
context:
space:
mode:
Diffstat (limited to 'dev-libs/efl')
-rw-r--r--dev-libs/efl/Manifest9
-rw-r--r--dev-libs/efl/efl-1.22.2.ebuild2
-rw-r--r--dev-libs/efl/efl-1.22.3.ebuild (renamed from dev-libs/efl/efl-1.21.1-r3.ebuild)55
-rw-r--r--dev-libs/efl/efl-1.22.4.ebuild281
-rw-r--r--dev-libs/efl/files/efl-1.21.1-fix_evas_preload_segfault.patch10
5 files changed, 317 insertions, 40 deletions
diff --git a/dev-libs/efl/Manifest b/dev-libs/efl/Manifest
index 0631199853fe..aac0f111e424 100644
--- a/dev-libs/efl/Manifest
+++ b/dev-libs/efl/Manifest
@@ -1,6 +1,7 @@
-AUX efl-1.21.1-fix_evas_preload_segfault.patch 381 BLAKE2B a4b8afbe06cd44154a41766fcf12775369c2243325eab17647423a3d2b78cc3646361c0a4884de71fd876698defb9816f50343c46690b595c3701a6295a95040 SHA512 90901ab26915a6d2aba80deb610eb8bb873cd4cc7210888a4f062057891024d4e0b3f051be2fda39680d2267301251abbfbfc47072cb5c22ba6eba8f9d9567fc
-DIST efl-1.21.1.tar.xz 71168368 BLAKE2B 4653e97f7b9a824d8e84dd1463dd6c95c0228bb3a03df1915f604136380343ad52e86e6b485f0aa14f1caef5a36451425b79cf2a5123c83d8e8a6d430ff213bf SHA512 1e26a57fca84ec85e45d707ee57abc50bd18edfa82e478e586300b6ad5ab8b9103a54a656902d29d80425988a6116a40aa01758fb8dd581dd48334ca0f4d5a63
DIST efl-1.22.2.tar.xz 71320272 BLAKE2B b1eb66228ec5a92f5d89bf38d95439f9bfb0b09a074e418094474d7c7d0de6a4ae998321a02273a5c9bbcfcba260a7ff3d8cef0af445293869c82c57dec2cca0 SHA512 7385b1fdeee0a4565a0765fedbe5cecca81b86b306ee95a703b3064a88427ab0b4967f6f075a92f5c1d5911cefc56a9c2d45c7347572480169e3f53348321734
-EBUILD efl-1.21.1-r3.ebuild 6637 BLAKE2B e8846787fa6d2a5767468468625492bb0794fd76a53ae8b08a204c3ce6d2950a96ce15fb7fb2d7fd7f98313f7c06124ce97638909fd34e8d8c979e3382110f77 SHA512 67874905f334701605d886c5f75a82b027c4c418c87f8e495b1449b3d3b79d544172b5be8a180098656ee620eeb46eeb805695dbeaa242d2301a8ea0f8c4710b
-EBUILD efl-1.22.2.ebuild 6879 BLAKE2B f6d0200b055bfe235b08053982243b64e4cdaa5290e91c173e86918a839a69a45385256651b0d013f6c0a854ac9d7dfd6281c9d8a529ba175d54e410081b2f10 SHA512 914afb7338f7c9889a35fc1e72bf4699439496e3c37aac13b83635a8cade901abcb17b45ebd0fd899fd7c725d546d767fc2e0b7db6ac42e2a64bdadd380f4f9c
+DIST efl-1.22.3.tar.xz 70620824 BLAKE2B b6a785ad1ebf9b7804eb2ea12dd78bcf1ee0647d24852c23955e10c59bb7a9a9d0b86cec7796382dacdef11ca164d87c02f186700dcc69bebe8ba6c62727fc6d SHA512 d29022c27950adebab96266343c4f861801f445f36806c8bf0da67fe4ea75807932fa9f218d9cb084c2c3f6ccc212903992ef4b94b95253656e8550b11b42f83
+DIST efl-1.22.4.tar.xz 71364104 BLAKE2B 66aa2cfad4b9474b4343e7c139a9d918e3c1b80944ca41414c62c2ec3468d84ebfe95e9834846b55f6ead0568b77e59cb115fd607f1653dd692baa8d9238ac5b SHA512 0a9e5bd40dfeb10f4c17c64aae5c9af8f54be934b78216f6effecaf077b9f57fe704cb61ded4487472bd9451a3eeb6634b2c0d0d038e911177c2e33576ad6b6e
+EBUILD efl-1.22.2.ebuild 6877 BLAKE2B 5569c1e68c66b5bf103f71e526eadd1ea58ead7e37d2cfa367a557bbfbfa3e0764a81338ee8f046a988984540c0a875b79097f62661fe567dfea7df7fb723cb6 SHA512 c1bb384fc318c85a7cefe6cd68c0f776f7319ff80c98389907e373f1880c00c1ce1f50befe097c207c227da87978e19c5031b590e0773ea395395f7c5a271369
+EBUILD efl-1.22.3.ebuild 6879 BLAKE2B 7d51377cfb1356054b7ab9562d77d8310591625b2af614e4cd99067eafa8f170cfb2fd66fca2e311bdc4f688aa48b61b15b7f65591810b8510d5e83797ab8bf1 SHA512 e8ce2178fd494b7e701e4e56d70573439db2ff1a6eddbbaf89b111a6b3388af49bf98367563a0c131c55a46c6df4bc982dd4582caf1110d8117ddfd35aa55d3f
+EBUILD efl-1.22.4.ebuild 6879 BLAKE2B 7d51377cfb1356054b7ab9562d77d8310591625b2af614e4cd99067eafa8f170cfb2fd66fca2e311bdc4f688aa48b61b15b7f65591810b8510d5e83797ab8bf1 SHA512 e8ce2178fd494b7e701e4e56d70573439db2ff1a6eddbbaf89b111a6b3388af49bf98367563a0c131c55a46c6df4bc982dd4582caf1110d8117ddfd35aa55d3f
MISC metadata.xml 1920 BLAKE2B 01decb622aae3e01bf59d93d48b4babc5e2f63a1499f0daeedd1e9b513f2e7a41819caf3a8f738d49333a2b538d3231d0355ed216edb6313e0c587281f4a9bfe SHA512 ae1c2f5791cf991940eff5333747cd3591b8d03048b99fe4ff1acf442c964f7e56ff0de60cc275205f871b937ef369e9e24342368e69c565fc2efe87931df5b4
diff --git a/dev-libs/efl/efl-1.22.2.ebuild b/dev-libs/efl/efl-1.22.2.ebuild
index dce1d89b8816..df0fbe727fc7 100644
--- a/dev-libs/efl/efl-1.22.2.ebuild
+++ b/dev-libs/efl/efl-1.22.2.ebuild
@@ -11,7 +11,7 @@ SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
IUSE="+bmp dds connman debug drm +eet elogind examples fbcon +fontconfig fribidi gif gles2 glib gnutls gstreamer harfbuzz hyphen +ico ibus jpeg2k libressl libuv luajit neon nls opengl ssl pdf physics postscript +ppm +psd pulseaudio raw scim sdl sound static-libs svg +system-lz4 systemd tga tiff tslib unwind v4l valgrind vlc vnc wayland webp X xcf xim xine xpm xpresent zeroconf"
REQUIRED_USE="
diff --git a/dev-libs/efl/efl-1.21.1-r3.ebuild b/dev-libs/efl/efl-1.22.3.ebuild
index 0efdcf3a7234..2da0160a9808 100644
--- a/dev-libs/efl/efl-1.21.1-r3.ebuild
+++ b/dev-libs/efl/efl-1.22.3.ebuild
@@ -1,9 +1,9 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
-EAPI=6
+EAPI=7
-inherit gnome2-utils pax-utils xdg-utils
+inherit pax-utils xdg-utils
DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
HOMEPAGE="https://www.enlightenment.org"
@@ -11,10 +11,11 @@ SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
SLOT="0"
-KEYWORDS="amd64 ~arm ~ia64 ~ppc ~ppc64 x86 ~amd64-linux ~x86-linux"
-IUSE="+bmp dds connman debug drm +eet examples fbcon +fontconfig fribidi gif gles2 glib gnutls gstreamer harfbuzz hyphen +ico ibus jpeg2k libressl libuv luajit neon nls opengl ssl pdf physics postscript +ppm +psd pulseaudio raw scim sdl sound static-libs svg +system-lz4 systemd tga tiff tslib unwind v4l valgrind vlc vnc wayland webp X xcf xim xine xpm xpresent zeroconf"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="+bmp dds connman debug drm +eet elogind examples fbcon +fontconfig fribidi gif gles2 glib gnutls gstreamer harfbuzz hyphen +ico ibus jpeg2k libressl libuv luajit neon nls opengl ssl pdf physics postscript +ppm +psd pulseaudio raw scim sdl sound static-libs svg +system-lz4 systemd tga tiff tslib unwind v4l valgrind vlc vnc wayland webp X xcf xim xine xpm xpresent zeroconf"
REQUIRED_USE="
+ ?? ( elogind systemd )
?? ( gles2 opengl )
fbcon? ( !tslib )
gles2? (
@@ -36,7 +37,6 @@ RDEPEND="
media-libs/libpng:0=
sys-apps/dbus
sys-apps/util-linux
- sys-libs/zlib:=
virtual/jpeg:0=
connman? ( net-misc/connman )
drm? (
@@ -45,6 +45,7 @@ RDEPEND="
x11-libs/libdrm
x11-libs/libxkbcommon
)
+ elogind? ( sys-auth/elogind )
fontconfig? ( media-libs/fontconfig )
fribidi? ( dev-libs/fribidi )
gif? ( media-libs/giflib:= )
@@ -61,7 +62,6 @@ RDEPEND="
libuv? ( dev-libs/libuv )
luajit? ( dev-lang/luajit:= )
!luajit? ( dev-lang/lua:* )
- nls? ( sys-devel/gettext )
pdf? ( app-text/poppler:=[cxx] )
physics? ( sci-physics/bullet:= )
postscript? ( app-text/libspectre )
@@ -85,7 +85,7 @@ RDEPEND="
x11-libs/cairo
)
system-lz4? ( app-arch/lz4 )
- systemd? ( sys-apps/systemd )
+ systemd? ( sys-apps/systemd:= )
tiff? ( media-libs/tiff:0= )
tslib? ( x11-libs/tslib:= )
unwind? ( sys-libs/libunwind )
@@ -128,14 +128,9 @@ RDEPEND="
zeroconf? ( net-dns/avahi )
"
-DEPEND="
- ${RDEPEND}
- virtual/pkgconfig
-"
-
-PATCHES=(
- "${FILESDIR}/${P}-fix_evas_preload_segfault.patch"
-)
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+ nls? ( sys-devel/gettext )"
src_prepare() {
default
@@ -145,25 +140,33 @@ src_prepare() {
sed -i -e 's:libunwind libunwind-generic:xxxxxxxxxxxxxxxx:' \
configure || die "Sedding configure file with unwind fix failed."
fi
-
- xdg_environment_reset
}
src_configure() {
local myconf=(
- --enable-cserve
+ --enable-cxx-bindings
--enable-image-loader-generic
--enable-image-loader-jpeg
--enable-image-loader-png
--enable-libeeze
--enable-libmount
+ --enable-quick-launch
+ --enable-threads
--enable-xinput22
+ --disable-cancel-ok
+ --disable-cocoa
+ --disable-csharp-beta
+ --disable-csharp-bindings
--disable-doc
+ --disable-ecore-buffer
+ --disable-ecore-drm
+ --disable-ecore-wayland
--disable-eglfs
+ --disable-g-main-loop
--disable-gesture
--disable-gstreamer
- --disable-image-loader-tgv
+ --disable-pixman
--disable-tizen
--disable-wayland-ivi-shell
@@ -173,6 +176,7 @@ src_configure() {
$(use_enable drm)
$(use_enable drm elput)
$(use_enable eet image-loader-eet)
+ $(use_enable elogind)
$(use_enable examples always-build-examples)
$(use_enable fbcon fb)
$(use_enable fontconfig)
@@ -254,23 +258,24 @@ src_compile() {
pax-mark m src/bin/elua/.libs/elua
fi
- V=1 emake || die "Compiling EFL failed."
+ V=1 emake
}
src_install() {
+ V=1 emake install DESTDIR="${D}"
einstalldocs
- V=1 emake install DESTDIR="${D}" || die "Installing EFL files failed."
-
- find "${D}" -name '*.la' -delete || die
+ if ! use static-libs ; then
+ find "${D}" -name '*.la' -delete || die
+ fi
}
pkg_postinst() {
- gnome2_icon_cache_update
+ xdg_icon_cache_update
xdg_mimeinfo_database_update
}
pkg_postrm() {
- gnome2_icon_cache_update
+ xdg_icon_cache_update
xdg_mimeinfo_database_update
}
diff --git a/dev-libs/efl/efl-1.22.4.ebuild b/dev-libs/efl/efl-1.22.4.ebuild
new file mode 100644
index 000000000000..2da0160a9808
--- /dev/null
+++ b/dev-libs/efl/efl-1.22.4.ebuild
@@ -0,0 +1,281 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit pax-utils xdg-utils
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+HOMEPAGE="https://www.enlightenment.org"
+SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="+bmp dds connman debug drm +eet elogind examples fbcon +fontconfig fribidi gif gles2 glib gnutls gstreamer harfbuzz hyphen +ico ibus jpeg2k libressl libuv luajit neon nls opengl ssl pdf physics postscript +ppm +psd pulseaudio raw scim sdl sound static-libs svg +system-lz4 systemd tga tiff tslib unwind v4l valgrind vlc vnc wayland webp X xcf xim xine xpm xpresent zeroconf"
+
+REQUIRED_USE="
+ ?? ( elogind systemd )
+ ?? ( gles2 opengl )
+ fbcon? ( !tslib )
+ gles2? (
+ || ( wayland X )
+ !sdl
+ )
+ ibus? ( glib )
+ opengl? ( X )
+ pulseaudio? ( sound )
+ sdl? ( opengl )
+ vnc? ( fbcon X )
+ wayland? ( gles2 !opengl )
+ xim? ( X )
+ xpresent? ( X )
+"
+
+RDEPEND="
+ net-misc/curl
+ media-libs/libpng:0=
+ sys-apps/dbus
+ sys-apps/util-linux
+ virtual/jpeg:0=
+ connman? ( net-misc/connman )
+ drm? (
+ dev-libs/libinput
+ media-libs/mesa[gbm]
+ x11-libs/libdrm
+ x11-libs/libxkbcommon
+ )
+ elogind? ( sys-auth/elogind )
+ fontconfig? ( media-libs/fontconfig )
+ fribidi? ( dev-libs/fribidi )
+ gif? ( media-libs/giflib:= )
+ gles2? ( media-libs/mesa[egl,gles2] )
+ glib? ( dev-libs/glib:2 )
+ gstreamer? (
+ media-libs/gstreamer:1.0
+ media-libs/gst-plugins-base:1.0
+ )
+ harfbuzz? ( media-libs/harfbuzz )
+ hyphen? ( dev-libs/hyphen )
+ ibus? ( app-i18n/ibus )
+ jpeg2k? ( media-libs/openjpeg:= )
+ libuv? ( dev-libs/libuv )
+ luajit? ( dev-lang/luajit:= )
+ !luajit? ( dev-lang/lua:* )
+ pdf? ( app-text/poppler:=[cxx] )
+ physics? ( sci-physics/bullet:= )
+ postscript? ( app-text/libspectre )
+ pulseaudio? ( media-sound/pulseaudio )
+ raw? ( media-libs/libraw:= )
+ scim? ( app-i18n/scim )
+ sdl? (
+ media-libs/libsdl2
+ virtual/opengl
+ )
+ sound? ( media-libs/libsndfile )
+ ssl? (
+ gnutls? ( net-libs/gnutls:= )
+ !gnutls? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:= )
+ )
+ )
+ svg? (
+ gnome-base/librsvg
+ x11-libs/cairo
+ )
+ system-lz4? ( app-arch/lz4 )
+ systemd? ( sys-apps/systemd:= )
+ tiff? ( media-libs/tiff:0= )
+ tslib? ( x11-libs/tslib:= )
+ unwind? ( sys-libs/libunwind )
+ valgrind? ( dev-util/valgrind )
+ vlc? ( media-video/vlc )
+ vnc? ( net-libs/libvncserver )
+ wayland? (
+ dev-libs/wayland
+ media-libs/mesa[gles2,wayland]
+ x11-libs/libxkbcommon
+ )
+ webp? ( media-libs/libwebp:= )
+ X? (
+ media-libs/freetype
+ x11-libs/libXcursor
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ x11-libs/libXdamage
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libXinerama
+ x11-libs/libXrandr
+ x11-libs/libXrender
+ x11-libs/libXtst
+ x11-libs/libXScrnSaver
+ gles2? (
+ x11-libs/libX11
+ x11-libs/libXrender
+ virtual/opengl
+ )
+ opengl? (
+ x11-libs/libX11
+ x11-libs/libXrender
+ virtual/opengl
+ )
+ )
+ xine? ( media-libs/xine-lib )
+ xpm? ( x11-libs/libXpm )
+ xpresent? ( x11-libs/libXpresent )
+ zeroconf? ( net-dns/avahi )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+ nls? ( sys-devel/gettext )"
+
+src_prepare() {
+ default
+
+ # Upstream still doesnt offer a configure flag. #611108
+ if ! use unwind ; then
+ sed -i -e 's:libunwind libunwind-generic:xxxxxxxxxxxxxxxx:' \
+ configure || die "Sedding configure file with unwind fix failed."
+ fi
+}
+
+src_configure() {
+ local myconf=(
+ --enable-cxx-bindings
+ --enable-image-loader-generic
+ --enable-image-loader-jpeg
+ --enable-image-loader-png
+ --enable-libeeze
+ --enable-libmount
+ --enable-quick-launch
+ --enable-threads
+ --enable-xinput22
+
+ --disable-cancel-ok
+ --disable-cocoa
+ --disable-csharp-beta
+ --disable-csharp-bindings
+ --disable-doc
+ --disable-ecore-buffer
+ --disable-ecore-drm
+ --disable-ecore-wayland
+ --disable-eglfs
+ --disable-g-main-loop
+ --disable-gesture
+ --disable-gstreamer
+ --disable-pixman
+ --disable-tizen
+ --disable-wayland-ivi-shell
+
+ $(use_enable bmp image-loader-bmp)
+ $(use_enable bmp image-loader-wbmp)
+ $(use_enable dds image-loader-dds)
+ $(use_enable drm)
+ $(use_enable drm elput)
+ $(use_enable eet image-loader-eet)
+ $(use_enable elogind)
+ $(use_enable examples always-build-examples)
+ $(use_enable fbcon fb)
+ $(use_enable fontconfig)
+ $(use_enable fribidi)
+ $(use_enable gif image-loader-gif)
+ $(use_enable gles2 egl)
+ $(use_enable gstreamer gstreamer1)
+ $(use_enable harfbuzz)
+ $(use_enable hyphen)
+ $(use_enable ico image-loader-ico)
+ $(use_enable ibus)
+ $(use_enable jpeg2k image-loader-jp2k)
+ $(use_enable libuv)
+ $(use_enable !luajit lua-old)
+ $(use_enable neon)
+ $(use_enable nls)
+ $(use_enable pdf poppler)
+ $(use_enable physics)
+ $(use_enable postscript spectre)
+ $(use_enable ppm image-loader-pmaps)
+ $(use_enable psd image-loader-psd)
+ $(use_enable pulseaudio)
+ $(use_enable raw libraw)
+ $(use_enable scim)
+ $(use_enable sdl)
+ $(use_enable sound audio)
+ $(use_enable static-libs static)
+ $(use_enable svg librsvg)
+ $(use_enable system-lz4 liblz4)
+ $(use_enable systemd)
+ $(use_enable tga image-loader-tga)
+ $(use_enable tiff image-loader-tiff)
+ $(use_enable tslib)
+ $(use_enable v4l v4l2)
+ $(use_enable valgrind)
+ $(use_enable vlc libvlc)
+ $(use_enable vnc vnc-server)
+ $(use_enable wayland)
+ $(use_enable webp image-loader-webp)
+ $(use_enable xcf)
+ $(use_enable xim)
+ $(use_enable xine)
+ $(use_enable xpm image-loader-xpm)
+ $(use_enable xpresent)
+ $(use_enable zeroconf avahi)
+
+ --with-crypto=$(usex gnutls gnutls $(usex ssl openssl none))
+ --with-glib=$(usex glib)
+ --with-js=none
+ --with-net-control=$(usex connman connman none)
+ --with-profile=$(usex debug debug release)
+ --with-x11=$(usex X xlib none)
+
+ $(use_with X x)
+ )
+
+ use drm && use wayland && myconf+=( --enable-gl-drm )
+
+ if use opengl ; then
+ myconf+=( --with-opengl=full )
+ elif use gles2 ; then
+ myconf+=( --with-opengl=es )
+ elif use drm && use wayland ; then
+ myconf+=( --with-opengl=es )
+ else
+ myconf+=( --with-opengl=none )
+ fi
+
+ econf "${myconf[@]}"
+}
+
+src_compile() {
+ if host-is-pax && use luajit ; then
+ # We need to build the lua code first so we can pax-mark it. #547076
+ local target='_e_built_sources_target_gogogo_'
+ printf '%s: $(BUILT_SOURCES)\n' "${target}" >> src/Makefile || die
+ emake -C src "${target}"
+ emake -C src bin/elua/elua
+ pax-mark m src/bin/elua/.libs/elua
+ fi
+
+ V=1 emake
+}
+
+src_install() {
+ V=1 emake install DESTDIR="${D}"
+ einstalldocs
+
+ if ! use static-libs ; then
+ find "${D}" -name '*.la' -delete || die
+ fi
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+}
diff --git a/dev-libs/efl/files/efl-1.21.1-fix_evas_preload_segfault.patch b/dev-libs/efl/files/efl-1.21.1-fix_evas_preload_segfault.patch
deleted file mode 100644
index 8d42cbb0f250..000000000000
--- a/dev-libs/efl/files/efl-1.21.1-fix_evas_preload_segfault.patch
+++ /dev/null
@@ -1,10 +0,0 @@
---- a/src/lib/evas/cache/evas_cache_image.c 14:09:44.971119099 +0100
-+++ b/src/lib/evas/cache/evas_cache_image.c 14:10:21.521226043 +0100
-@@ -361,6 +361,7 @@
- cache = current->cache;
-
- if ((!current->flags.loaded) &&
-+ (current->info.loader) &&
- current->info.loader->threadable)
- {
- evas_module_task_register(evas_cache_image_cancelled, current);
generated by cgit v1.2.3 (git 2.25.1) at 2025-03-31 19:03:32 +0000