summaryrefslogtreecommitdiff
path: root/media-sound/ardour
diff options
context:
space:
mode:
Diffstat (limited to 'media-sound/ardour')
-rw-r--r--media-sound/ardour/Manifest6
-rw-r--r--media-sound/ardour/ardour-8.6-r1.ebuild2
-rw-r--r--media-sound/ardour/ardour-8.7.ebuild200
-rw-r--r--media-sound/ardour/ardour-9999.ebuild2
4 files changed, 206 insertions, 4 deletions
diff --git a/media-sound/ardour/Manifest b/media-sound/ardour/Manifest
index 232196112488..ea319b346f3d 100644
--- a/media-sound/ardour/Manifest
+++ b/media-sound/ardour/Manifest
@@ -1,6 +1,8 @@
AUX ardour-6.8-boost-1.85.patch 750 BLAKE2B 9a86275431cb735b32b36a570450d4b5c035f1360c89e69d7d688171e299aea15128057f01dd905335c4fca68035a146cc54cd62b0aa163ec56ae06e545ca8ad SHA512 ad4888bbda5da5ba3e49ca751bdec34159fde01355e8dac3e23c968a8eeba4bce3228f43ef87977ee619c70063ef16e2383c6b7126213d88125222431f79574d
AUX ardour-6.8-metadata.patch 568 BLAKE2B 68bb84e5249d67e88e191dbc009b7f2b696d448903a2c7164778f4fda3b526370bd2562fa627faea832da2c115d61fe8ddccf6c54c016a7f68e5cab688868984 SHA512 1bf77b0cf2692e7051a524a049add8f22feb734120d9ae58ffcf06647e8ed28249dcbe2cd124eb2354897f119a2977c6124228fc37c15e476053dc5ea4b5033c
DIST Ardour-8.6.0.tar.bz2 17588463 BLAKE2B e8d3b603fecaf453eae9e0c2cac531a5c2d35850b282d27c25dbd22a930a6537fbbff3f1fa58f4dcc525dcc65ef8343172642d16ad473c8b80b0e373364a06cb SHA512 c4a3b6369fe1a1789ba2b5cbcfd23b6ac6b93f819b016aac2c071f1135e32826ca4f5bb99d4c3e4e1d8f91f82719ae17bcf2991eb29072c14e60f282545f934a
-EBUILD ardour-8.6-r1.ebuild 5257 BLAKE2B 62f46b11c3ad5103a5f5a2278a5d1ba25b69e6473c8c78db9cbf9989cd029c29314c09a3130cb8f9b432e48672fe6a55a6fd341e98a1c56048e5547e0a4e2fa8 SHA512 86aee8c52c77b697c3b1e310af49f449eef257343bd6016dc6065af15c51cdd247594997e4c7a08d15a4f7e992cbcf0f2bc87be0d0e7546c2e8703972242c2d6
-EBUILD ardour-9999.ebuild 5258 BLAKE2B bcafbd36ccf9abc3a8adee5c889255500f707e98e1549dd771c5d3b1e4dac2e03b473847ed5d6340b0e8c96f2efcc6aac442f30ba4d5fe72174a11d39fd973da SHA512 042c6c9bbf9719e8e2c944256db585a3a98949abef647676e51a66e737129d1496cb250bbdecd202ab6c40f1d227341bb7c1cb7de00cafdd3d737c4912638bbf
+DIST Ardour-8.7.0.tar.bz2 17807972 BLAKE2B 9bbe4ed5c3ad62d643518881a45b71642f5ce41c8620eb4c82befcb9df1053b08b60d3683961d78825f99e3a74222404c511073491972f138edaaaea445c6961 SHA512 cd2cdc1360b01d23cd3df62ee949ecab9d5d8da5112636438c2ef8a88d188503bcd7f09f2a5d8e07460dacbc35cecd96e8edbc748adccc50b5a90375f2f742d0
+EBUILD ardour-8.6-r1.ebuild 5257 BLAKE2B 48899bdee879dd24d9530e2eadb4c89a03241a1c793e87bd8ff5df3cdd25e598bc73ae2cb4dae131bfd6607957e77b42ddf0d33e996949e10887a0b8cbd6047d SHA512 d37fb303db968c36017d1e6a4a296e534bfd6280bd25ef841f5fb556ebda5b87e6bbf3d8e4b47517c28d0f99573d6d6852a5c6801960a5309a2107be2e8b4552
+EBUILD ardour-8.7.ebuild 5258 BLAKE2B 0111663a23b399284b867d47579d47f5f1e67fd0d480ed709b3f28b542db32f5e39e221553f5727ead1b28c59a60c8ec8fdec43d84efcf5448adef39a0843e2a SHA512 450b9579fda381e986333f827d4f559d442c020911ed92a7d40f3b3c4a459dccaede1a73bef8b30b2a35e9621a3712e00920fb07c64847f409d727964171973c
+EBUILD ardour-9999.ebuild 5258 BLAKE2B 0111663a23b399284b867d47579d47f5f1e67fd0d480ed709b3f28b542db32f5e39e221553f5727ead1b28c59a60c8ec8fdec43d84efcf5448adef39a0843e2a SHA512 450b9579fda381e986333f827d4f559d442c020911ed92a7d40f3b3c4a459dccaede1a73bef8b30b2a35e9621a3712e00920fb07c64847f409d727964171973c
MISC metadata.xml 451 BLAKE2B 0ed571ca79f0d4b92239239982f04abf725365df169290e4a02f6d8f580cf801f70d8bc93414b4549c8172ff43864d5c49fa987caeec58e1b2331ffe01a69ae6 SHA512 504bd817356c7ee57c64193584b3fc5b3bc70f5224d5a531ac5ecf8fb974728639e75b77bb9e7c5ad77cf6099123361b9ec6211b855edb4761acd95b8cb7abcb
diff --git a/media-sound/ardour/ardour-8.6-r1.ebuild b/media-sound/ardour/ardour-8.6-r1.ebuild
index f52d764936e0..fa3ba391ecf7 100644
--- a/media-sound/ardour/ardour-8.6-r1.ebuild
+++ b/media-sound/ardour/ardour-8.6-r1.ebuild
@@ -3,7 +3,7 @@
EAPI=8
-PYTHON_COMPAT=( python3_{9..12} )
+PYTHON_COMPAT=( python3_{9..13} )
PYTHON_REQ_USE='threads(+)'
PLOCALES="ca cs de el en_GB es eu fr it ja ko nn pl pt pt_PT ru sv zh"
inherit toolchain-funcs flag-o-matic plocale python-any-r1 waf-utils desktop xdg
diff --git a/media-sound/ardour/ardour-8.7.ebuild b/media-sound/ardour/ardour-8.7.ebuild
new file mode 100644
index 000000000000..3eb5cde4c590
--- /dev/null
+++ b/media-sound/ardour/ardour-8.7.ebuild
@@ -0,0 +1,200 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..13} )
+PYTHON_REQ_USE='threads(+)'
+PLOCALES="ca cs de el en_GB es eu fr it ja ko nn pl pt pt_PT ru sv zh"
+inherit toolchain-funcs flag-o-matic plocale python-any-r1 waf-utils desktop xdg
+
+DESCRIPTION="Digital Audio Workstation"
+HOMEPAGE="https://ardour.org/"
+
+if [[ ${PV} == *9999* ]]; then
+ EGIT_REPO_URI="https://git.ardour.org/ardour/ardour.git"
+ inherit git-r3
+else
+ KEYWORDS="~amd64 ~loong ~x86"
+ SRC_URI="https://dev.gentoo.org/~fordfrog/distfiles/Ardour-${PV}.0.tar.bz2"
+ S="${WORKDIR}/Ardour-${PV}.0"
+fi
+
+LICENSE="GPL-2"
+SLOT="8"
+IUSE="doc jack nls phonehome pulseaudio cpu_flags_ppc_altivec cpu_flags_x86_sse cpu_flags_x86_mmx cpu_flags_x86_3dnow"
+
+RDEPEND="
+ dev-cpp/glibmm:2
+ dev-cpp/gtkmm:2.4
+ dev-libs/boost:=
+ dev-libs/glib:2
+ dev-libs/libsigc++:2
+ dev-libs/libxml2:2
+ media-libs/alsa-lib
+ media-libs/aubio
+ media-libs/flac:=
+ media-libs/freetype:2
+ media-libs/liblo
+ media-libs/liblrdf
+ media-libs/libsamplerate
+ media-libs/libsndfile
+ media-libs/libsoundtouch
+ media-libs/raptor:2
+ media-libs/rubberband
+ media-libs/taglib
+ media-libs/vamp-plugin-sdk
+ net-libs/libwebsockets
+ net-misc/curl
+ sys-libs/readline:0=
+ sci-libs/fftw:3.0[threads]
+ virtual/libusb:1
+ x11-libs/cairo
+ x11-libs/gtk+:2
+ x11-libs/pango
+ jack? ( virtual/jack )
+ pulseaudio? ( media-libs/libpulse )
+ media-libs/lilv
+ media-libs/sratom
+ dev-libs/sord
+ media-libs/suil[X,gtk2]
+ media-libs/lv2"
+# !bundled-libs? ( media-sound/fluidsynth ) at least libltc is missing to be able to unbundle...
+
+DEPEND="${RDEPEND}
+ ${PYTHON_DEPS}
+ dev-util/itstool
+ sys-devel/gettext
+ virtual/pkgconfig
+ doc? ( app-text/doxygen[dot] )
+ jack? ( virtual/jack )"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-6.8-metadata.patch"
+ "${FILESDIR}/${PN}-6.8-boost-1.85.patch"
+)
+
+pkg_pretend() {
+ [[ $(tc-getLD) == *gold* ]] && (has_version sci-libs/fftw[openmp] || has_version sci-libs/fftw[threads]) && \
+ ewarn "Linking with gold linker might produce broken executable, see bug #733972"
+}
+
+pkg_setup() {
+ if has_version \>=dev-libs/libsigc++-2.6 ; then
+ append-cxxflags -std=c++11
+ fi
+ python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+
+ # delete optimization flags
+ sed 's/'full-optimization\'\ :\ \\[.*'/'full-optimization\'\ :\ \'\','/' -i "${S}"/wscript || die
+
+ # handle arch
+ MARCH=$(get-flag march)
+ OPTFLAGS=""
+ if use cpu_flags_x86_sse; then
+ if [[ ${MARCH} == "i686" ]] || [[ ${MARCH} == "i486" ]]; then
+ elog "You enabled sse but use an march that does not support sse!"
+ elog "We add -msse to the flags now, but please consider switching your march in make.conf!"
+ fi
+ OPTFLAGS="sse"
+ fi
+ if use cpu_flags_x86_mmx; then
+ if [[ ${MARCH} == "i486" ]]; then
+ elog "You enabled mmx with i486 set as march! You have been warned!"
+ fi
+ OPTFLAGS="${OPTFLAGS} mmx"
+ fi
+ if use cpu_flags_x86_3dnow; then
+ OPTFLAGS="${OPTFLAGS} 3dnow"
+ fi
+ sed 's/flag_line\ =\ o.*/flag_line\ =\ \": '"${OPTFLAGS}"' just some place holders\"/' \
+ -i "${S}"/wscript || die
+ sed 's/cpu\ ==\ .*/cpu\ ==\ "LeaveMarchAsIs":/' -i "${S}"/wscript || die
+
+ # boost and shebang
+ append-flags "-lboost_system"
+ python_fix_shebang "${S}"/wscript
+ python_fix_shebang "${S}"/waf
+
+ # handle locales
+ my_lcmsg() {
+ rm -f {gtk2_ardour,gtk2_ardour/appdata,libs/ardour,libs/gtkmm2ext}/po/${1}.po
+ }
+ plocale_for_each_disabled_locale my_lcmsg
+}
+
+src_configure() {
+ # avoid bug https://bugs.gentoo.org/800067
+ local -x AS="$(tc-getCC) -c"
+
+ # -Werror=odr
+ # https://tracker.ardour.org/view.php?id=9649
+ # https://bugs.gentoo.org/917095
+ filter-lto
+
+ local backends="alsa,dummy"
+ use jack && backends+=",jack"
+ use pulseaudio && backends+=",pulseaudio"
+
+ tc-export CC CXX
+ local myconf=(
+ --configdir=/etc
+ --freedesktop
+ --noconfirm
+ --optimize
+ --no-ytk
+ --with-backends=${backends}
+ $({ use cpu_flags_ppc_altivec || use cpu_flags_x86_sse; } && \
+ echo '' || echo "--no-fpu-optimization")
+ $(usex doc "--docs" '')
+ $(usex nls '' "--no-nls")
+ $(usex phonehome '' "--no-phone-home")
+ # not possible right now --use-external-libs
+ # missing dependency: https://github.com/c4dm/qm-dsp
+ )
+
+ waf-utils_src_configure "${myconf[@]}"
+}
+
+src_compile() {
+ waf-utils_src_compile
+ use nls && waf-utils_src_compile i18n
+}
+
+src_install() {
+ local s
+
+ waf-utils_src_install
+
+ mv ${PN}.1 ${PN}${SLOT}.1 || die
+ doman ${PN}${SLOT}.1
+
+ for s in 16 22 32 48 256 512; do
+ newicon -s ${s} gtk2_ardour/resources/Ardour-icon_${s}px.png ardour${SLOT}.png
+ done
+
+ # the build system still installs ardour6.png files so we get rid of those to not conflict with ardour:6
+ find "${D}/usr/share/icons/" -name ardour6.png -delete
+
+ sed -i \
+ -e "s/\(^Name=\).*/\1Ardour ${SLOT}/" \
+ -e 's/;AudioEditing;/;X-AudioEditing;/' \
+ build/gtk2_ardour/ardour${SLOT}.desktop || die
+ domenu build/gtk2_ardour/ardour${SLOT}.desktop
+
+ insinto /usr/share/mime/packages
+ newins build/gtk2_ardour/ardour.xml ardour${SLOT}.xml
+ rm "${D}/usr/share/mime/packages/ardour.xml" || die
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ elog "Please do _not_ report problems with the package to ${PN} upstream."
+ elog "If you think you've found a bug, check the upstream binary package"
+ elog "before you report anything to upstream."
+}
diff --git a/media-sound/ardour/ardour-9999.ebuild b/media-sound/ardour/ardour-9999.ebuild
index cba836bba78d..3eb5cde4c590 100644
--- a/media-sound/ardour/ardour-9999.ebuild
+++ b/media-sound/ardour/ardour-9999.ebuild
@@ -3,7 +3,7 @@
EAPI=8
-PYTHON_COMPAT=( python3_{9..12} )
+PYTHON_COMPAT=( python3_{9..13} )
PYTHON_REQ_USE='threads(+)'
PLOCALES="ca cs de el en_GB es eu fr it ja ko nn pl pt pt_PT ru sv zh"
inherit toolchain-funcs flag-o-matic plocale python-any-r1 waf-utils desktop xdg
generated by cgit v1.2.3 (git 2.25.1) at 2024-11-11 04:59:27 +0000