5 files changed, 203 insertions, 0 deletions
diff --git a/dev-util/Manifest.gz b/dev-util/Manifest.gz
index 7c783c5ea558..df7fd82f83db 100644
--- a/dev-util/Manifest.gz
+++ b/dev-util/Manifest.gz
diff --git a/dev-util/gdbus-codegen/Manifest b/dev-util/gdbus-codegen/Manifest
index 6b3229c00e83..c3588f2e5723 100644
--- a/dev-util/gdbus-codegen/Manifest
+++ b/dev-util/gdbus-codegen/Manifest
@@ -9,4 +9,5 @@ EBUILD gdbus-codegen-2.78.6.ebuild 2318 BLAKE2B 537e2e7c3c4e39413ebeaef33885c11b
 EBUILD gdbus-codegen-2.80.5.ebuild 2221 BLAKE2B df96ec7c2b8166701044b648e530be6b66d91528b4f5398b9ecd9b54641d82c56ce6b3b294a1fa2a7b2df2b15da79fd06d341c87593bdeabf7ae1c10d2e273e8 SHA512 17fdd3890e4b3d7ea0b5df0016c51f271493726335a1675e7d7eedf2ef101ec454246a7c2501dc328ef22cfd05225eb563ad4dee36914a994d41ca55401a4c0d
 EBUILD gdbus-codegen-2.82.5.ebuild 2221 BLAKE2B df96ec7c2b8166701044b648e530be6b66d91528b4f5398b9ecd9b54641d82c56ce6b3b294a1fa2a7b2df2b15da79fd06d341c87593bdeabf7ae1c10d2e273e8 SHA512 17fdd3890e4b3d7ea0b5df0016c51f271493726335a1675e7d7eedf2ef101ec454246a7c2501dc328ef22cfd05225eb563ad4dee36914a994d41ca55401a4c0d
 EBUILD gdbus-codegen-2.84.0-r1.ebuild 2252 BLAKE2B 00ee347c8823d2e82bf27e19fb2122046ad79e8736003bc15470a471e6405e7fb8e2cf0f07b5161726f2114e82c65643222604ed5d8b8e67145d1ed53f515959 SHA512 a780c8c6d94490d881c1a3031889f1a15f20cd34e735ce03faac12bf07b5a05e03e3d65e22469691ca496e3a19ab4bba3cf893b332cd6361d71c6efc09e5342f
+EBUILD gdbus-codegen-2.84.0-r2.ebuild 2252 BLAKE2B becaca128f530e1d5cfb89c2de9dceddd61ca8e3b458b60cc75c4b9c1092d73e88f939d1cd975056abe3bb341fa0f995b826a67e0edf3d737bd5dc4a7cd0b21d SHA512 8ef862e1603bafae2e0aacfe57650fa76e2227236a8d17adef858a4caa91f0f788d9eef29f7c197fc59305bc4da91c3840a543255206d456227e9c8c1941c8bb
 MISC metadata.xml 345 BLAKE2B 91a0526be5ce32d4aa4ea0827c78b2d2d45beae9a8d467916448a0a6b5459fd457e44ac900182654826328b34d37999bedb3ade42e80db92312e50f34d940014 SHA512 b11e427345fab56c77cb1f4f96473645b69054012e86840e2ca7dab221cf55041a1add1dfabce155274acf18488ac79de8149d405213daf39b807f679d4ac752
diff --git a/dev-util/gdbus-codegen/gdbus-codegen-2.84.0-r2.ebuild b/dev-util/gdbus-codegen/gdbus-codegen-2.84.0-r2.ebuild
new file mode 100644
index 000000000000..0c7b74283273
--- /dev/null
+++ b/dev-util/gdbus-codegen/gdbus-codegen-2.84.0-r2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+GNOME_ORG_MODULE="glib"
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="xml(+)"
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+
+inherit gnome.org distutils-r1
+
+DESCRIPTION="GDBus code and documentation generator"
+HOMEPAGE="https://www.gtk.org/"
+
+S="${WORKDIR}/glib-${PV}/gio/gdbus-2.0/codegen"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-${PV}
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	>=dev-python/docutils-0.21.1
+"
+
+python_prepare_all() {
+	PATCHES=(
+		"${FILESDIR}/${PN}-2.56.1-sitedir.patch"
+	)
+	distutils-r1_python_prepare_all
+
+	local MAJOR_VERSION=$(ver_cut 1)
+	local MINOR_VERSION=$(ver_cut 2)
+	sed -e 's:@PYTHON@:python:' gdbus-codegen.in > gdbus-codegen || die
+	sed -e "s:@VERSION@:${PV}:" \
+		-e "s:@MAJOR_VERSION@:${MAJOR_VERSION}:" \
+		-e "s:@MINOR_VERSION@:${MINOR_VERSION}:" config.py.in > config.py || die
+	cp "${FILESDIR}/setup.py-2.32.4" setup.py || die "cp failed"
+	sed -e "s/@PV@/${PV}/" -i setup.py || die "sed setup.py failed"
+}
+
+do_xsltproc_command() {
+	# Taken from meson.build for manual manpage building - keep in sync (also copied to dev-util/glib-utils)
+	xsltproc \
+		--nonet \
+		--stringparam man.output.quietly 1 \
+		--stringparam funcsynopsis.style ansi \
+		--stringparam man.th.extra1.suppress 1 \
+		--stringparam man.authors.section.enabled 0 \
+		--stringparam man.copyright.section.enabled 0 \
+		-o "${2}" \
+		http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl \
+		"${1}" || die "manpage generation failed"
+}
+
+src_compile() {
+	distutils-r1_src_compile
+	rst2man \
+		"${WORKDIR}/glib-${PV}/docs/reference/gio/gdbus-codegen.rst" \
+		"${WORKDIR}/glib-${PV}/docs/reference/gio/gdbus-codegen.1"
+}
+
+src_test() {
+	einfo "Skipping tests. This package is tested by dev-libs/glib"
+	einfo "when merged with FEATURES=test"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all # no-op, but prevents QA warning
+	doman "${WORKDIR}/glib-${PV}/docs/reference/gio/gdbus-codegen.1"
+}
diff --git a/dev-util/pkgcruft/Manifest b/dev-util/pkgcruft/Manifest
index 4fc47e9693e9..b93d700c72a5 100644
--- a/dev-util/pkgcruft/Manifest
+++ b/dev-util/pkgcruft/Manifest
@@ -1,4 +1,6 @@
 DIST pkgcruft-0.0.10.tar.xz 32193612 BLAKE2B d0f28f63e0b4f1d1309156309331feb0daa0cd52c6f0491f918d49f76c425b36a47fd02060554cd4398ac3490d6e21009b7421cb0ca14a821093fca7f57087bc SHA512 14812be27345a737d91281c869bc8149581bf3802b3bddca19908bfb687013cd1ee751213e86c7c277850f07eff2b58358930c74cbe2e3f4b370929de518097e
+DIST pkgcruft-0.0.11.tar.xz 40812256 BLAKE2B 6afbc3750d99d715a01d644413b4e5c407d902cbb1761b5017dae0cf5b868a48f6fe5a8ee845bb8e4484cc9ea154d954afc85cd81d53480eee1233598a07a044 SHA512 b4ba070b811e1a94795bd8e90452b4e2db6fba53a563b828c8f8c6b938727ed6aff35e969c88a22b961ded1bd51847f52f1d285863a27b76715fe1ec72979934
 EBUILD pkgcruft-0.0.10.ebuild 2928 BLAKE2B 965b6a456af8285664f46960b5ddfd7690944259e17bd7575cb4972da57a99528133658ba2c99d59029e9c977b8c563a6163619e268126c66c0845824de1e180 SHA512 c9fde1ae0a1ca37d1dfa751cac12c215a1baef620368ac1fa123ece0e6653cf54d8e4eed09c5a20bac5a6a48b7a37055b184ea3507224eee1bbce2f7181913f0
+EBUILD pkgcruft-0.0.11.ebuild 2929 BLAKE2B 0be9d003042d52aa73c7ede8464bba3728091582dea8b741a27a8b70dd61f506cad5d566f106806f3b6b5bd24e97a4e322ee41c52425d3c508fc8d8528cb24d0 SHA512 0f66f5744e6b7cc570c97c0479429808c9e29f8b45b5feafc484fd18b262aef8dd61863f209a4d6378a189b90a2a016eaa51d5b4984402c07e8c7cf29d6a045a
 EBUILD pkgcruft-9999.ebuild 2929 BLAKE2B 0be9d003042d52aa73c7ede8464bba3728091582dea8b741a27a8b70dd61f506cad5d566f106806f3b6b5bd24e97a4e322ee41c52425d3c508fc8d8528cb24d0 SHA512 0f66f5744e6b7cc570c97c0479429808c9e29f8b45b5feafc484fd18b262aef8dd61863f209a4d6378a189b90a2a016eaa51d5b4984402c07e8c7cf29d6a045a
 MISC metadata.xml 322 BLAKE2B b0ee0fc53eb8b4b485f74806a78b5560aaf53f1772d7bd3e5af4e03385b3f3aed18fc52462c2d49de6c0d735db0cae3fab175b8adc0e5f7c4baa89e28973776f SHA512 9343cd5028750182fe9325c44f4c4c7df0976b79e0422b66e0fd16f94be76eaa203e8ecad5ec2cbed3535f455f038e51968850ced9afb27af9a98b6b968df88a
diff --git a/dev-util/pkgcruft/pkgcruft-0.0.11.ebuild b/dev-util/pkgcruft/pkgcruft-0.0.11.ebuild
new file mode 100644
index 000000000000..911e226eef4d
--- /dev/null
+++ b/dev-util/pkgcruft/pkgcruft-0.0.11.ebuild
@@ -0,0 +1,122 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES=" "
+LLVM_COMPAT=( {17..19} )
+RUST_MIN_VER="1.82.0"
+
+inherit cargo edo llvm-r2 multiprocessing shell-completion toolchain-funcs
+
+DESCRIPTION="QA library and tools based on pkgcraft"
+HOMEPAGE="https://pkgcraft.github.io/"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/pkgcraft/pkgcraft"
+	inherit git-r3
+
+	S="${WORKDIR}"/${P}/crates/${PN}
+else
+	SRC_URI="https://github.com/pkgcraft/pkgcraft/releases/download/${P}/${P}.tar.xz"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 BSD-2 BSD CC0-1.0 GPL-3+ ISC MIT MPL-2.0 Unicode-DFS-2016
+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# clang needed for bindgen
+BDEPEND+="
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}
+	')
+	test? ( dev-util/cargo-nextest )
+"
+
+QA_FLAGS_IGNORED="usr/bin/pkgcruft"
+
+pkg_setup() {
+	llvm-r2_pkg_setup
+	rust_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == 9999 ]] ; then
+		git-r3_src_unpack
+		cargo_live_src_unpack
+	else
+		cargo_src_unpack
+	fi
+}
+
+src_compile() {
+	# For scallop building bash
+	tc-export AR CC
+
+	cargo_src_compile
+
+	if [[ ${PV} == 9999 ]] ; then
+		# https://github.com/pkgcraft/pkgcraft/issues/258
+		edo cargo run --features shell --bin pkgcruft-shell-comp -p pkgcruft
+	fi
+}
+
+src_test() {
+	unset CLICOLOR CLICOLOR_FORCE
+
+	# TODO: Maybe move into eclass (and maybe have a cargo_enable_tests
+	# helper)
+	local -x NEXTEST_TEST_THREADS="$(makeopts_jobs)"
+
+	# The test failures appear ebuild-related
+	edo cargo nextest run $(usev !debug '--release') \
+		--color always \
+		--all-features \
+		--tests \
+		--no-fail-fast \
+		-- \
+		--skip 'commands::tests::check' \
+		--skip 'dependency::tests::check' \
+		--skip 'dependency_slot_missing::tests::check' \
+		--skip 'eapi_stale::tests::check' \
+		--skip 'eapi_status::tests::check' \
+		--skip 'ebuild_name::tests::check' \
+		--skip 'eclass::tests::check' \
+		--skip 'filesdir::tests::check' \
+		--skip 'header::tests::check' \
+		--skip 'homepage::tests::check' \
+		--skip 'ignore::tests::check' \
+		--skip 'iuse::tests::check' \
+		--skip 'keywords::tests::check' \
+		--skip 'keywords_dropped::tests::check' \
+		--skip 'license::tests::check' \
+		--skip 'live::tests::check' \
+		--skip 'manifest::tests::check' \
+		--skip 'metadata::tests::check' \
+		--skip 'properties::tests::check' \
+		--skip 'python_update::tests::check' \
+		--skip 'repo_layout::tests::check' \
+		--skip 'restrict::tests::check' \
+		--skip 'restrict_test_missing::tests::check' \
+		--skip 'ruby_update::tests::check' \
+		--skip 'src_uri::tests::check' \
+		--skip 'unstable_only::tests::check' \
+		--skip 'use_local::tests::check' \
+		--skip 'variable_order::tests::check' \
+		--skip 'whitespace::tests::check'
+}
+
+src_install() {
+	cargo_src_install
+
+	newbashcomp shell/pkgcruft.bash ${PN}
+	dozshcomp shell/_pkgcruft
+	dofishcomp shell/pkgcruft.fish
+}