1 files changed, 50 insertions, 0 deletions
diff --git a/dev-python/ansi2html/ansi2html-1.4.2.ebuild b/dev-python/ansi2html/ansi2html-1.4.2.ebuild
new file mode 100644
index 000000000000..e8c9113901fd
--- /dev/null
+++ b/dev-python/ansi2html/ansi2html-1.4.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Convert text with ANSI color codes to HTML"
+HOMEPAGE="https://pypi.python.org/pypi/ansi2html https://github.com/ralphbean/ansi2html"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc test"
+
+# They miserably fail.
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/six-1.7.3[${PYTHON_USEDEP}]"
+DEPEND="
+	doc? ( app-text/asciidoc )
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy)
+	)
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	"
+
+src_compile() {
+	use doc && emake man/${PN}.1
+	distutils-r1_src_compile
+}
+
+python_test() {
+	chmod -x "${S}"/tests/* || die
+	esetup.py check
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && doman man/${PN}.1
+	DOCS=( README.rst man/${PN}.1.txt )
+	distutils-r1_python_install_all
+}