1 files changed, 37 insertions, 0 deletions
diff --git a/media-sound/sonata/sonata-1.7.0.ebuild b/media-sound/sonata/sonata-1.7.0.ebuild
new file mode 100644
index 000000000000..f655eca0a200
--- /dev/null
+++ b/media-sound/sonata/sonata-1.7.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_SINGLE_IMPL="true"
+DISTUTILS_USE_SETUPTOOLS="rdepend"
+inherit desktop distutils-r1 xdg
+
+DESCRIPTION="Elegant GTK+ music client for the Music Player Daemon (MPD)"
+HOMEPAGE="https://www.nongnu.org/sonata/"
+SRC_URI="https://github.com/multani/sonata/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="dbus taglib"
+
+BDEPEND="
+	virtual/pkgconfig"
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		dev-python/python-mpd[${PYTHON_MULTI_USEDEP}]
+		dbus? ( dev-python/dbus-python[${PYTHON_MULTI_USEDEP}] )
+		taglib? ( dev-python/tagpy[${PYTHON_MULTI_USEDEP}] )
+	')
+"
+
+distutils_enable_tests unittest
+
+src_install() {
+	distutils-r1_src_install
+	doicon -s 128 sonata/pixmaps/sonata.png
+	rm -r "${ED}"/usr/share/sonata || die
+}