summaryrefslogtreecommitdiff
path: root/dev-python
diff options
context:
space:
mode:
Diffstat (limited to 'dev-python')
-rw-r--r--dev-python/PyGithub/PyGithub-1.43.7.ebuild47
-rw-r--r--dev-python/aiorpcX/aiorpcX-0.17.0.ebuild26
-rw-r--r--dev-python/aiorpcX/aiorpcX-0.18.3.ebuild26
-rw-r--r--dev-python/deprecated/Manifest3
-rw-r--r--dev-python/deprecated/deprecated-1.2.5.ebuild27
-rw-r--r--dev-python/deprecated/metadata.xml11
-rw-r--r--dev-python/fido2/fido2-0.7.0.ebuild49
-rw-r--r--dev-python/google-pasta/google-pasta-0.1.7.ebuild20
-rw-r--r--dev-python/httpretty/httpretty-0.9.6.ebuild43
-rw-r--r--dev-python/protobuf-python/protobuf-python-3.8.0.ebuild64
-rw-r--r--dev-python/pygresql/pygresql-5.1.ebuild35
-rw-r--r--dev-python/sure/sure-1.4.11.ebuild32
-rw-r--r--dev-python/unidecode/unidecode-1.1.1.ebuild29
-rw-r--r--dev-python/vine/vine-1.3.0.ebuild27
-rw-r--r--dev-python/wrapt/wrapt-1.11.2.ebuild46
15 files changed, 485 insertions, 0 deletions
diff --git a/dev-python/PyGithub/PyGithub-1.43.7.ebuild b/dev-python/PyGithub/PyGithub-1.43.7.ebuild
new file mode 100644
index 000000000000..5585ba44ef02
--- /dev/null
+++ b/dev-python/PyGithub/PyGithub-1.43.7.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library to access the Github API v3"
+HOMEPAGE="https://github.com/PyGithub/PyGithub/"
+# Use github since pypi is missing test data
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/deprecated[${PYTHON_USEDEP}]
+ dev-python/pyjwt[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.14.0[${PYTHON_USEDEP}]"
+DEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/httpretty[${PYTHON_USEDEP}]
+ )"
+
+python_prepare_all() {
+ # tests requiring network access
+ sed -i -e 's:testDecodeJson:_&:' tests/Issue142.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ # silly!
+ cp -r tests "${BUILD_DIR}" || die
+ if python_is_python3; then
+ 2to3 --no-diffs -n -w "${BUILD_DIR}"/tests || die
+ fi
+
+ cd "${BUILD_DIR}" || die
+ "${EPYTHON}" -m unittest -v tests.AllTests || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/aiorpcX/aiorpcX-0.17.0.ebuild b/dev-python/aiorpcX/aiorpcX-0.17.0.ebuild
new file mode 100644
index 000000000000..b87a61bb4dd1
--- /dev/null
+++ b/dev-python/aiorpcX/aiorpcX-0.17.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_6,3_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Generic async RPC implementation, including JSON-RPC"
+HOMEPAGE="https://pypi.org/project/aiorpcX/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+ >=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+DOCS=( README.rst )
diff --git a/dev-python/aiorpcX/aiorpcX-0.18.3.ebuild b/dev-python/aiorpcX/aiorpcX-0.18.3.ebuild
new file mode 100644
index 000000000000..b87a61bb4dd1
--- /dev/null
+++ b/dev-python/aiorpcX/aiorpcX-0.18.3.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_6,3_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Generic async RPC implementation, including JSON-RPC"
+HOMEPAGE="https://pypi.org/project/aiorpcX/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+ >=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+DOCS=( README.rst )
diff --git a/dev-python/deprecated/Manifest b/dev-python/deprecated/Manifest
new file mode 100644
index 000000000000..4cfe25bc520c
--- /dev/null
+++ b/dev-python/deprecated/Manifest
@@ -0,0 +1,3 @@
+DIST deprecated-1.2.5.gh.tar.gz 5038752 BLAKE2B 82ceadca4ccef4309b2a7d493620cc8a4dd9160ab7449a3019c9e9bc3a99e8016b6125d4165b71813d9543b7629d55372affdbd14ad2c71d101061595bdb677c SHA512 3a16b5d4f2475788ce919c327b668bb8852dab88adfa959826c9b68ccbfba3207a1c60ca164edacde8a756bd3895225af944a51eebde1230a93a973145231234
+EBUILD deprecated-1.2.5.ebuild 656 BLAKE2B 9763106db3ce5682550668baa7e5bc03ed271fa8dd115ebde5baaf7cb20016235a0b7e36794468db0264567ad1c64f0e87f2c45e7e3efe626c41e0cde49acbe5 SHA512 58a383055c50ade947e689f9b0ad529d7ee77f40b5d3e50f05a5d80928a022cce56e11f0bb597abc93303643630cf371a5ac304fb52d08d6473471b6ef72503d
+MISC metadata.xml 326 BLAKE2B 465cb8f46170cfced4ed1ba3af61210b58fba1c1fe0af7f5f9b5d498f1a32993ff19f860231ac84b5f6661a67cc7837aa8a19b81afc108cd44e5d836f3fb93e3 SHA512 19656915996f8905a7c2ea398da098d5ae704445273471730c82c3bc391d4662a6e7fe8bf9b416ce23d3c171008d93bd6b462fe278c7bef64b304b2e467d894a
diff --git a/dev-python/deprecated/deprecated-1.2.5.ebuild b/dev-python/deprecated/deprecated-1.2.5.ebuild
new file mode 100644
index 000000000000..4f502db5e1b9
--- /dev/null
+++ b/dev-python/deprecated/deprecated-1.2.5.ebuild
@@ -0,0 +1,27 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+inherit distutils-r1
+
+DESCRIPTION="Python @deprecated decorator to deprecate old API"
+HOMEPAGE="https://github.com/tantale/deprecated"
+SRC_URI="https://github.com/tantale/deprecated/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="dev-python/wrapt[${PYTHON_USEDEP}]"
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ dev-python/pytest[${PYTHON_USEDEP}]
+ )"
+
+python_test() {
+ pytest -vv || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/deprecated/metadata.xml b/dev-python/deprecated/metadata.xml
new file mode 100644
index 000000000000..22e0d6d87f61
--- /dev/null
+++ b/dev-python/deprecated/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+ <email>mgorny@gentoo.org</email>
+ <name>Michał Górny</name>
+ </maintainer>
+ <maintainer type="project">
+ <email>python@gentoo.org</email>
+ </maintainer>
+</pkgmetadata>
diff --git a/dev-python/fido2/fido2-0.7.0.ebuild b/dev-python/fido2/fido2-0.7.0.ebuild
new file mode 100644
index 000000000000..bc1d3938cb32
--- /dev/null
+++ b/dev-python/fido2/fido2-0.7.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{5,6}} )
+inherit distutils-r1
+
+DESCRIPTION="Python based FIDO 2.0 library"
+HOMEPAGE="https://github.com/Yubico/python-fido2"
+SRC_URI="https://github.com/Yubico/python-fido2/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="Apache-2.0 BSD-2 MIT MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+RDEPEND="
+ dev-python/six[${PYTHON_USEDEP}]
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/pyscard[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python2_7)
+ examples? (
+ dev-python/flask[${PYTHON_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ )
+"
+DEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/pyfakefs[${PYTHON_USEDEP}]
+ )
+"
+
+python_test() {
+ esetup.py test
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ if use examples; then
+ docinto examples
+ dodoc -r "${S}"/examples/.
+ docompress -x "/usr/share/doc/${PF}/examples"
+ fi
+}
diff --git a/dev-python/google-pasta/google-pasta-0.1.7.ebuild b/dev-python/google-pasta/google-pasta-0.1.7.ebuild
new file mode 100644
index 000000000000..6baf55a5779d
--- /dev/null
+++ b/dev-python/google-pasta/google-pasta-0.1.7.ebuild
@@ -0,0 +1,20 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python{3_5,3_6,3_7} )
+inherit distutils-r1
+
+DESCRIPTION="AST-based Python refactoring library"
+HOMEPAGE="https://pypi.org/project/google-pasta/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+BDEPEND="${RDEPEND}
+ dev-python/setuptools[${PYTHON_USEDEP}]"
diff --git a/dev-python/httpretty/httpretty-0.9.6.ebuild b/dev-python/httpretty/httpretty-0.9.6.ebuild
new file mode 100644
index 000000000000..f65d19098d48
--- /dev/null
+++ b/dev-python/httpretty/httpretty-0.9.6.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP client mock for Python"
+HOMEPAGE="https://github.com/gabrielfalcao/httpretty"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/six[${PYTHON_USEDEP}]
+ dev-python/urllib3[${PYTHON_USEDEP}]"
+DEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ >=dev-python/nose-1.2[${PYTHON_USEDEP}]
+ >=dev-python/mock-1.0[${PYTHON_USEDEP}]
+ dev-python/sure[${PYTHON_USEDEP}]
+ dev-python/httplib2[${PYTHON_USEDEP}]
+ >=dev-python/requests-1.1[${PYTHON_USEDEP}]
+ >=www-servers/tornado-2.2[${PYTHON_USEDEP}]
+)"
+
+python_prepare_all() {
+ # remove useless deps
+ sed -i -e '/randomly/d' -e '/rednose/d' setup.cfg || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ nosetests -v tests || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/protobuf-python/protobuf-python-3.8.0.ebuild b/dev-python/protobuf-python/protobuf-python-3.8.0.ebuild
new file mode 100644
index 000000000000..f222111ba2da
--- /dev/null
+++ b/dev-python/protobuf-python/protobuf-python-3.8.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2008-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# True Authors: Arfrever Frehtes Taifersar Arahesis and others
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_5,3_6,3_7})
+
+inherit distutils-r1
+
+if [[ "${PV}" == "9999" ]]; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
+ EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="Google's Protocol Buffers - Python bindings"
+HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/protocolbuffers/protobuf"
+if [[ "${PV}" == "9999" ]]; then
+ SRC_URI=""
+else
+ SRC_URI="https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+fi
+
+LICENSE="BSD"
+SLOT="0/19"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+ ~dev-libs/protobuf-${PV}
+ dev-python/namespace-google[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${PYTHON_DEPS}
+ ~dev-libs/protobuf-${PV}"
+RDEPEND="${BDEPEND}
+ !<dev-libs/protobuf-3[python(-)]"
+
+S="${WORKDIR}/protobuf-${PV}/python"
+
+if [[ "${PV}" == "9999" ]]; then
+ EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
+fi
+
+python_configure_all() {
+ mydistutilsargs=(--cpp_implementation)
+}
+
+python_compile() {
+ python_is_python3 || local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+ distutils-r1_python_compile
+}
+
+python_test() {
+ esetup.py test
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ find "${D}" -name "*.pth" -delete || die
+}
diff --git a/dev-python/pygresql/pygresql-5.1.ebuild b/dev-python/pygresql/pygresql-5.1.ebuild
new file mode 100644
index 000000000000..1f1d7861a4f3
--- /dev/null
+++ b/dev-python/pygresql/pygresql-5.1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+POSTGRES_COMPAT=( 9.{4..6} {10..11} )
+PYTHON_COMPAT=( python2_7 python3_{5..7} )
+
+inherit distutils-r1 postgres
+
+MY_P="PyGreSQL-${PV}"
+
+DESCRIPTION="A Python interface for the PostgreSQL database"
+HOMEPAGE="http://www.pygresql.org/"
+SRC_URI="mirror://pypi/P/PyGreSQL/${MY_P}.tar.gz"
+
+LICENSE="POSTGRESQL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~sparc ~x86"
+
+DEPEND="${POSTGRES_DEP}"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+ sed "s/, '-Wall'//" -i setup.py || die
+ default
+}
+
+python_install_all() {
+ local DOCS=( docs/*.rst docs/community/* docs/contents/tutorial.rst )
+
+ distutils-r1_python_install_all
+}
diff --git a/dev-python/sure/sure-1.4.11.ebuild b/dev-python/sure/sure-1.4.11.ebuild
new file mode 100644
index 000000000000..550d962c8cb9
--- /dev/null
+++ b/dev-python/sure/sure-1.4.11.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="idiomatic assertion toolkit with human-friendly failure messages"
+HOMEPAGE="https://github.com/gabrielfalcao/sure"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/mock[${PYTHON_USEDEP}]
+ >=dev-python/nose-1.3.0[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? ( ${RDEPEND} )
+"
+
+python_test() {
+ nosetests -v tests || die "Tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/unidecode/unidecode-1.1.1.ebuild b/dev-python/unidecode/unidecode-1.1.1.ebuild
new file mode 100644
index 000000000000..5cdc5ae57905
--- /dev/null
+++ b/dev-python/unidecode/unidecode-1.1.1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+PYTHON_REQ_USE="wide-unicode(+)"
+
+MY_PN=Unidecode
+MY_P=${MY_PN}-${PV}
+
+inherit distutils-r1
+
+DESCRIPTION="Module providing ASCII transliterations of Unicode text"
+HOMEPAGE="https://pypi.org/project/Unidecode/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+
+S=${WORKDIR}/${MY_P}
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+
+python_test() {
+ esetup.py test
+}
diff --git a/dev-python/vine/vine-1.3.0.ebuild b/dev-python/vine/vine-1.3.0.ebuild
new file mode 100644
index 000000000000..5123b36f2266
--- /dev/null
+++ b/dev-python/vine/vine-1.3.0.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Promises"
+HOMEPAGE="https://pypi.org/project/vine/ https://github.com/celery/vine"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="test"
+
+RDEPEND=""
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ >=dev-python/case-1.3.1[${PYTHON_USEDEP}]
+ >=dev-python/pytest-3.0[${PYTHON_USEDEP}]
+ )"
+
+python_test() {
+ esetup.py test
+}
diff --git a/dev-python/wrapt/wrapt-1.11.2.ebuild b/dev-python/wrapt/wrapt-1.11.2.ebuild
new file mode 100644
index 000000000000..fb3261b28fc7
--- /dev/null
+++ b/dev-python/wrapt/wrapt-1.11.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Module for decorators, wrappers and monkey patching"
+HOMEPAGE="https://github.com/GrahamDumpleton/wrapt"
+SRC_URI="https://github.com/GrahamDumpleton/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+DEPEND="
+ test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+ doc? (
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+ )
+"
+RDEPEND=""
+
+python_compile_all() {
+ use doc && emake -C docs html
+}
+
+python_compile() {
+ local WRAPT_EXTENSIONS=true
+
+ distutils-r1_python_compile
+}
+
+python_test() {
+ py.test -vv || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+ use doc && local HTML_DOCS=( docs/_build/html/. )
+
+ distutils-r1_python_install_all
+}
generated by cgit v1.2.3 (git 2.25.1) at 2025-04-01 23:44:45 +0000