3 files changed, 113 insertions, 0 deletions
diff --git a/games-strategy/lgeneral/Manifest b/games-strategy/lgeneral/Manifest
new file mode 100644
index 000000000000..a4304e1f2633
--- /dev/null
+++ b/games-strategy/lgeneral/Manifest
@@ -0,0 +1,4 @@
+DIST lgeneral-1.3.1.tar.gz 1678892 BLAKE2B 701b22a8967c037e2385a1f1bbb2e91703cbffc7fff6383f3d593fab07dc01fa352f9ec3ee25dfbbdd5172c4e8cd804bd7f9fa2a84a3c6a22f581884c8d7d9d9 SHA512 4eb8fc6d1dc134792893f3f9b23833da75412fafefea66d699a27de1954d3c1338c7e5dedef842537303368387797ecea2158a477fe1d018e3af973dd5b755e5
+DIST pg-data.tar.gz 410454 BLAKE2B 70b325636c43b69b7cdc2f074a0ac49af46db5c60ebeea5ecefaae18169509b05b4c452c34e8b0cd483d3565c54191623ff3eb900f24683252fd8c775ecdf847 SHA512 b0df30dd9a9d0652acd8702d601c489e5d3a030854ceeb173d2daa656c00633a78a3f45814da9f4157b86544dec34eda02495742242653c7cdebba5ec9951516
+EBUILD lgeneral-1.3.1-r2.ebuild 1922 BLAKE2B 743229424c55bc5581c30bcccf727efe5720294f8449e58113acf4a3b83a4a5c101430aad7ac12c0a1fbea35a053e93b5f05138b3a5d36ab22d9a662d2a86ee2 SHA512 5edbe0077b8fcca017235986c57c481ac88798494830015feaf57efee555614562fab26f17a51b9cd65621846e906ccac8e8657956af76db3e48c0ddefd10585
+MISC metadata.xml 331 BLAKE2B ed6b281fa54a304ddd752e6bda476635922a0d9be37524a0e988666502279b85c793d455de63929c93e02f5b105367b78bea2eeb004e1a996d558159fe6443e2 SHA512 eef1e23a9d81b81e39f84ba41d70d39bf11f52acad42dc312548239919b7ce359a671f9b76dcdee92be92bc11c798d9031f3a641c13ab6febfe5bd978a4bbeeb
diff --git a/games-strategy/lgeneral/lgeneral-1.3.1-r2.ebuild b/games-strategy/lgeneral/lgeneral-1.3.1-r2.ebuild
new file mode 100644
index 000000000000..bc431e1c2933
--- /dev/null
+++ b/games-strategy/lgeneral/lgeneral-1.3.1-r2.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools desktop gnome2-utils
+
+MY_P="${P/_/}"
+MY_P="${MY_P/beta/beta-}"
+DESCRIPTION="A Panzer General clone written in SDL"
+HOMEPAGE="http://lgames.sourceforge.net/LGeneral/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz
+	mirror://sourceforge/${PN}/pg-data.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="
+	media-libs/libsdl[sound,video]
+	media-libs/sdl-mixer
+	nls? ( virtual/libintl )
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	sed -i \
+		-e '/desktop_DATA/d' \
+		-e '/icon_DATA/d' \
+		Makefile.am || die
+
+	cp /usr/share/gettext/config.rpath .
+	rm -f missing
+	mv configure.in configure.ac
+	eautoreconf
+
+	# Build a temporary lgc-pg that knows about ${WORKDIR}:
+	cp -pPR "${S}" "${WORKDIR}"/tmp-build || die
+	sed -i \
+		-e "s:@GENTOO_DATADIR@:/usr/share:" \
+		-e "s:@D@::" \
+		{lgc-pg,src}/misc.c || die
+
+	cd "${WORKDIR}"/tmp-build || die
+	sed -i \
+		-e "s:@GENTOO_DATADIR@:/usr/share:" \
+		-e "s:@D@:${D}:" \
+		{lgc-pg,src}/misc.c || die
+}
+
+src_configure() {
+	econf $(use_enable nls)
+
+	# Build the temporary lgc-pg:
+	cd "${WORKDIR}"/tmp-build || die
+	econf \
+		--disable-nls \
+		--datadir="${D}/usr/share"
+}
+
+src_compile() {
+	emake
+
+	# Build the temporary lgc-pg:
+	cd "${WORKDIR}"/tmp-build || die
+	emake
+}
+
+src_install() {
+	default
+	keepdir /usr/share/${PN}/{ai_modules,music,terrain}
+
+	# Generate scenario data:
+	dodir /usr/share/${PN}/gfx/{flags,units,terrain} #413901
+	SDL_VIDEODRIVER=dummy "${WORKDIR}"/tmp-build/lgc-pg/lgc-pg --separate-bridges \
+		-s "${WORKDIR}"/pg-data \
+		-d "${D}"/usr/share/${PN} || die
+
+	doicon -s 48 lgeneral.png
+	make_desktop_entry ${PN} LGeneral
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-strategy/lgeneral/metadata.xml b/games-strategy/lgeneral/metadata.xml
new file mode 100644
index 000000000000..a7f8ed3d65fa
--- /dev/null
+++ b/games-strategy/lgeneral/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="sourceforge">lgeneral</remote-id>
+	</upstream>
+</pkgmetadata>