1 files changed, 42 insertions, 0 deletions
diff --git a/dev-ruby/launchy/launchy-3.0.0.ebuild b/dev-ruby/launchy/launchy-3.0.0.ebuild
new file mode 100644
index 000000000000..8c308b3654cb
--- /dev/null
+++ b/dev-ruby/launchy/launchy-3.0.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_EXTRADOC="README.md HISTORY.md"
+
+inherit ruby-fakegem virtualx
+
+DESCRIPTION="Helper class for launching cross-platform applications"
+HOMEPAGE="https://github.com/copiousfreetime/launchy"
+
+LICENSE="ISC"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+
+ruby_add_rdepend "
+	>=dev-ruby/addressable-2.8
+	dev-ruby/childprocess:5
+	!<dev-ruby/launchy-2.5.2
+"
+
+ruby_add_bdepend "test? ( >=dev-ruby/minitest-5.0:5 )"
+
+all_ruby_prepare() {
+	sed -i -e "/[Ss]implecov/d" spec/spec_helper.rb || die
+
+	# Avoid tests depending on the current user's desktop environment.
+	sed -e '/returns NotFound if it cannot determine/askip "gentoo"' \
+		-i spec/detect/nix_desktop_environment_spec.rb || die
+	sed -e '/asssumes we open a local file if we have an exception/askip "gentoo"' \
+		-i spec/launchy_spec.rb || die
+	sed -e "/'darwin'/ s:^:#:" \
+		-i spec/applications/browser_spec.rb || die
+}
+
+each_ruby_test() {
+	CI=true virtx each_fakegem_test
+}