1 files changed, 75 insertions, 0 deletions
diff --git a/dev-python/pycairo/pycairo-1.27.0.ebuild b/dev-python/pycairo/pycairo-1.27.0.ebuild
new file mode 100644
index 000000000000..9f44293d3716
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.27.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit meson distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="
+	https://www.cairographics.org/pycairo/
+	https://github.com/pygobject/pycairo/
+	https://pypi.org/project/pycairo/
+"
+SRC_URI="
+	https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz
+"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=x11-libs/cairo-1.15.10[svg(+)]
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+python_compile() {
+	local emesonargs=(
+		# TODO: move that to the eclass?
+		-Dpython.bytecompile=2
+		-Dtests="$(usex test true false)"
+	)
+
+	meson_src_configure
+	meson_src_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install() {
+	meson_src_install
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}