1 files changed, 51 insertions, 0 deletions
diff --git a/games-action/gltron/gltron-0.70-r1.ebuild b/games-action/gltron/gltron-0.70-r1.ebuild
new file mode 100644
index 000000000000..ec112c045e75
--- /dev/null
+++ b/games-action/gltron/gltron-0.70-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils games
+
+DESCRIPTION="3d tron, just like the movie"
+HOMEPAGE="http://gltron.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-source.tar.gz
+	mirror://gentoo/${PN}.png"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE=""
+
+DEPEND="virtual/opengl
+	media-libs/libpng:0
+	media-libs/libsdl[sound,video]
+	media-libs/sdl-mixer[vorbis]
+	media-libs/sdl-sound[vorbis,mikmod]
+	media-libs/smpeg
+	media-libs/libmikmod"
+RDEPEND=${DEPEND}
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-configure.patch \
+		"${FILESDIR}"/${P}-prototypes.patch \
+		"${FILESDIR}"/${P}-debian.patch \
+		"${FILESDIR}"/${P}-gcc49.patch
+	sed -i \
+		-e '/^gltron_LINK/s/$/ $(LDFLAGS)/' \
+		Makefile.in || die
+}
+
+src_configure() {
+	# warn/debug/profile just modify CFLAGS, they aren't
+	# real options, so don't utilize USE flags here
+	egamesconf \
+		--disable-warn \
+		--disable-debug \
+		--disable-profile
+}
+
+src_install() {
+	default
+	doicon "${DISTDIR}"/${PN}.png
+	make_desktop_entry ${PN} GLtron
+	prepgamesdirs
+}