summaryrefslogtreecommitdiff
path: root/media-tv
diff options
context:
space:
mode:
Diffstat (limited to 'media-tv')
-rw-r--r--media-tv/Manifest.gzbin3756 -> 3749 bytes
-rw-r--r--media-tv/kodi/Manifest8
-rw-r--r--media-tv/kodi/kodi-19.1.ebuild355
-rw-r--r--media-tv/kodi/kodi-19.9999.ebuild6
-rw-r--r--media-tv/kodi/kodi-9999.ebuild4
-rw-r--r--media-tv/kodi/metadata.xml1
6 files changed, 367 insertions, 7 deletions
diff --git a/media-tv/Manifest.gz b/media-tv/Manifest.gz
index c198a4fe70a6..1af7d202fdda 100644
--- a/media-tv/Manifest.gz
+++ b/media-tv/Manifest.gz
Binary files differ
diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
index f1252b18fed9..f6e262e2f81c 100644
--- a/media-tv/kodi/Manifest
+++ b/media-tv/kodi/Manifest
@@ -2,10 +2,12 @@ DIST ffmpeg-kodi-4.3.1-Matrix-Beta1.tar.gz 13477440 BLAKE2B 49415f76fd2a888b0efa
DIST ffmpeg-kodi-4.3.2-Matrix-19.1.tar.gz 13490949 BLAKE2B 90007f2c4bac0e0a52b419d9333cf75b00e291f1ea7447cbdc579ee2f860de7c436c924253600f3fbd6e3faaabe97aaf46db083a5bbd2f5f03badcca5d643e89 SHA512 d3719253d674b16638b873545583b82fba3176803c81ba8bcb37e90456dd956f1c2ee8996493840cff2d61c6399f06ed0524a759f46e4ce174bce23e9c6eda4a
DIST ffmpeg-kodi-4.4-N-Alpha1.tar.gz 13717391 BLAKE2B 2c45778e36167a8740f8f724dc8a66ea2491d8343b1f2546027c4dd1a711aa7a8b830defc439006402e141f264532cbc623758dd066b45fc8a09f67ffdc0f9b8 SHA512 53edceae357747763dd20cdaae0a546970506e5f488477426821ecb87aff613dadb9c4c46a63594db9e230ba54db6da8e5f34699afc0221fd10adfb8f08cf840
DIST kodi-19.0.tar.gz 52311355 BLAKE2B 543936b8fb607d1d629a8f2abd9cd0cb3bf6114aa93647c7e8ccee2f99ff1f84a2740bb57f0cbf675b3efa5914e98c57effb28ecd8e9df83a39d67ee708280a2 SHA512 d6c9fe7414b64d33d919d6c3de1ddb4800e36b786a460d2d2f5c1e5346cd4819487e54f212c37778103d44dd051f7df6c74e0a98a0b21d1e4dc9bedaa8570422
+DIST kodi-19.1.tar.gz 52323919 BLAKE2B 6aa82632d2d70e5f84340c572b586e903e7dbc50c4f99fc5118761d495bd13dcbbcd70462e6288147dd4a305952d1e07f08daf45bbc402b59e3ef785391e1fe7 SHA512 725cbc270259ef5d3b79f9bc271b789dc8ef6616a6d4038e0cd449755ca4ed25198ad6e854b304aedc1fb911ecb98a0aad1b3e469857f8aed54fc4634193eb75
DIST libdvdcss-1.4.2-Leia-Beta-5.tar.gz 101068 BLAKE2B 283aa2cec0a2200d3569bc280cb9659e9224a6b3a77db8a35b269cd8caf1337ac9d8b92b806df66f63ef7458a46bd6261f0b8b14678b10e26644a79dcbeea5da SHA512 5185dbdbeb1bd13ea9d8723f1f4ab599d6f3102f5ba1096cd085aa1cda252c045f327c719227bba8e1b742352ade5e335106c8d0c1637a5a6b93ce661620dd7e
DIST libdvdnav-6.0.0-Leia-Alpha-3.tar.gz 137942 BLAKE2B 7573434a0ae8e8ccabf48173f81fcde29074eb138e119a2ae9156cde3c3d8bfd716f5d0e605b97f2dcac21f570781137c8533c5ae306b51e3905822fda318355 SHA512 11c93eaacd156f8fd7dec7c43d366438b201f31ad55b2870463a9e286912b6ada08882319a021fb7992190f87b909a49f2b83e0321cc17aedc29f7fe5898fa72
DIST libdvdread-6.0.0-Leia-Alpha-3.tar.gz 130649 BLAKE2B 0c206acdaf0776841ab792c74e023af07d9539eb72e03ae164382a31ed950f60e5e15f1d055979d28f1398924471b294d11f064b11b8373353b3962a3777ff3c SHA512 b3419ba0a1a2dd70f1bb6236afdfe1c6e88c9ad4264198b289e3bba9375e077cecf7f89848c7b09debaa445327f3507101f3d157e692f7a7163b2bb52643e1e7
EBUILD kodi-19.0.ebuild 10843 BLAKE2B 60ac01d6b4f1e61a8f2f5e8e0734ce8f8ac13e06bf27d185d4141ec46dae3958ca375db4e3febdb0b0cde26e533948bf1adbde6cd82c66f4960510e566cb7225 SHA512 b36a304f423c604c11f67e5af97a3c9933b49fc0f124e6c9ea285b47896bb72467b876176f84ecc0dea68bf493c366d360d11a4b3e022334030d4d6e455b8e87
-EBUILD kodi-19.9999.ebuild 10843 BLAKE2B 84015180791f9672a90e582f408ad80d14d99cd97306ca0a130d6c98c8166139507998e56fca617ccb83c6b1ba11a75cbe6f5d010b3ab7f86f07db9530efa759 SHA512 c072d58bf092da3dbc4888c23065af79b6703126e65efb143d1405baff2ae0ad8a09abbeb11cf0cc860b864338abb335096828cccc00b6d1c91b23f38343d04d
-EBUILD kodi-9999.ebuild 10815 BLAKE2B dbadae4cd1613ee4fb965702113b787b9be3243bd0362a6039f833c0d0660824ffb5e40d288279f5466af76272affe76d0fb7467291334946fbf929cfaf74f95 SHA512 259308fcc5430e59d90f1ff35d1bd712a41b95e15dc703b4e99fa15e151d6dd26c749a4188af95a3a5e7ff597f42eedf5ba32c9a780339f6d6fbc347cd929a53
-MISC metadata.xml 2707 BLAKE2B 647da6ee38f710be18a87b3b3267dddcbe1f4e23f3008a73f6d800e8c765a58dbdcf4b0ec165aa45be843276712b5a1feee5754b8553a43ba149993702cf2252 SHA512 04ad8ecd819f0c7779bdac2860bf31f89b7308c633c527a9f70600bfb1d82681874d4304c59f394a91c18fdac1441e5d97dee2ab81ace1589985c0c422a672b0
+EBUILD kodi-19.1.ebuild 10820 BLAKE2B 1383c72c46e268cfcb0e6e140ee5625824155ce7656eae7d702346798f3594da546f3c0e0fc52a79ac3f97c07fd7fd28775993ba66d648bd6d00ac7ab927967a SHA512 625b501a8a817c02a454b3ead006d5ca1d5dc170124b44d4763682cebe4ff8863c1535a57169fabd9169522285fc0052f0da851fdc11a46f71d1144fb70567a8
+EBUILD kodi-19.9999.ebuild 10820 BLAKE2B 1383c72c46e268cfcb0e6e140ee5625824155ce7656eae7d702346798f3594da546f3c0e0fc52a79ac3f97c07fd7fd28775993ba66d648bd6d00ac7ab927967a SHA512 625b501a8a817c02a454b3ead006d5ca1d5dc170124b44d4763682cebe4ff8863c1535a57169fabd9169522285fc0052f0da851fdc11a46f71d1144fb70567a8
+EBUILD kodi-9999.ebuild 10897 BLAKE2B c24337d42e960fb2e485b72c6ef4461730fafa8170c819ffb00ae277894564c49945cea1823c69a93e4555c19244acca98a13fc8ac48ec264b27a68a7af7bf6f SHA512 3ff06ced5e2575d4b8492875544b6561e2c01f20dd7aabdf7126bbde778cab933566dee8d03d184eba4f5cd5a8478ce77d82d34380ad2b79637e33ae3a39b3d7
+MISC metadata.xml 2762 BLAKE2B bfb7136dd5d2314362f94da7d51340b57aa8176e4e081027c89e08db03e32fa14213a3301c44a89a5d172c71331b9d9da53665e077398dac9a84948fec08d707 SHA512 916c7c7696f704b24d534414f0d79bbd66268d88cee3b2365e95cdf8d2cd0a90f01db8ffb855b49badfab3dd0b1c8efee78aac3e4b4b1208d1a8b21d8ad336c8
diff --git a/media-tv/kodi/kodi-19.1.ebuild b/media-tv/kodi/kodi-19.1.ebuild
new file mode 100644
index 000000000000..11329e6f4706
--- /dev/null
+++ b/media-tv/kodi/kodi-19.1.ebuild
@@ -0,0 +1,355 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_REQ_USE="sqlite,ssl"
+LIBDVDCSS_VERSION="1.4.2-Leia-Beta-5"
+LIBDVDREAD_VERSION="6.0.0-Leia-Alpha-3"
+LIBDVDNAV_VERSION="6.0.0-Leia-Alpha-3"
+FFMPEG_VERSION="4.3.2"
+CODENAME="Matrix"
+FFMPEG_KODI_VERSION="19.1"
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
+ https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
+ https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
+ !system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
+if [[ ${PV} == *9999 ]] ; then
+ EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
+ EGIT_BRANCH="Matrix"
+ inherit git-r3
+else
+ MY_PV=${PV/_p/_r}
+ MY_PV=${MY_PV/_alpha/a}
+ MY_PV=${MY_PV/_beta/b}
+ MY_PV=${MY_PV/_rc/RC}
+ MY_P="${PN}-${MY_PV}"
+ SRC_URI+=" https://github.com/xbmc/xbmc/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+ KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+ S=${WORKDIR}/xbmc-${MY_PV}
+fi
+
+inherit autotools cmake desktop linux-info pax-utils python-single-r1 xdg
+
+DESCRIPTION="A free and open source media-player and entertainment hub"
+HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+# use flag is called libusb so that it doesn't fool people in thinking that
+# it is _required_ for USB support. Otherwise they'll disable udev and
+# that's going to be worse.
+IUSE="airplay alsa bluetooth bluray caps cec +css dav1d dbus eventclients gbm gles lcms libusb lirc mariadb mysql nfs +optical power-control pulseaudio raspberry-pi samba +system-ffmpeg test udf udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
+IUSE="${IUSE} cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_arm_neon"
+REQUIRED_USE="
+ ${PYTHON_REQUIRED_USE}
+ || ( gbm wayland X )
+ ?? ( mariadb mysql )
+ bluray? ( udf )
+ udev? ( !libusb )
+ udisks? ( dbus )
+ upower? ( dbus )
+ power-control? ( dbus )
+ vdpau? (
+ X
+ !gles
+ !gbm
+ )
+ zeroconf? ( dbus )
+"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+ >=dev-libs/lzo-2.04
+ >=dev-libs/flatbuffers-1.12.0
+ >=media-libs/libjpeg-turbo-2.0.4:=
+ >=media-libs/libpng-1.6.26:0=
+"
+COMMON_TARGET_DEPEND="${PYTHON_DEPS}
+ airplay? (
+ >=app-pda/libplist-2.0.0
+ net-libs/shairplay
+ )
+ alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
+ bluetooth? ( net-wireless/bluez )
+ bluray? ( >=media-libs/libbluray-1.1.2 )
+ caps? ( sys-libs/libcap )
+ dbus? ( sys-apps/dbus )
+ dev-db/sqlite
+ dev-libs/crossguid
+ >=dev-libs/fribidi-1.0.5
+ cec? ( >=dev-libs/libcec-4.0[raspberry-pi?] )
+ dev-libs/libpcre[cxx]
+ >=dev-libs/spdlog-1.5.0:=
+ dev-libs/tinyxml[stl]
+ $(python_gen_cond_dep '
+ dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+ dev-python/pycryptodome[${PYTHON_MULTI_USEDEP}]
+ ')
+ >=dev-libs/libcdio-2.1.0[cxx]
+ >=dev-libs/libfmt-6.1.2
+ dev-libs/libfstrcmp
+ gbm? (
+ >=dev-libs/libinput-1.10.5
+ media-libs/mesa[gbm]
+ x11-libs/libxkbcommon
+ )
+ gles? (
+ !raspberry-pi? ( media-libs/mesa[gles2] )
+ )
+ lcms? ( media-libs/lcms:2 )
+ libusb? ( virtual/libusb:1 )
+ virtual/ttf-fonts
+ media-fonts/roboto
+ >=media-libs/freetype-2.10.1
+ >=media-libs/libass-0.13.4
+ !raspberry-pi? ( media-libs/mesa[egl] )
+ >=media-libs/taglib-1.11.1
+ system-ffmpeg? (
+ >=media-video/ffmpeg-${FFMPEG_VERSION}:=[dav1d?,encode,postproc]
+ media-video/ffmpeg[openssl]
+ )
+ !system-ffmpeg? (
+ app-arch/bzip2
+ dav1d? ( media-libs/dav1d )
+ )
+ mysql? ( dev-db/mysql-connector-c:= )
+ mariadb? ( dev-db/mariadb-connector-c:= )
+ >=net-misc/curl-7.68.0[http2]
+ nfs? ( >=net-fs/libnfs-2.0.0:= )
+ !gles? ( media-libs/glu )
+ >=dev-libs/openssl-1.0.2l:0=
+ raspberry-pi? (
+ || ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl,gles2,video_cards_vc4] )
+ )
+ pulseaudio? ( media-sound/pulseaudio )
+ samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
+ >=sys-libs/zlib-1.2.11
+ udf? ( >=dev-libs/libudfread-1.0.0 )
+ udev? ( virtual/udev )
+ vaapi? (
+ x11-libs/libva:=
+ !gles? ( x11-libs/libva[opengl] )
+ system-ffmpeg? ( media-video/ffmpeg[vaapi] )
+ vdpau? ( x11-libs/libva[vdpau] )
+ wayland? ( x11-libs/libva[wayland] )
+ X? ( x11-libs/libva[X] )
+ )
+ virtual/libiconv
+ vdpau? (
+ || ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
+ system-ffmpeg? ( media-video/ffmpeg[vdpau] )
+ )
+ wayland? (
+ >=dev-cpp/waylandpp-0.2.3:=
+ media-libs/mesa[wayland]
+ >=dev-libs/wayland-protocols-1.7
+ >=x11-libs/libxkbcommon-0.4.1
+ )
+ webserver? ( >=net-libs/libmicrohttpd-0.9.55[messages(+)] )
+ X? (
+ media-libs/mesa[X]
+ !gles? ( media-libs/libglvnd[X] )
+ x11-libs/libX11
+ x11-libs/libXrandr
+ x11-libs/libXrender
+ system-ffmpeg? ( media-video/ffmpeg[X] )
+ )
+ x11-libs/libdrm
+ xslt? (
+ dev-libs/libxslt
+ >=dev-libs/libxml2-2.9.4
+ )
+ zeroconf? ( net-dns/avahi[dbus] )
+"
+RDEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
+ lirc? ( app-misc/lirc )
+ power-control? ( || ( sys-apps/systemd sys-auth/elogind ) )
+ udisks? ( sys-fs/udisks:2 )
+ upower? ( sys-power/upower )
+"
+DEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
+ dev-libs/rapidjson
+ test? ( >=dev-cpp/gtest-1.10.0 )
+"
+BDEPEND="${COMMON_DEPEND}
+ dev-lang/swig
+ dev-util/cmake
+ media-libs/giflib
+ >=dev-libs/flatbuffers-1.11.0
+ >=media-libs/libjpeg-turbo-2.0.4:=
+ >=media-libs/libpng-1.6.26:0=
+ virtual/pkgconfig
+ virtual/jre
+"
+
+CONFIG_CHECK="~IP_MULTICAST"
+ERROR_IP_MULTICAST="
+In some cases Kodi needs to access multicast addresses.
+Please consider enabling IP_MULTICAST under Networking options.
+"
+
+pkg_setup() {
+ check_extra_config
+ python-single-r1_pkg_setup
+}
+
+src_unpack() {
+ if [[ ${PV} == *9999 ]] ; then
+ git-r3_src_unpack
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ cmake_src_prepare
+
+ # avoid long delays when powerkit isn't running #348580
+ sed -i \
+ -e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
+ xbmc/platform/linux/*.cpp || die
+
+ # Prepare tools and libs witch are configured with autotools during compile time
+ AUTOTOOLS_DIRS=(
+ "${S}"/tools/depends/native/TexturePacker/src
+ "${S}"/tools/depends/native/JsonSchemaBuilder/src
+ )
+
+ local d
+ for d in "${AUTOTOOLS_DIRS[@]}" ; do
+ pushd ${d} >/dev/null || die
+ AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
+ popd >/dev/null || die
+ done
+ elibtoolize
+
+ # Prevent autoreconf rerun
+ sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
+ "${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
+ "${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
+ || die
+}
+
+src_configure() {
+ local platform=()
+ use gbm && platform+=( gbm )
+ use wayland && platform+=( wayland )
+ use X && platform+=( x11 )
+ local core_platform_name="${platform[@]}"
+ local mycmakeargs=(
+ -DENABLE_SSE=$(usex cpu_flags_x86_sse)
+ -DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
+ -DENABLE_SSE3=$(usex cpu_flags_x86_sse3)
+ -DENABLE_SSE4_1=$(usex cpu_flags_x86_sse4_1)
+ -DENABLE_SSE4_2=$(usex cpu_flags_x86_sse4_2)
+ -DENABLE_AVX=$(usex cpu_flags_x86_avx)
+ -DENABLE_AVX2=$(usex cpu_flags_x86_avx2)
+ -DENABLE_NEON=$(usex cpu_flags_arm_neon)
+ -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+ -DVERBOSE=ON
+ -DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
+ -DENABLE_ALSA=$(usex alsa)
+ -DENABLE_AIRTUNES=$(usex airplay)
+ -DENABLE_AVAHI=$(usex zeroconf)
+ -DENABLE_BLUETOOTH=$(usex bluetooth)
+ -DENABLE_BLURAY=$(usex bluray)
+ -DENABLE_CCACHE=OFF
+ -DENABLE_CLANGFORMAT=OFF
+ -DENABLE_CLANGTIDY=OFF
+ -DENABLE_CPPCHECK=OFF
+ -DENABLE_ISO9660PP=$(usex optical)
+ -DENABLE_CEC=$(usex cec)
+ -DENABLE_DBUS=$(usex dbus)
+ -DENABLE_DVDCSS=$(usex css)
+ -DENABLE_EVENTCLIENTS=ON # alway enable to have 'kodi-send' and filter extra staff in 'src_install()'
+ -DENABLE_INTERNAL_CROSSGUID=OFF
+ -DENABLE_INTERNAL_RapidJSON=OFF
+ -DENABLE_INTERNAL_FMT=OFF
+ -DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
+ -DENABLE_INTERNAL_FSTRCMP=OFF
+ -DENABLE_INTERNAL_FLATBUFFERS=OFF
+ -DENABLE_INTERNAL_DAV1D=OFF
+ -DENABLE_INTERNAL_GTEST=OFF
+ -DENABLE_INTERNAL_UDFREAD=OFF
+ -DENABLE_INTERNAL_SPDLOG=OFF
+ -DENABLE_CAP=$(usex caps)
+ -DENABLE_LCMS2=$(usex lcms)
+ -DENABLE_LIRCCLIENT=$(usex lirc)
+ -DENABLE_MARIADBCLIENT=$(usex mariadb)
+ -DENABLE_MDNS=OFF # used only on Android
+ -DENABLE_MICROHTTPD=$(usex webserver)
+ -DENABLE_MYSQLCLIENT=$(usex mysql)
+ -DENABLE_NFS=$(usex nfs)
+ -DENABLE_OPENGLES=$(usex gles)
+ -DENABLE_OPENGL=$(usex !gles)
+ -DENABLE_OPTICAL=$(usex optical)
+ -DENABLE_PLIST=$(usex airplay)
+ -DENABLE_PULSEAUDIO=$(usex pulseaudio)
+ -DENABLE_SMBCLIENT=$(usex samba)
+ -DENABLE_SNDIO=OFF
+ -DENABLE_TESTING=$(usex test)
+ -DENABLE_UDEV=$(usex udev)
+ -DENABLE_UDFREAD=$(usex udf)
+ -DENABLE_UPNP=$(usex upnp)
+ -DENABLE_VAAPI=$(usex vaapi)
+ -DENABLE_VDPAU=$(usex vdpau)
+ -DENABLE_XSLT=$(usex xslt)
+ -Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
+ -Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
+ -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
+ -DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
+ -DPYTHON_LIBRARY="$(python_get_library_path)"
+ -DAPP_RENDER_SYSTEM="$(usex gles gles gl)"
+ -DCORE_PLATFORM_NAME="${core_platform_name}"
+ )
+
+ use !udev && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
+
+ use X && use !gles && mycmakeargs+=( -DENABLE_GLX=ON )
+
+ if use system-ffmpeg; then
+ mycmakeargs+=( -DWITH_FFMPEG="yes" )
+ else
+ mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
+ fi
+
+ if ! echo "${CFLAGS}" | grep -Fwqe '-DNDEBUG' - && ! echo "${CFLAGS}" | grep -Fwqe '-D_DEBUG' - ; then
+ CFLAGS+=' -DNDEBUG' # Kodi requires one of the 'NDEBUG' or '_DEBUG' defines
+ CXXFLAGS+=' -DNDEBUG'
+ fi
+
+ cmake_src_configure
+}
+
+src_compile() {
+ cmake_src_compile all
+}
+
+src_test() {
+ # see https://github.com/xbmc/xbmc/issues/17860#issuecomment-630120213
+ KODI_HOME="${BUILD_DIR}" cmake_build check
+}
+
+src_install() {
+ cmake_src_install
+
+ pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin
+
+ newicon media/icon48x48.png kodi.png
+
+ rm "${ED}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
+ dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
+ usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
+
+ if use !eventclients ; then
+ rm -f "${ED}"/usr/bin/kodi-ps3remote || die
+ rm -f "${D}"$(python_get_sitedir)/kodi/ps3_remote.py || die
+ rm -rf "${D}"$(python_get_sitedir)/kodi/ps3 || die
+ rm -rf "${D}"$(python_get_sitedir)/kodi/bt || die
+ rm -rf "${ED}"/usr/share/doc/${PF}/kodi-eventclients-dev || die
+ fi
+
+ python_optimize "${D}$(python_get_sitedir)"
+}
diff --git a/media-tv/kodi/kodi-19.9999.ebuild b/media-tv/kodi/kodi-19.9999.ebuild
index ef65967b6723..11329e6f4706 100644
--- a/media-tv/kodi/kodi-19.9999.ebuild
+++ b/media-tv/kodi/kodi-19.9999.ebuild
@@ -25,9 +25,9 @@ else
MY_PV=${MY_PV/_beta/b}
MY_PV=${MY_PV/_rc/RC}
MY_P="${PN}-${MY_PV}"
- SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz"
+ SRC_URI+=" https://github.com/xbmc/xbmc/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
- S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
+ S=${WORKDIR}/xbmc-${MY_PV}
fi
inherit autotools cmake desktop linux-info pax-utils python-single-r1 xdg
@@ -62,7 +62,7 @@ RESTRICT="!test? ( test )"
COMMON_DEPEND="
>=dev-libs/lzo-2.04
- >=dev-libs/flatbuffers-1.11.0
+ >=dev-libs/flatbuffers-1.12.0
>=media-libs/libjpeg-turbo-2.0.4:=
>=media-libs/libpng-1.6.26:0=
"
diff --git a/media-tv/kodi/kodi-9999.ebuild b/media-tv/kodi/kodi-9999.ebuild
index 1e3017a63585..1d0692f7deee 100644
--- a/media-tv/kodi/kodi-9999.ebuild
+++ b/media-tv/kodi/kodi-9999.ebuild
@@ -39,7 +39,7 @@ SLOT="0"
# use flag is called libusb so that it doesn't fool people in thinking that
# it is _required_ for USB support. Otherwise they'll disable udev and
# that's going to be worse.
-IUSE="airplay alsa bluetooth bluray caps cec +css dav1d dbus eventclients gbm gles lcms libusb lirc mariadb mysql nfs +optical power-control pulseaudio raspberry-pi samba +system-ffmpeg test udf udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
+IUSE="airplay alsa bluetooth bluray caps cec +css dav1d dbus eventclients gbm gles lcms libusb lirc mariadb mysql nfs +optical pipewire power-control pulseaudio raspberry-pi samba +system-ffmpeg test udf udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
IUSE="${IUSE} cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_arm_neon"
REQUIRED_USE="
${PYTHON_REQUIRED_USE}
@@ -122,6 +122,7 @@ COMMON_TARGET_DEPEND="${PYTHON_DEPS}
raspberry-pi? (
|| ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl,gles2,video_cards_vc4] )
)
+ pipewire? ( media-video/pipewire )
pulseaudio? ( media-sound/pulseaudio )
samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
>=sys-libs/zlib-1.2.11
@@ -285,6 +286,7 @@ src_configure() {
-DENABLE_OPENGL=$(usex !gles)
-DENABLE_OPTICAL=$(usex optical)
-DENABLE_PLIST=$(usex airplay)
+ -DENABLE_PIPEWIRE=$(usex pipewire)
-DENABLE_PULSEAUDIO=$(usex pulseaudio)
-DENABLE_SMBCLIENT=$(usex samba)
-DENABLE_SNDIO=OFF
diff --git a/media-tv/kodi/metadata.xml b/media-tv/kodi/metadata.xml
index b33526329c7c..215cec6e20fa 100644
--- a/media-tv/kodi/metadata.xml
+++ b/media-tv/kodi/metadata.xml
@@ -20,6 +20,7 @@
<flag name="dav1d">Enables AV1 decoding via <pkg>media-libs/dav1d</pkg></flag>
<flag name="nfs">Enable NFS client support</flag>
<flag name="optical">Enable Audio CD playback, optical disks detection and reading (CD-ROM, Video CD, and others), and ISO optical disk images direct reading. DVD disks may require additional 'udf' flag.</flag>
+ <flag name="pipewire">Enable pipewire support</flag>
<flag name="power-control">Enable control of shutdown, reboot, suspend, and hibernate</flag>
<flag name="raspberry-pi">Enable support for the Raspberry Pi</flag>
<flag name="system-ffmpeg">Use system ffmpeg instead of the bundled one</flag>
generated by cgit v1.2.3 (git 2.25.1) at 2024-10-31 01:58:40 +0000