1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/pyftpdlib/pyftpdlib-1.5.1.ebuild b/dev-python/pyftpdlib/pyftpdlib-1.5.1.ebuild
new file mode 100644
index 000000000000..a176fa4b0a4d
--- /dev/null
+++ b/dev-python/pyftpdlib/pyftpdlib-1.5.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} pypy )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python FTP server library"
+HOMEPAGE="https://github.com/giampaolo/pyftpdlib https://pypi.org/project/pyftpdlib/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris"
+IUSE="examples ssl test"
+
+RDEPEND="ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}] )"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND} )
+"
+
+python_test() {
+	"${EPYTHON}" ${PN}/test/runner.py || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r demo/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] && \
+		[[ ${PYTHON_TARGETS} == *python2_7* ]] && \
+		! has_version dev-python/pysendfile ; then
+		elog "dev-python/pysendfile is not installed"
+		elog "It can considerably speed up file transfers for Python 2"
+	fi
+}