1 files changed, 61 insertions, 0 deletions
diff --git a/dev-util/cunit/cunit-2.1_p3-r1.ebuild b/dev-util/cunit/cunit-2.1_p3-r1.ebuild
new file mode 100644
index 000000000000..1c4e3118cc87
--- /dev/null
+++ b/dev-util/cunit/cunit-2.1_p3-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic multilib-minimal toolchain-funcs
+
+MY_PN="CUnit"
+MY_PV="${PV/_p*}-3"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="C Unit Test Framework"
+HOMEPAGE="http://cunit.sourceforge.net"
+SRC_URI="mirror://sourceforge/cunit/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="ncurses static-libs"
+
+RDEPEND="ncurses? ( >=sys-libs/ncurses-5.9-r3:0=[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.1_p3-ncurses-format-security.patch
+)
+
+src_prepare() {
+	default
+
+	sed -e "/^docdir/d" -i doc/Makefile.am || die
+	sed -e '/^dochdrdir/{s:$(prefix)/doc/@PACKAGE@:$(docdir):}' \
+		-i doc/headers/Makefile.am || die
+	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.in || die
+
+	mv configure.{in,ac} || die
+	eautoreconf
+
+	append-cppflags -D_BSD_SOURCE
+
+	# unable to find headers otherwise
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local LIBS=${LIBS}
+	append-libs $($(tc-getPKG_CONFIG) --libs ncurses)
+
+	econf \
+		$(use_enable static-libs static) \
+		--disable-debug \
+		$(use_enable ncurses curses)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -type f -delete || die
+}