1 files changed, 41 insertions, 0 deletions
diff --git a/dev-libs/openspecfun/openspecfun-0.5.5.ebuild b/dev-libs/openspecfun/openspecfun-0.5.5.ebuild
new file mode 100644
index 000000000000..da7263c522f8
--- /dev/null
+++ b/dev-libs/openspecfun/openspecfun-0.5.5.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit fortran-2 toolchain-funcs
+
+DESCRIPTION="A collection of special mathematical functions"
+HOMEPAGE="https://julialang.org"
+SRC_URI="https://github.com/JuliaLang/openspecfun/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="sci-libs/openlibm:="
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}"/${P}-Makefile.patch )
+
+src_configure() {
+	tc-export CC
+}
+
+src_compile() {
+	emake \
+		prefix="${EPREFIX}"/usr \
+		libdir="${EPREFIX}"/usr/$(get_libdir) \
+		USE_OPENLIBM=1
+}
+
+src_install() {
+	emake \
+		prefix="${EPREFIX}"/usr \
+		libdir="${EPREFIX}"/usr/$(get_libdir) \
+		DESTDIR="${D}" \
+		install
+	einstalldocs
+
+	find "${ED}" -name '*.la' -delete || die
+}