3 files changed, 58 insertions, 34 deletions
diff --git a/dev-python/jaraco-functools/Manifest b/dev-python/jaraco-functools/Manifest
index f82fa4c82698..6aa4a8a535ac 100644
--- a/dev-python/jaraco-functools/Manifest
+++ b/dev-python/jaraco-functools/Manifest
@@ -1,3 +1,3 @@
 DIST jaraco.functools-3.5.0.tar.gz 13254 BLAKE2B 9165f901106278da562c6b59c3cc29e0b1c4689c5db7955f57a76fca3c12e90d30a80a7dde3420a719b093c41b889e54170bfa6f6f18b6f078e3f4291e59736f SHA512 7257f41506f90ca2fda1bd12fed58fa4d4ff5738547f8cdae8ccad1901e0c818afb701dd8e9050fc77ca1271bc2466d5a542990138bc3db2cf9b04d12850844c
-EBUILD jaraco-functools-3.5.0.ebuild 867 BLAKE2B d1280658776303459976304b08708278729ba70f8ce6caca07f63d849946039edc45409621a41b512faa7e2b3e629ba220f0235e09e32afbc407f80052e1e3d5 SHA512 1db1450fa3864de3fe545b86ae1e42b7aa6557b50b5aba4c78b7963a3e8ea85df06c76daa7e23605ea80f1a12e46ad13d9efc9cb767125053291f52d590c2b41
+EBUILD jaraco-functools-3.5.0-r2.ebuild 1526 BLAKE2B c54e6e1173a141f2233529c68e4f09a3e523180d8a95ff1b99d9abbb75bd5cdbaf85ff35fad3e6ef4701a71d43b5773bf958a3047abf27c1f9342d12be739200 SHA512 3c9b2ac4c7592c88cd7f539c5e4fc7c66ab904837b1831f96517c61478f708d1aad6431f8c1944a493fd40632a33b1c7b1b6690942032ccb1f1e42ab286e760a
 MISC metadata.xml 676 BLAKE2B b437d010c92db7c16013c9e2dbdb0071c793900189cdd0ec1918abc587ea5fcff10f36b5822e0912797fd2baf3aab5e8a25cf30ad8bb7f3e8e65608a52cd41cc SHA512 95fbff54e3f761dc323dd6c590ad093d301f5438db7a46c90be8a22ab59e1531ea1785317c764e98e278629ff8cd4db976ff1e25d00de46fe741c65ff655201d
diff --git a/dev-python/jaraco-functools/jaraco-functools-3.5.0-r2.ebuild b/dev-python/jaraco-functools/jaraco-functools-3.5.0-r2.ebuild
new file mode 100644
index 000000000000..2e1c4bb4a95d
--- /dev/null
+++ b/dev-python/jaraco-functools/jaraco-functools-3.5.0-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Additional functions used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.functools"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN/-/.}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv sparc x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/more-itertools-0.12.0-r1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "jaraco.functools"
+		version = "${PV}"
+		description = "Functools like those found in stdlib"
+	EOF
+}
+
+python_install() {
+	distutils-r1_python_install
+	# rename to workaround a bug in pkg_resources
+	# https://bugs.gentoo.org/834522
+	mv "${D}$(python_get_sitedir)"/jaraco{_,.}functools-${PV}.dist-info || die
+}
diff --git a/dev-python/jaraco-functools/jaraco-functools-3.5.0.ebuild b/dev-python/jaraco-functools/jaraco-functools-3.5.0.ebuild
deleted file mode 100644
index 71c71c267e6f..000000000000
--- a/dev-python/jaraco-functools/jaraco-functools-3.5.0.ebuild
+++ /dev/null
@@ -1,33 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( pypy3 python3_{8..10} )
-inherit distutils-r1
-
-MY_PN="${PN/-/.}"
-DESCRIPTION="Additional functions used by other projects by developer jaraco"
-HOMEPAGE="https://github.com/jaraco/jaraco.functools"
-SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
-S="${WORKDIR}/${MY_PN}-${PV}"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ppc ppc64 ~riscv sparc x86 ~x64-macos"
-
-RDEPEND="
-	dev-python/more-itertools[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	dev-python/toml[${PYTHON_USEDEP}]
-	dev-python/setuptools_scm[${PYTHON_USEDEP}]
-	test? (
-		dev-python/jaraco-classes[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_sphinx docs \
-	">=dev-python/jaraco-packaging-3.2" \
-	">=dev-python/rst-linker-1.9"
-distutils_enable_tests pytest