1 files changed, 44 insertions, 0 deletions
diff --git a/dev-python/anyio/anyio-3.5.0.ebuild b/dev-python/anyio/anyio-3.5.0.ebuild
new file mode 100644
index 000000000000..a57dd40c611b
--- /dev/null
+++ b/dev-python/anyio/anyio-3.5.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Compatibility layer for multiple asynchronous event loop implementations"
+HOMEPAGE="
+	https://github.com/agronholm/anyio
+	https://pypi.org/project/anyio/
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/idna-2.8[${PYTHON_USEDEP}]
+	>=dev-python/sniffio-1.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/hypothesis-4.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.6.1[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		>=dev-python/uvloop-0.15[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme \
+	dev-python/sphinx-autodoc-typehints
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	distutils_install_for_testing --via-venv
+	epytest -m 'not network'
+}