1 files changed, 38 insertions, 0 deletions
diff --git a/dev-python/click/click-8.1.5.ebuild b/dev-python/click/click-8.1.5.ebuild
new file mode 100644
index 000000000000..0cf462f36528
--- /dev/null
+++ b/dev-python/click/click-8.1.5.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python package for creating beautiful command line interfaces"
+HOMEPAGE="
+	https://palletsprojects.com/p/click/
+	https://github.com/pallets/click/
+	https://pypi.org/project/click/
+"
+SRC_URI="
+	https://github.com/pallets/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="examples"
+
+distutils_enable_sphinx docs \
+	'>=dev-python/docutils-0.14' \
+	dev-python/pallets-sphinx-themes \
+	dev-python/sphinxcontrib-log-cabinet \
+	dev-python/sphinx-issues \
+	dev-python/sphinx-tabs
+distutils_enable_tests pytest
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}