7 files changed, 343 insertions, 0 deletions
diff --git a/gnome-extra/Manifest.gz b/gnome-extra/Manifest.gz
index 72c803564c8a..9b65f81cf2d8 100644
--- a/gnome-extra/Manifest.gz
+++ b/gnome-extra/Manifest.gz
diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index 99d3899c9b14..9dc1f62ff69d 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -4,8 +4,10 @@ AUX calentry.schema 3661 BLAKE2B 0235e8d98d1367f209a31cc74da9563d53dfc12ca34e020
 DIST evolution-data-server-3.48.4.tar.xz 4906356 BLAKE2B 13cbd21d8f6829d052227d3d328439d5f00a2cda2384ffeace791a563ed8acdcd707729ae032dbdbe16e530b2e6205c006412f1cbaa03e8fb6d669c2c75d67bd SHA512 35bc6653efdb70a110f39499945516408090f101319a3080c87f6e14f886e0f9283225c4c5b6a4c2af418b9928c5eb7fba2d319481c81af1fa87f7dd930f7215
 DIST evolution-data-server-3.50.0.tar.xz 4964568 BLAKE2B 1239bab5563e645ebf3999d1977f5b13fdbb155f70fef85904c0cbc06abba64bf79a1c9417749df1ee2f381a757f06d43e0eea1eb064ef5d6250058d9d66c823 SHA512 30a04721304e4447fbe5dccc6992ca38fd7e4ed4a6f8c846def34ee8097d31db3139b0f3b89a64c59af71b9dcd6108bfcdd60b36098b85ad96aee63f9ed5bba5
 DIST evolution-data-server-3.50.1.tar.xz 4964724 BLAKE2B 9896c4dd69c5ce8272594170ba52ca58fdbdbd11122a8d0a40aeee219137c84dfe1f40e713610485f1bf56e89df6ff7cb94e787dc6019ea68217def5390a502d SHA512 9d15eeb265aa7243d87e8e05c50b329554c1adfda20c175df5b4dd2efc970bb8a8fae95505288584cce0ec95755c5d183e2cd43e71137df9a5aa252bd35c7847
+DIST evolution-data-server-3.50.2.tar.xz 4964152 BLAKE2B 7279a5bcb0399fdcce723336a052dca13efa6f0af6ef7371b7cb8e76fbd7e1b0313e7f677cea530de62a93770c35887fd70bac551338f9a89860e2529b1f1519 SHA512 9e2a34e06a446ae142535072a3d6916e31b7be987b114c111fb0687fa32a3fe4085ba5a09ccd77fb395d107e5c673130dc770bae74a50fdb566c91cd9de85610
 EBUILD evolution-data-server-3.48.4-r1.ebuild 4242 BLAKE2B 0580edc90c0b1f1a82364a1b202d9045ce3bcafe45b4f819171f4029052b31899dfb17cbe0519d03c0d91c6fde97cfdbc68c810c7df030794ead05f98aafdcec SHA512 4e0fc3e3c2f01df64c38f7575b16e1ae7ec75d2ec5344b947a4a9c095c23428b07e19c28362ef04eb7f23af87b1ab448d2067e0f3eabd306de7043fd58fe4467
 EBUILD evolution-data-server-3.50.0-r1.ebuild 4763 BLAKE2B 715942f74bd09ab7228656f6eb009e64900a768b679f4868d877d7396f5dd195625833dcdec7513c05972d488774cd6cb50cac359ae80e222c81d56c614e0158 SHA512 9b020043774bd760765b91d94403f3309c9d8cf0bd00f459046f40a2d6aa4063a404d24340aac0f11b9200a956de26772dae59dd436287b9102b05752eea3c1a
 EBUILD evolution-data-server-3.50.0.ebuild 4289 BLAKE2B db8cf2a8d0e6a96e6d8d72743cd1de0d3928c4e1c9a8b507d135c8308489839a725971c59726f6425654411e974bc96e5f9819f3ecc907da76122e7e13170fce SHA512 6d75489b4e3b92dab6bc1049d181b1e646e2b4bf07807ed098377b04665b785c98c735a1e113c3c82fd2e00d8f0e7c0ee0bfc0078e518db718789c582ec7c64c
 EBUILD evolution-data-server-3.50.1.ebuild 4763 BLAKE2B 715942f74bd09ab7228656f6eb009e64900a768b679f4868d877d7396f5dd195625833dcdec7513c05972d488774cd6cb50cac359ae80e222c81d56c614e0158 SHA512 9b020043774bd760765b91d94403f3309c9d8cf0bd00f459046f40a2d6aa4063a404d24340aac0f11b9200a956de26772dae59dd436287b9102b05752eea3c1a
+EBUILD evolution-data-server-3.50.2.ebuild 4763 BLAKE2B 715942f74bd09ab7228656f6eb009e64900a768b679f4868d877d7396f5dd195625833dcdec7513c05972d488774cd6cb50cac359ae80e222c81d56c614e0158 SHA512 9b020043774bd760765b91d94403f3309c9d8cf0bd00f459046f40a2d6aa4063a404d24340aac0f11b9200a956de26772dae59dd436287b9102b05752eea3c1a
 MISC metadata.xml 1564 BLAKE2B d79ded98c993bf742359631b96c98d119ab777968cc57f0e8f455521ab1d4c59de3f05869abc8abe0476b2be24a1e98b9462969c6d6571f872942c059dc26728 SHA512 7ad29524094d811c5194c6f43e5af130830afb02633cc527db361c66b3edf3890599cbc03734e4c3db57429d1a4fa5072395097d5846402ab7f6ab999107a48c
diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.50.2.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.50.2.ebuild
new file mode 100644
index 000000000000..b819888c92af
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.50.2.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake db-use flag-o-matic gnome2 vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-data-server"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/64-11-21-4-2-27-2-27-4-0" # subslot = libcamel-1.2/libebackend-1.2/libebook-1.2/libebook-contacts-1.2/libecal-2.0/libedata-book-1.2/libedata-cal-2.0/libedataserver-1.2/libedataserverui-1.2/libedataserverui4-1.0 soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ldap kerberos oauth-gtk3 oauth-gtk4 vala +weather"
+REQUIRED_USE="
+	oauth-gtk3? ( gtk )
+	oauth-gtk4? ( gtk )
+	vala? ( introspection )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+# glib-2.70 for build-time optional GPowerProfileMonitor
+RDEPEND="
+	>=app-crypt/libsecret-0.5[crypt]
+	>=dev-db/sqlite-3.7.17:3
+	>=dev-libs/glib-2.70:2
+	>=dev-libs/libical-3.0.8:=[glib,introspection?]
+	>=dev-libs/libxml2-2
+	>=dev-libs/nspr-4.4
+	>=dev-libs/nss-3.9
+	>=net-libs/libsoup-3.1.1:3.0
+	>=dev-libs/json-glib-1.0.4
+
+	dev-libs/icu:=
+	sys-libs/zlib:=
+	virtual/libiconv
+
+	berkdb? ( >=sys-libs/db-4:= )
+	gtk? (
+		>=x11-libs/gtk+-3.20:3
+		>=gui-libs/gtk-4.4:4
+		>=media-libs/libcanberra-0.25[gtk3]
+
+		oauth-gtk3? ( >=net-libs/webkit-gtk-2.34.0:4.1 )
+		oauth-gtk4? ( >=net-libs/webkit-gtk-2.39.90:6 )
+	)
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	kerberos? ( virtual/krb5:= )
+	ldap? ( >=net-nds/openldap-2:= )
+	weather? ( >=dev-libs/libgweather-4.2.0:4= )
+"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend)
+		>=net-libs/libsoup-3.1.1:3.0[vala]
+		dev-libs/libical[vala]
+	)
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gperf
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.14
+		dev-util/gi-docgen
+		app-text/docbook-xml-dtd:4.1.2
+	)
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="!test? ( test )"
+
+pkg_pretend() {
+	if has_version "gnome-extra/evolution-data-server[oauth(-)]" &&
+		! use oauth-gtk3 && ! use oauth-gtk4
+	then
+		ewarn "The previous installed version of gnome-extra/evolution-data-server"
+		ewarn "had USE=oauth enabled that is now split into USE=oauth-gtk3"
+		ewarn "and USE=oauth-gtk4.  Please consider enabling either (or both)"
+		ewarn "of these flags to preserve OAuth2 support."
+	fi
+}
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+	use vala && vala_setup
+	cmake_src_prepare
+	gnome2_src_prepare
+
+	eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
+
+	# Make CMakeLists versioned vala enabled
+	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+	  -e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+	  -i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	# /usr/include/db.h is always db-1 on FreeBSD
+	# so include the right dir in CPPFLAGS
+	use berkdb && append-cppflags "-I$(db_includedir)"
+
+	# phonenumber does not exist in tree
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+#		-DENABLE_GI_DOCGEN=$(usex gtk-doc)
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_INTROSPECTION=$(usex introspection)
+		-DWITH_KRB5=$(usex kerberos)
+		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DWITH_PHONENUMBER=OFF
+		-DENABLE_SMIME=ON
+		-DENABLE_GTK=$(usex gtk)
+		-DENABLE_GTK4=$(usex gtk)
+		-DENABLE_CANBERRA=$(usex gtk)
+		-DENABLE_OAUTH2_WEBKITGTK=$(usex oauth-gtk3)
+		-DENABLE_OAUTH2_WEBKITGTK4=$(usex oauth-gtk4)
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_GOA=$(usex gnome-online-accounts)
+		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+		# ENABLE_BACKTRACES requires libdwarf ?
+		-DENABLE_IPV6=ON
+		-DENABLE_WEATHER=$(usex weather)
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_VALA_BINDINGS=$(usex vala)
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use ldap; then
+		insinto /etc/openldap/schema
+		doins "${FILESDIR}"/calentry.schema
+		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+	fi
+}
diff --git a/gnome-extra/evolution-ews/Manifest b/gnome-extra/evolution-ews/Manifest
index 35a47bb6100c..ce816ea4ebf8 100644
--- a/gnome-extra/evolution-ews/Manifest
+++ b/gnome-extra/evolution-ews/Manifest
@@ -1,7 +1,9 @@
 DIST evolution-ews-3.48.2.tar.xz 701356 BLAKE2B 8c941302f383870bacf0dd3f02b28be34105ec7f612b027a505b98be0f66099d65671808e26e86ce756fc47116d012aa1c82fff74c5a501d3778dc7aba6b2498 SHA512 deccc3b442718b03809a7c49297a3f5d7c0bd2873fddfd9f90861a102208759cb95db9bfec1b04cff6932678f58aa81467c48fd4b1e32bb49ed43b9d8c9f4f77
 DIST evolution-ews-3.50.0.tar.xz 707208 BLAKE2B b2137c393e3ad6f3fdcd865d7dbba8f2830fbf3f287cb5599a23837ca5b4597714deeff08dc6e69443baf96171976476302bafeccdfb0c941c5b63e9a80f69c3 SHA512 51b90c018a5aea84e2c89785edcf69fe396d10d3fe447bc3ea5207506efa6433fe7af5e35ef6e2f5c3c2b8e3218ddff12c5be000dcad50c998c914994ce95745
 DIST evolution-ews-3.50.1.tar.xz 707220 BLAKE2B 8d5e579e885ebdabcbc3f19b18ba8ecaafdf393c473d3f3ca47c0002841634e2fda5c3d3db6ec132c1589a5bc7869e84b36e6761457f00bd999b2e866151b1af SHA512 f02b1815f8d641a5941f67e7b7507966231301f258602b8772e7ae01490f6ac18f66f60609c94e4ea996bf8544a65d5d895dd56a0eabbf7c20a86ff310537c18
+DIST evolution-ews-3.50.2.tar.xz 707800 BLAKE2B 18241eff067658af2f4620af87dea1c9c7c62476bbf9bf259addf15868a3b7e3f156dc952f21af2cad7ba6c2da9fd348b8733e5887f4276ad7eeeca8f9088476 SHA512 9aa4bb023922e39132a0ac3171d95f8362116960aa14dcb961b31ad242e6d7bcf2e946f19aea2c6f9a5324ca0954731264594a27fbb2b0e2cc38eca0cf441108
 EBUILD evolution-ews-3.48.2.ebuild 1574 BLAKE2B 83c02cb79285e854bc78ba63627baf9b3790bed6d23c5c0fe7eab0eb320046d7c5a1d3c5fd0a7c276264af3f4be34545d8c87eff86f3efa1f46a56c2a43463e1 SHA512 5d639deb515d9468ae5c97c406b8ab58e129d652c6e51b0ab92e6e45f6fcc1f014f4d103ae81a3bf5a09715d8b27026fa21658d2410dbda8d553210c1b625051
 EBUILD evolution-ews-3.50.0.ebuild 1583 BLAKE2B 7e80ce1197e8bebe2ad14a10cc16293be4d02a24083cbaee39dce4f974612142605c28277533e57182cfce091d3e72393b7785851f41366ba8a600ad08dd0f04 SHA512 ee44edf02473ea8e7ac98a1d8eefc3dbf36d9c61d8a67db0186a0fa468d0c308752e58089ee1c85df8b3f36fb11bce052ea4cabd64904df48d33ed243254e3dd
 EBUILD evolution-ews-3.50.1.ebuild 1583 BLAKE2B 7e80ce1197e8bebe2ad14a10cc16293be4d02a24083cbaee39dce4f974612142605c28277533e57182cfce091d3e72393b7785851f41366ba8a600ad08dd0f04 SHA512 ee44edf02473ea8e7ac98a1d8eefc3dbf36d9c61d8a67db0186a0fa468d0c308752e58089ee1c85df8b3f36fb11bce052ea4cabd64904df48d33ed243254e3dd
+EBUILD evolution-ews-3.50.2.ebuild 1583 BLAKE2B 7e80ce1197e8bebe2ad14a10cc16293be4d02a24083cbaee39dce4f974612142605c28277533e57182cfce091d3e72393b7785851f41366ba8a600ad08dd0f04 SHA512 ee44edf02473ea8e7ac98a1d8eefc3dbf36d9c61d8a67db0186a0fa468d0c308752e58089ee1c85df8b3f36fb11bce052ea4cabd64904df48d33ed243254e3dd
 MISC metadata.xml 354 BLAKE2B a6cf76e87956f2418a25c83542af3e5efe415943426b03750b2572129b06f977f900207a1eef805b7ae463a84204d12bf286ef9ed0a5b6990cbac2c77783260f SHA512 9f06dce58e2dfdba0a22f8a711d5fc98aba9ae1d130173bd7ef8effd0bb3c1cf046eef712f7ea7bd55c4382ca01e78d7028419ce41812d33ef38a1329978af56
diff --git a/gnome-extra/evolution-ews/evolution-ews-3.50.2.ebuild b/gnome-extra/evolution-ews/evolution-ews-3.50.2.ebuild
new file mode 100644
index 000000000000..def2f07990d7
--- /dev/null
+++ b/gnome-extra/evolution-ews/evolution-ews-3.50.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake gnome2 optfeature
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-ews"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="test"
+
+# libical-glib currently (2020-02-29) oddly behind USE=introspection
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/libical-3.0.5:0=[introspection(-)]
+	>=dev-libs/json-glib-1.0.4
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-${PV}:0=
+	>=mail-client/evolution-${PV}:2.0
+	>=net-libs/libsoup-3.0:3.0
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	test? ( >=net-libs/uhttpmock-0.9:1.0 )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+}
+
+pkg_postinst() {
+	optfeature "oauth support" "gnome-extra/evolution-data-server[oauth-gtk3]"
+}
diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 17c7c53ca4f3..9aa004b1ac13 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,7 +1,9 @@
 DIST gnome-software-44.4.tar.xz 2426404 BLAKE2B 6f60ffd115ad0e11b619118ae5e665fb35c70621adefe4c532481ab3742c8e2c6a5a0790dae29b2fcf0311f89fda93c323e5bc24b185bbbe95e62a687f71930d SHA512 97eaa33b4dd91a6865ee7eeee28e5acf3cf5fbd6a72a60cf5a7c528f79f6f0684014d1169318314b8efce23c1c29e7d24a71193998ced930584a50494137cf8b
 DIST gnome-software-45.0.tar.xz 2474756 BLAKE2B c42d31bdfb1f8f55cd37ce80a10c84928649e7126a17f1c9fa2309687612244d94f50a619b855abdd629ffb24b4bdb64a4baaa9f393561ee7b686d03c6fa00ae SHA512 3a7fab748c6d826e07e4bf86462cfecd9494bfaca2383222f7053be97830ab603cb0dc83d4d5693c2ddac1cc72897783922a05f5aae2ad07d6b7f5ccd5a4eefb
 DIST gnome-software-45.1.tar.xz 2474664 BLAKE2B cba81242a29da12cba7c74232592ac3c28e96b8d0ccceb59c330b7f64a18e0590cdd7f871e75d39591f805193db792f55733490e40100412bf31be2e128047b7 SHA512 5fdf5e6a34ab9acf938bc4ade41b916ad38ad3b4a7f604b2cba9dfaa38f17299001bef8fde9165f6a035fcc7fef3ebd451bd29ff126c0b9d5a7104e448729434
+DIST gnome-software-45.2.tar.xz 2475796 BLAKE2B e8741f4394cb6b86f177dbcce64876d67870c269f9eb41ebc545dff9211a76c7f694412e8be1aafb83eba0caedd9dce1eba56fc767aa7859bb2a1aee17696aca SHA512 ea271146683d199b27ffaaab98a13c25f8f794da3c6cc6b0daeb37f3f4c92d8644926dc592d309ea32dcb131d33e6c77d1c6fa36ac10cf6b23cd7adc73e898cb
 EBUILD gnome-software-44.4.ebuild 2664 BLAKE2B c8464d8e45ea71097e91ceaaacb722e317bd089c27e0e7ade3318ed7e8ec16c274baa1337cb7ea88fbddfdf2c37ad903a21f2736ed24cf5dbf54c04f8227c1d8 SHA512 9163535b7198d7d2369f31d6dbab926b98b628120715f212d88388a11167a60ceffd92971b7dd9f5dd5594f6a7700cb3c6127456fc786bc4f66d551e06f7cddb
 EBUILD gnome-software-45.0.ebuild 2621 BLAKE2B e7e7330bd857a32647bbe52ed4d8c75d1d0626ab7efbfced2b1dabfcd501b7e0068d427ef078583b2f6d006fcf51b75560bdb63d6bf42cd9ec3bc3f8ce1e2cd7 SHA512 e35a64425dcc4ef0ed91b56d99bc865c3128fc29aa97ce0f860547bf44aab5605e0c0a48528872b98846a2c40322d2b72153bfc62c11a70f9a7d5632ba724f6b
 EBUILD gnome-software-45.1.ebuild 2621 BLAKE2B e7e7330bd857a32647bbe52ed4d8c75d1d0626ab7efbfced2b1dabfcd501b7e0068d427ef078583b2f6d006fcf51b75560bdb63d6bf42cd9ec3bc3f8ce1e2cd7 SHA512 e35a64425dcc4ef0ed91b56d99bc865c3128fc29aa97ce0f860547bf44aab5605e0c0a48528872b98846a2c40322d2b72153bfc62c11a70f9a7d5632ba724f6b
+EBUILD gnome-software-45.2.ebuild 2621 BLAKE2B e7e7330bd857a32647bbe52ed4d8c75d1d0626ab7efbfced2b1dabfcd501b7e0068d427ef078583b2f6d006fcf51b75560bdb63d6bf42cd9ec3bc3f8ce1e2cd7 SHA512 e35a64425dcc4ef0ed91b56d99bc865c3128fc29aa97ce0f860547bf44aab5605e0c0a48528872b98846a2c40322d2b72153bfc62c11a70f9a7d5632ba724f6b
 MISC metadata.xml 688 BLAKE2B e157620837f5fd999b67d2a20f09cc64066317a47391ad97ae645b268964cff5a57e2e088e3040bfc98900f75ddcbffed10f1c159516c38f03d11aa1d2d00386 SHA512 9735764b439bdcb3db3b329d986530677ba87e00f10f217178d8014ea4335c3b74ec0e0051117086da92e9eac59849460a62c324ca249f621b13a3a7d50771a4
diff --git a/gnome-extra/gnome-software/gnome-software-45.2.ebuild b/gnome-extra/gnome-software/gnome-software-45.2.ebuild
new file mode 100644
index 000000000000..9951ed339e16
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-45.2.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://apps.gnome.org/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~x86"
+IUSE="flatpak +firmware gnome gtk-doc sysprof udev test"
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	>=gui-libs/gtk-4.10.0:4
+	>=dev-libs/glib-2.70.0:2
+	>=dev-libs/json-glib-1.6.0
+	>=net-libs/libsoup-3.0:3.0
+	>=gui-libs/libadwaita-1.3_rc:1
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	sys-auth/polkit
+	firmware? ( >=sys-apps/fwupd-1.5.6 )
+	flatpak? (
+		>=sys-apps/flatpak-1.14.0-r1
+		dev-util/ostree
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		-Dpackagekit=false
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dwebapps=true
+		-Dhardcoded_foss_webapps=true
+		-Dhardcoded_proprietary_webapps=true
+		$(meson_use udev gudev)
+		-Dapt=false
+		-Dsnap=false
+		-Dexternal_appstream=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_curated=true
+		# TODO: Will this be beneficial to us with flatpak at least? If
+		# enabled, it shows some apps under installed (probably merely due to
+		# /usr/share/app-info presence), but launching and removal of them is
+		# broken
+		-Ddefault_featured_apps=false
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+		-Dprofile=''
+		-Dsoup2=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}