1 files changed, 0 insertions, 50 deletions
diff --git a/dev-python/multidict/multidict-6.0.4-r1.ebuild b/dev-python/multidict/multidict-6.0.4-r1.ebuild
deleted file mode 100644
index b96ba51c677a..000000000000
--- a/dev-python/multidict/multidict-6.0.4-r1.ebuild
+++ /dev/null
@@ -1,50 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..12} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="multidict implementation"
-HOMEPAGE="
-	https://github.com/aio-libs/multidict/
-	https://pypi.org/project/multidict/
-"
-SRC_URI="
-	https://github.com/aio-libs/${PN}/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
-IUSE="+native-extensions"
-
-distutils_enable_sphinx docs --no-autodoc
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	# don't enable coverage or other pytest settings
-	sed -i -e 's:--cov.*::' setup.cfg || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile() {
-	# the C extension segfaults on py3.12
-	# https://github.com/aio-libs/multidict/issues/868
-	if ! use native-extensions || [[ ${EPYTHON} == python3.12 ]]; then
-		local -x MULTIDICT_NO_EXTENSIONS=1
-	fi
-
-	distutils-r1_python_compile
-}
-
-python_test() {
-	rm -rf multidict || die
-	epytest
-}