1 files changed, 39 insertions, 0 deletions
diff --git a/dev-python/reedsolo/reedsolo-2.1.1_beta1-r1.ebuild b/dev-python/reedsolo/reedsolo-2.1.1_beta1-r1.ebuild
new file mode 100644
index 000000000000..715acdcf1fbf
--- /dev/null
+++ b/dev-python/reedsolo/reedsolo-2.1.1_beta1-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python Reed Solomon encoder/decoder"
+HOMEPAGE="
+	https://github.com/tomerfiliba-org/reedsolomon/
+	https://pypi.org/project/reedsolo/
+"
+
+LICENSE="|| ( Unlicense MIT-0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="+native-extensions"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/pytest-cov/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	local DISTUTILS_ARGS=()
+	if use native-extensions && [[ ${EPYTHON} != pypy3 ]] ; then
+		DISTUTILS_ARGS+=(
+			# TODO: switch to --cythonize once we're on cython-3
+			--native-compile
+		)
+	fi
+	distutils-r1_python_compile
+}