1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/multidict/multidict-2.1.5.ebuild b/dev-python/multidict/multidict-2.1.5.ebuild
new file mode 100644
index 000000000000..ffd36de34e32
--- /dev/null
+++ b/dev-python/multidict/multidict-2.1.5.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="multidict implementation"
+HOMEPAGE="https://github.com/aio-libs/multidict/"
+SRC_URI="https://github.com/aio-libs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+RDEPEND=""
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	# Running tests from ${S} fails as follows:
+	#     ImportError: No module named 'multidict._multidict'
+	pushd "${BUILD_DIR}" >/dev/null || die
+	"${PYTHON}" -m pytest "${S}/tests" || die "tests failed under ${EPYTHON}"
+	popd >/dev/null || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}