1 files changed, 42 insertions, 0 deletions
diff --git a/dev-libs/iksemel/iksemel-1.4-r2.ebuild b/dev-libs/iksemel/iksemel-1.4-r2.ebuild
new file mode 100644
index 000000000000..dc67c8484ffd
--- /dev/null
+++ b/dev-libs/iksemel/iksemel-1.4-r2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="eXtensible Markup Language parser library designed for Jabber applications"
+HOMEPAGE="https://github.com/meduketto/iksemel"
+SRC_URI="https://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ppc ~ppc64 x86"
+IUSE="ssl"
+
+RDEPEND="ssl? ( net-libs/gnutls:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="ssl? ( virtual/pkgconfig )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3-gnutls-2.8.patch
+	"${FILESDIR}"/${PN}-1.4-gnutls-3.4.patch
+	"${FILESDIR}"/${PN}-1.4-ikstack.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with ssl gnutls)
+}
+
+src_install() {
+	default
+	dodoc HACKING
+
+	# package installs .pc files
+	find "${ED}" -name '*.la' -delete || die
+}