4 files changed, 126 insertions, 2 deletions
diff --git a/media-libs/Manifest.gz b/media-libs/Manifest.gz
index 30bed9257a22..fd87c7f66690 100644
--- a/media-libs/Manifest.gz
+++ b/media-libs/Manifest.gz
diff --git a/media-libs/libplacebo/Manifest b/media-libs/libplacebo/Manifest
index fae9de09b4fb..494fd0ffc6fe 100644
--- a/media-libs/libplacebo/Manifest
+++ b/media-libs/libplacebo/Manifest
@@ -6,8 +6,10 @@ DIST libplacebo-glad-2.0.4.tar.gz 599932 BLAKE2B 788d2b70222fd09eea02515bdf3cbc1
 DIST libplacebo-v5.264.1.tar.gz 725394 BLAKE2B 421de50ef5e2270e3ba32dd85d92d816a374257442b535face6cb8501d565652aae530b86a7d717c9352c6a82ca665ff7d91c2d9768365780cbbe4f48d1d3276 SHA512 305f43b71f078f4113def43c444df667dfbdd2a6a34d3b457b15da0b3499ca97ec9a8acbd151d58c8e1a593ace3d8aa61067b32556c6bae451efbb217d60a731
 DIST libplacebo-v6.292.1.tar.bz2 702879 BLAKE2B 74319bdffb141d4ab50c04312dbcce8fe7926d28b59b2c088a975fec30b86b38bb99afc375de5d421f8f633524deb4a74bb30cd60ffb69b16caceccd0f4f13d9 SHA512 a519d540e5063905c7125ca90334471a21868e2795d3e2da502fe12adfa69555de5369b14d1d45f9d2b0ac589379ad687488896c6dbe22f1dbd7cc6f9eef544f
 DIST libplacebo-v6.338.0.tar.bz2 696457 BLAKE2B fad5f0562b925528f44cdddd349114acfa8135503a47d5e7015be8b22a372f52d4ada8f196839d688887cce9ce91c11d0e32ac4dc0209f7dbc961d4785129fa7 SHA512 59be50efa3f56185a978f6ba5592beeabb40986ba8ccd6c0d43a8538a07a5459bec793df313c00ec721768490e30728c62dcef32693ba49e2544d59fd3d519e7
+DIST libplacebo-v6.338.1.tar.bz2 696577 BLAKE2B c4b1a9830ba91127c78fca30deabbc90c157b0bd9220216c6452866312374b9415f00c6f0c3b573070d4bf26a0c25df96462365d0929dcd022ef5ab84b909e17 SHA512 79e9f800791dcc856ead965f2b0b463ede3313186f248be85e3cf9ec62901043dad72b639f426f858e1fff0bbd9bdcdea48d01a5d3d2218b79e263fa0432bc5b
 EBUILD libplacebo-5.264.1.ebuild 2908 BLAKE2B edeb06ac3b3f8ff055adab7e3457806282c6854297d7710e41acb9609c94ba53afd8e6b03ff04dc0693fe8cf00a813f94a730acc92bf1b9302773f79c74d6769 SHA512 d581927db83ce4205522f195eb9a4d5f2bf3007a6b8c4018339611c9339d23fd9c648f78621a1771436d8aa59f473987bae828cdbc1cc9c16a5f1044f01b9805
 EBUILD libplacebo-6.292.1.ebuild 2923 BLAKE2B 8e82848c99c630115e8d9b1f4a8ce74851d8a3040965daea0af0c219fb247df6bf4490c86e805b6f595ef19756823bb21abc0b1b67972b23ca1364e40e3e5332 SHA512 d39af02ab940640a85638ec778beb456a6a94f5399568adbe81009be1b3dee9a7f5bd809719cfc67e9387cd2ad480c9a8842707c1abab3a3eef1d37117e3378b
 EBUILD libplacebo-6.338.0.ebuild 3325 BLAKE2B eecbf0d11649a0cd7f8539f075108e831286fbc999cbc1f28eaaa324bd602a04c1a56a40d57cdb9dd90ce8efb4b1f2492e9da8a0158beaed74e809167f5534df SHA512 73077355282a89458e876c1f8db169f8b6240ec10032d822a3cac2cb5398dd99f6dcb2da83c25bcb3ce38dceca4e614c141a06fd79333fc6aac5683d320661cb
-EBUILD libplacebo-9999.ebuild 3318 BLAKE2B 3a95d1440e4a9d56e1e4f266ffc037d947a029a3d867aebdd458cc68dcece99f2b739b402529add70f5d099f84523cab9eddbd8fdbb952de1f314c030bcb23be SHA512 1b5d0ca83731b76587f8fa48501b84b524ebfb36b971e35ef9a40b4f43d0edaff88f3b6b2999f7edad6589319707e188f7a75610785fe7eaf3aad6cc90e08a2c
+EBUILD libplacebo-6.338.1.ebuild 3325 BLAKE2B eecbf0d11649a0cd7f8539f075108e831286fbc999cbc1f28eaaa324bd602a04c1a56a40d57cdb9dd90ce8efb4b1f2492e9da8a0158beaed74e809167f5534df SHA512 73077355282a89458e876c1f8db169f8b6240ec10032d822a3cac2cb5398dd99f6dcb2da83c25bcb3ce38dceca4e614c141a06fd79333fc6aac5683d320661cb
+EBUILD libplacebo-9999.ebuild 3325 BLAKE2B eecbf0d11649a0cd7f8539f075108e831286fbc999cbc1f28eaaa324bd602a04c1a56a40d57cdb9dd90ce8efb4b1f2492e9da8a0158beaed74e809167f5534df SHA512 73077355282a89458e876c1f8db169f8b6240ec10032d822a3cac2cb5398dd99f6dcb2da83c25bcb3ce38dceca4e614c141a06fd79333fc6aac5683d320661cb
 MISC metadata.xml 700 BLAKE2B 339905c53f52620737835f397717eba8b742fa4cb26f8dbc9f2dfd7a443a4e7f143b1ef844a52bddb280099f87a073cbf685c5a4a21e4788a1ac16cdccacce1c SHA512 8524de2cf08b516c79c6d1ae032e68d8421122084d431692663ac1ad3e1e841398eb4543bad6e24b674727b01d0959cec4960deb8300cb52d015a583d66d9ddc
diff --git a/media-libs/libplacebo/libplacebo-6.338.1.ebuild b/media-libs/libplacebo/libplacebo-6.338.1.ebuild
new file mode 100644
index 000000000000..89a1527ea842
--- /dev/null
+++ b/media-libs/libplacebo/libplacebo-6.338.1.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit meson-multilib python-any-r1
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://code.videolan.org/videolan/libplacebo.git"
+	inherit git-r3
+else
+	GLAD_PV=2.0.4
+	FASTFLOAT_PV=5.2.0
+	SRC_URI="
+		https://code.videolan.org/videolan/libplacebo/-/archive/v${PV}/libplacebo-v${PV}.tar.bz2
+		https://github.com/fastfloat/fast_float/archive/refs/tags/v${FASTFLOAT_PV}.tar.gz
+			-> fast_float-${FASTFLOAT_PV}.tar.gz
+		opengl? (
+			https://github.com/Dav1dde/glad/archive/refs/tags/v${GLAD_PV}.tar.gz
+				-> ${PN}-glad-${GLAD_PV}.tar.gz
+		)
+	"
+	S="${WORKDIR}/${PN}-v${PV}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Reusable library for GPU-accelerated image processing primitives"
+HOMEPAGE="
+	https://libplacebo.org/
+	https://code.videolan.org/videolan/libplacebo/
+"
+
+LICENSE="
+	LGPL-2.1+
+	|| ( Apache-2.0 Boost-1.0 MIT )
+	opengl? ( MIT )
+"
+SLOT="0/$(ver_cut 2 ${PV}.9999)" # soname
+IUSE="glslang +lcms llvm-libunwind +opengl +shaderc test unwind +vulkan +xxhash"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="vulkan? ( || ( glslang shaderc ) )"
+
+# dlopen: libglvnd (glad)
+RDEPEND="
+	lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )
+	opengl? ( media-libs/libglvnd[${MULTILIB_USEDEP}] )
+	shaderc? ( media-libs/shaderc[${MULTILIB_USEDEP}] )
+	!shaderc? ( glslang? ( dev-util/glslang:=[${MULTILIB_USEDEP}] ) )
+	unwind? (
+		llvm-libunwind? ( sys-libs/llvm-libunwind[${MULTILIB_USEDEP}] )
+		!llvm-libunwind? ( sys-libs/libunwind:=[${MULTILIB_USEDEP}] )
+	)
+	vulkan? ( media-libs/vulkan-loader[${MULTILIB_USEDEP}] )
+	xxhash? ( dev-libs/xxhash[${MULTILIB_USEDEP}] )
+"
+# vulkan-headers is required even with USE=-vulkan (bug #882065)
+DEPEND="
+	${RDEPEND}
+	dev-util/vulkan-headers
+"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/jinja[${PYTHON_USEDEP}]')
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.229.1-llvm-libunwind.patch
+	"${FILESDIR}"/${PN}-5.229.1-python-executable.patch
+)
+
+python_check_deps() {
+	python_has_version "dev-python/jinja[${PYTHON_USEDEP}]"
+}
+
+src_unpack() {
+	if [[ ${PV} == 9999 ]]; then
+		local EGIT_SUBMODULES=(
+			3rdparty/fast_float
+			$(usev opengl 3rdparty/glad)
+		)
+		git-r3_src_unpack
+	else
+		default
+
+		rmdir "${S}"/3rdparty/fast_float || die
+		mv fast_float-${FASTFLOAT_PV} "${S}"/3rdparty/fast_float || die
+
+		if use opengl; then
+			rmdir "${S}"/3rdparty/glad || die
+			mv glad-${GLAD_PV} "${S}"/3rdparty/glad || die
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+
+	# typically auto-skipped, but may assume usable opengl/vulkan then hang
+	sed -i "/tests += 'opengl_surfaceless.c'/d" src/opengl/meson.build || die
+	sed -i "/tests += 'vulkan.c'/d" src/vulkan/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddemos=false #851927
+		$(meson_use test tests)
+		$(meson_feature lcms)
+		-Dlibdovi=disabled # TODO: package libdovi, ask if you need this
+		$(meson_feature opengl)
+		$(meson_feature opengl gl-proc-addr)
+		$(meson_feature shaderc)
+		$(usex shaderc -Dglslang=disabled $(meson_feature glslang))
+		$(meson_feature unwind)
+		$(meson_feature vulkan)
+		$(meson_feature vulkan vk-proc-addr)
+		-Dvulkan-registry="${ESYSROOT}"/usr/share/vulkan/registry/vk.xml
+		$(meson_feature xxhash)
+	)
+
+	meson_src_configure
+}
diff --git a/media-libs/libplacebo/libplacebo-9999.ebuild b/media-libs/libplacebo/libplacebo-9999.ebuild
index 5a8219d45eb1..89a1527ea842 100644
--- a/media-libs/libplacebo/libplacebo-9999.ebuild
+++ b/media-libs/libplacebo/libplacebo-9999.ebuild
@@ -22,7 +22,7 @@ else
 		)
 	"
 	S="${WORKDIR}/${PN}-v${PV}"
-	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
 fi
 
 DESCRIPTION="Reusable library for GPU-accelerated image processing primitives"