5 files changed, 342 insertions, 0 deletions
diff --git a/media-video/Manifest.gz b/media-video/Manifest.gz
index c7fcbad326e7..624d672a2555 100644
--- a/media-video/Manifest.gz
+++ b/media-video/Manifest.gz
diff --git a/media-video/ffmpeg-chromium/Manifest b/media-video/ffmpeg-chromium/Manifest
index 21b8d43ad2b5..0a2a54f17b9a 100644
--- a/media-video/ffmpeg-chromium/Manifest
+++ b/media-video/ffmpeg-chromium/Manifest
@@ -2,8 +2,10 @@ AUX chromium.patch 1536 BLAKE2B 8caf1ff11f8da710138cbb857bd42e8679f98f3c30a3eadd
 AUX ffmpeg-chromium-120.patch 1485 BLAKE2B 49ece028bf7da100adc7af93e82b6235fb39f12199ce037b730b97012ca787047b45be821cec609cdfa7e00bb1f8c88a9ecae0b7b88fd8db6f53476b94833f9f SHA512 0f3276f75132bd8adbde4305ffa604cfa3d504ed66f883af109c75711d0f9af6dee2d55d7298ec36864a421250a0c4998d3306f0e47750c016c4274545195b49
 DIST ffmpeg-chromium-120.tar.xz 10096036 BLAKE2B 8f24dfed854c713df369e6ef15bc773a3166fdf6eb8c90bcb1d1b7ddddaca0702df7615bc323432a40b5d213352945fa49acf8e864df2caa358764b5068a75f3 SHA512 0e0bfb44225981f91edceeb6f302592a7e108da49c5e6503b43f0e12b91d84dece908efe5e548bb31ccab49c5fba5a8365f5f0793bbf1450d35bfd836f8a3e9b
 DIST ffmpeg-chromium-121.tar.xz 10128048 BLAKE2B ba8e25356b7e0820dffea1b919288ddb3d6ec56fe8d17493529ec978deae629607ff5a5857a313e478193a1fca55fa3e5256e37d57251141e1f0a892cbdcf674 SHA512 e6cef1285237673ce5851cbddf4cda77779821c247a120bf73af2b931745b2886c915a35bb2bc21a8a9c5154be9e540f8abccc3bb64e704f5b859141d0dcc2e1
+DIST ffmpeg-chromium-123.tar.xz 10323756 BLAKE2B b56afd5946513511938feeea4fd60e22fcf241a2380b36990eadf812b3517d6941156de73135efdc873704d27bc3329c71193be5132e462caaf7f2dc29e8a058 SHA512 635e1c5496d6f41fa5dd69efbe6dd335a15705dce8544fc45df440b19965caa130646d16b7c22b2b7cc0809979d28f39245fc5c208637e445b1fc1eb384da418
 DIST ffmpeg-chromium-124.tar.xz 10378648 BLAKE2B 3cb79d356e84d76a241ad81491d22d42b7a768e348d245bda00101e3967c0864e95a1dd83372e6aaf3a9130ff5ae38610fe2bd4ee8e21fc8247af4172af0683a SHA512 627d1ba81c50300e7188e8a2cc5f76ea9e81e817209631f2eecb81b7b9a0be60a12290eba16240dd0b0dce3d59550a8246be54df2035bd75a9e95ae77d67467b
 EBUILD ffmpeg-chromium-120.ebuild 6692 BLAKE2B db110de522d1885bcf2f5d3c45ca3b343943ecdbe594610a427baeae6e5e6521ee9abfebc6126b543da4c35b7715f464916e65a6c44205c69612a68fd7692317 SHA512 fd3b1ded196a4af08742723ab1ca36dda21e13c2899718e64b5ca3046474bb97042402b3870c2b9edeee3027a0f1eaba1f960bd4208c465651ad741ec8c361c8
 EBUILD ffmpeg-chromium-121.ebuild 6692 BLAKE2B 36aafbff5f4c4a7bf81d9fe1293a1962a8632f9df49012f08e7130e6050a2a026ee3b4394eca6456200ba30a2661a7fe7d1b4a3c5c95602d7865802d65587247 SHA512 a47296b03217d345a6465321ed51ae11a0a61991ea6b8790571e7c0754d1a0c9d91f7944f255dd6a05e255d863523b4637e0e9c21cc644541c04fd5abbd3a43d
+EBUILD ffmpeg-chromium-123.ebuild 6624 BLAKE2B 1af7239be5284f75702eef246fac3ad439458c3577da1ddb8316c3d9cbcfbf6b5c8fc4cb017c6ab3068fbffee32f3be8c80e7f82c6348526fba8e9c6e7f49ef8 SHA512 5d89484a22a09e738187647986d4e586b8dfd24e48bd9b0ec4729f65037814fd36715cc84f648fd44c3d7d121e6235f9690ec9653538508b4ddca65051c06aca
 EBUILD ffmpeg-chromium-124.ebuild 6626 BLAKE2B c2d9f1e7aa872e5852c68c0f0145662b5efb9479d87d96f635666fee2642ac59377e204ec6e0f46c8079232be8c1fd877f933495a48e4601584ab3b4a0273b2e SHA512 a33c6e9da4c73a11ec7c030b2a9641568e878e2fc76a81a296868264e4ecf9b56247cb2e7a311c13d1ea94223c8e9a6b651610160138d95e66273952a81bc5b8
 MISC metadata.xml 589 BLAKE2B 60a8f7a2eca511672dc67487956c589fffbb86ca6500d61c266916be92d1cde6c26246516289f129bbce05b07b811bdfcc0136d56676ce4097e5f19b361f375a SHA512 3953c626bb570af8cceedbf8b4035a0259e789823c296d11e6823237d05bd5d25a08260c6a8815bcea02bee56a522b0bb8da2b8aacd6be417b1992c4b0d22964
diff --git a/media-video/ffmpeg-chromium/ffmpeg-chromium-123.ebuild b/media-video/ffmpeg-chromium/ffmpeg-chromium-123.ebuild
new file mode 100644
index 000000000000..08fe358ac43b
--- /dev/null
+++ b/media-video/ffmpeg-chromium/ffmpeg-chromium-123.ebuild
@@ -0,0 +1,247 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+COMMIT=7c1b0b524c639beeb25363b1d0809ebe5c6efe5e
+DESCRIPTION="FFmpeg built specifically for codec support in Chromium-based browsers"
+HOMEPAGE="https://ffmpeg.org/"
+SRC_URI="https://deps.gentoo.zip/media-video/${P}.tar.xz"
+
+LICENSE="
+	!gpl? ( LGPL-2.1 )
+	gpl? ( GPL-2 )
+"
+SLOT="${PV}"
+
+KEYWORDS="~amd64 ~arm ~arm64"
+
+# Options to use as use_enable in the foo[:bar] form.
+# This will feed configure with $(use_enable foo bar)
+# or $(use_enable foo foo) if no :bar is set.
+# foo is added to IUSE.
+FFMPEG_FLAG_MAP=(
+		cpudetection:runtime-cpudetect debug
+		+gpl
+		vaapi vdpau vulkan
+		nvenc:ffnvcodec
+		# Threads; we only support pthread for now but ffmpeg supports more
+		+threads:pthreads
+)
+
+IUSE="
+	${FFMPEG_FLAG_MAP[@]%:*}
+"
+
+# Strings for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+ARM_CPU_FEATURES=(
+	cpu_flags_arm_thumb:armv5te
+	cpu_flags_arm_v6:armv6
+	cpu_flags_arm_thumb2:armv6t2
+	cpu_flags_arm_neon:neon
+	cpu_flags_arm_vfp:vfp
+	cpu_flags_arm_vfpv3:vfpv3
+	cpu_flags_arm_v8:armv8
+	cpu_flags_arm_asimddp:dotprod
+	cpu_flags_arm_i8mm:i8mm
+)
+ARM_CPU_REQUIRED_USE="
+	arm64? ( cpu_flags_arm_v8 )
+	cpu_flags_arm_v8? ( cpu_flags_arm_vfpv3 cpu_flags_arm_neon )
+	cpu_flags_arm_neon? (
+		cpu_flags_arm_vfp
+		arm? ( cpu_flags_arm_thumb2 )
+	)
+	cpu_flags_arm_vfpv3? ( cpu_flags_arm_vfp )
+	cpu_flags_arm_thumb2? ( cpu_flags_arm_v6 )
+	cpu_flags_arm_v6? (
+		arm? ( cpu_flags_arm_thumb )
+	)
+"
+X86_CPU_FEATURES_RAW=( 3dnow:amd3dnow 3dnowext:amd3dnowext aes:aesni avx:avx avx2:avx2 fma3:fma3 fma4:fma4 mmx:mmx
+					   mmxext:mmxext sse:sse sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4 sse4_2:sse42 xop:xop )
+X86_CPU_FEATURES=( ${X86_CPU_FEATURES_RAW[@]/#/cpu_flags_x86_} )
+X86_CPU_REQUIRED_USE="
+	cpu_flags_x86_avx2? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma4? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma3? ( cpu_flags_x86_avx )
+	cpu_flags_x86_xop?  ( cpu_flags_x86_avx )
+	cpu_flags_x86_avx?  ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_aes? ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_sse4_2?  ( cpu_flags_x86_sse4_1 )
+	cpu_flags_x86_sse4_1?  ( cpu_flags_x86_ssse3 )
+	cpu_flags_x86_ssse3?  ( cpu_flags_x86_sse3 )
+	cpu_flags_x86_sse3?  ( cpu_flags_x86_sse2 )
+	cpu_flags_x86_sse2?  ( cpu_flags_x86_sse )
+	cpu_flags_x86_sse?  ( cpu_flags_x86_mmxext )
+	cpu_flags_x86_mmxext?  ( cpu_flags_x86_mmx )
+	cpu_flags_x86_3dnowext?  ( cpu_flags_x86_3dnow )
+	cpu_flags_x86_3dnow?  ( cpu_flags_x86_mmx )
+"
+
+CPU_FEATURES_MAP=(
+	${ARM_CPU_FEATURES[@]}
+	${X86_CPU_FEATURES[@]}
+)
+IUSE="${IUSE}
+	${CPU_FEATURES_MAP[@]%:*}"
+
+CPU_REQUIRED_USE="
+	${ARM_CPU_REQUIRED_USE}
+	${X86_CPU_REQUIRED_USE}
+"
+
+RDEPEND="
+	>=media-libs/opus-1.0.2-r2
+	vaapi? ( >=media-libs/libva-1.2.1-r1:0= )
+	nvenc? ( >=media-libs/nv-codec-headers-11.1.5.3 )
+	vdpau? ( >=x11-libs/libvdpau-0.7 )
+	vulkan? ( >=media-libs/vulkan-loader-1.3.255:= )
+"
+
+DEPEND="${RDEPEND}
+	vulkan? ( >=dev-util/vulkan-headers-1.3.255 )
+"
+BDEPEND="
+	>=dev-build/make-3.81
+	virtual/pkgconfig
+	cpu_flags_x86_mmx? ( || ( >=dev-lang/nasm-2.13 >=dev-lang/yasm-1.3 ) )
+"
+
+REQUIRED_USE="
+	${CPU_REQUIRED_USE}"
+RESTRICT="
+	test
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-120.patch
+	"${FILESDIR}"/chromium.patch
+)
+
+src_prepare() {
+	export revision=git-N-g${COMMIT:0:10}
+	default
+
+	# -fdiagnostics-color=auto gets appended after user flags which
+	# will ignore user's preference.
+	sed -i -e '/check_cflags -fdiagnostics-color=auto/d' configure || die
+
+	echo 'include $(SRC_PATH)/ffbuild/libffmpeg.mak' >> Makefile || die
+}
+
+src_configure() {
+	local myconf=( )
+
+	# Bug #918997. Will probably be fixed upstream in the next release.
+	use vulkan && append-ldflags -Wl,-z,muldefs
+
+	# bug 842201
+	use ia64 && tc-is-gcc && append-flags \
+		-fno-tree-ccp \
+		-fno-tree-dominator-opts \
+		-fno-tree-fre \
+		-fno-code-hoisting \
+		-fno-tree-pre \
+		-fno-tree-vrp
+
+	local ffuse=( "${FFMPEG_FLAG_MAP[@]}" )
+
+	for i in "${ffuse[@]#+}" ; do
+		myconf+=( $(use_enable ${i%:*} ${i#*:}) )
+	done
+
+	# CPU features
+	for i in "${CPU_FEATURES_MAP[@]}" ; do
+		use ${i%:*} || myconf+=( --disable-${i#*:} )
+	done
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag mcpu) $(get-flag march) ; do
+		[[ ${i} = native ]] && i="host" # bug #273421
+		myconf+=( --cpu=${i} )
+		break
+	done
+
+	# LTO support, bug #566282, bug #754654, bug #772854
+	if [[ ${ABI} != x86 ]] && tc-is-lto; then
+		# Respect -flto value, e.g -flto=thin
+		local v="$(get-flag flto)"
+		[[ -n ${v} ]] && myconf+=( "--enable-lto=${v}" ) || myconf+=( "--enable-lto" )
+	fi
+	filter-lto
+
+	# Mandatory configuration
+	myconf=(
+		--disable-stripping
+		# This is only for hardcoded cflags; those are used in configure checks that may
+		# interfere with proper detections, bug #671746 and bug #645778
+		# We use optflags, so that overrides them anyway.
+		--disable-optimizations
+		--disable-libcelt # bug #664158
+		"${myconf[@]}"
+	)
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- --host-cc="$(tc-getBUILD_CC)" )
+		case ${CHOST} in
+			*mingw32*)
+				myconf+=( --target-os=mingw32 )
+				;;
+			*linux*)
+				myconf+=( --target-os=linux )
+				;;
+		esac
+	fi
+
+	# Use --extra-libs if needed for LIBS
+	set -- "${S}/configure" \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--nm="$(tc-getNM)" \
+		--strip="$(tc-getSTRIP)" \
+		--ranlib="$(tc-getRANLIB)" \
+		--pkg-config="$(tc-getPKG_CONFIG)" \
+		--optflags="${CFLAGS}" \
+		--disable-all \
+		--disable-autodetect \
+		--disable-error-resilience \
+		--disable-everything \
+		--disable-faan \
+		--disable-iconv \
+		--disable-network \
+		--enable-avcodec \
+		--enable-avformat \
+		--enable-avutil \
+		--enable-libopus \
+		--enable-decoder=aac,flac,h264,libopus,mp3,pcm_alaw,pcm_f32le,pcm_mulaw,pcm_s16be,pcm_s16le,pcm_s24be,pcm_s24le,pcm_s32le,pcm_u8,theora,vorbis,vp8 \
+		--enable-demuxer=aac,flac,matroska,mov,mp3,ogg,wav \
+		--enable-parser=aac,flac,h264,mpegaudio,opus,vorbis,vp3,vp8,vp9 \
+		--enable-pic \
+		--enable-static \
+		"${myconf[@]}" \
+		${EXTRA_FFMPEG_CONF}
+
+	echo "${@}"
+	"${@}" || die
+}
+
+src_compile() {
+	emake V=1 libffmpeg
+}
+
+src_install() {
+	emake V=1 DESTDIR="${D}" install-libffmpeg
+}
diff --git a/media-video/libva-utils/Manifest b/media-video/libva-utils/Manifest
index 9e1b5b3198f6..5edd313c8322 100644
--- a/media-video/libva-utils/Manifest
+++ b/media-video/libva-utils/Manifest
@@ -1,6 +1,8 @@
 DIST libva-utils-2.20.0.tar.gz 1280967 BLAKE2B b4d80eb3301a27b9e9ea31edf77f0f6d0bad8660d350fbc0ce4502a5f09b613b7d71ded94c1ce94697c3d679f9b06c099ebce4bf6c57b0e02f92f14458a12787 SHA512 e0edf08f90fc5b360c0123cd77fcb125be289700e62e3d53c92312175e0ee082f3714af3784f4b087de1379bb384c1cfc0f5f881e5a9b31d4806bc3216eacbf0
 DIST libva-utils-2.20.1.tar.gz 1281764 BLAKE2B 9561270811a3d9c314a1f3b73a363b1c7fdda2f38a45404a3e1760eb8ee2384288a589e7b6e001e902e8b9d5ee9611839eccec9a9a89fd5676670a5792e3d3ab SHA512 65f7e03a242a520aae4f9e7ea16ea1c437d7915582a21287f23a05c246b92f1691be3e47d9d92cab9eb6eabb190ba77c6cd0bb3a5fec88898a33b352fc70b5a0
+DIST libva-utils-2.21.0.tar.gz 1281468 BLAKE2B 9b7027e5e9a46961af5da0883deb5dcde4bb2128ff73a99a4b71385a63afd44b9ce01ca863949c305d4c07ed9d02150e472fed5be42b6bce8f20ff993d2633a7 SHA512 b56b5c29e8210cb448cec34fd057865b9332d219e486a324a9fa716f791d8d10cd83e8c1e91248c11e6387b442142a7d1fafae0ded3caab44179fd6dca23fcbc
 EBUILD libva-utils-2.20.0.ebuild 1887 BLAKE2B af617d30f0280a3db0acd79210fc4a9a87fac15ab625708c334d283213ffe5f195bdffcca9c3f9ce0aa5ad955d7b14f5aac9126ce2d7e7369583a4553832f5df SHA512 b3747cb360cfd2c1f5a39319e9e286d4673afdc3ec4e39155af3d5fea7d680fd0f6faa1f3a7ce67af4cc15a6306afc89daaa710e71a3c34bc973140d3714a98b
 EBUILD libva-utils-2.20.1.ebuild 1894 BLAKE2B 0699d208d7af8bca1692a98daefea2acd5c5602da7fc9f77376dddbfb3be381b1ca86ddbc7dc660fce445cbef0b6798c3220693018cf287d213d8c7162229364 SHA512 953a158fc3e4ab1582a57ddadaf064b910b50d3ed7c36d463ceb7dd7d005ed4798a52ac059c084ad4a4ec7d055c21f3eac7d6f00953aecd8f558058ccdd8ef07
+EBUILD libva-utils-2.21.0.ebuild 1898 BLAKE2B d055c2e615c6b198ffca2e1b23cbe2a9953c5d0c8d8d47f6d48aa8a59bed5b81d2df4f0deadaacb11debe96ad982f356d874b55ed01b8b6c252eac4a3da2c1c2 SHA512 9e98a7d0f5d2ec9161aaf20e4bccef9bcfa347b09c34bf920eff910ef3b0b3bf6b906082eca06e3f727cadf18d7e426c640db12be720dc4571e9a3c3b1418d1c
 EBUILD libva-utils-9999.ebuild 1903 BLAKE2B 977bd6b9097f5fc340e8d59ff5fbfcb7ec0e9f81ac9b9b4bdd4b8a3af3647c895e496dd0c671dcbebe48275469e0fde2288333f4e1f87808642293ca1fa46580 SHA512 c85d4d3322e2851e23a528c031f363a5e06c3982b5bcded6b08471ea9f07e8f91608b50b53d7b0564fb16f6c9b57b379dc524ab27344195d96a68cac14514462
 MISC metadata.xml 596 BLAKE2B 856d27918d6cd6c983271e4f762f7b1278bd90231d33181b5381dbc425523d637c65902526ed1b48a0df6aadf41d77bd249e886dbc485edf93f5394fa458cd13 SHA512 46e6d1ef1cc966aadb696293fb1b5f86d1f3fe5d0245ca01a2d9be6d1b35f29830cee41d4e04f0c8d557dd20eb41ae927dc60a854ce24862a2b2f7fc8faee766
diff --git a/media-video/libva-utils/libva-utils-2.21.0.ebuild b/media-video/libva-utils/libva-utils-2.21.0.ebuild
new file mode 100644
index 000000000000..60f57e6e4c4a
--- /dev/null
+++ b/media-video/libva-utils/libva-utils-2.21.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Collection of utilities and tests for VA-API"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+if [[ ${PV} = *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/intel/libva-utils"
+else
+	SRC_URI="https://github.com/intel/libva-utils/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="examples putsurface test +vainfo wayland X"
+RESTRICT="test" # Tests must be run manually
+
+REQUIRED_USE="
+	putsurface? ( || ( wayland X ) )
+	|| ( examples putsurface test vainfo )
+"
+
+DEPEND="
+	x11-libs/libdrm
+	wayland? ( >=dev-libs/wayland-1.0.6 )
+	X? ( >=x11-libs/libX11-1.6.2 )
+"
+if [[ ${PV} = *9999 ]] ; then
+	DEPEND+="~media-libs/libva-${PV}:=[wayland?,X?]"
+else
+	DEPEND+=">=media-libs/libva-$(ver_cut 1-2).0:=[wayland?,X?]"
+fi
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	local sed_args=()
+
+	if ! use examples ; then
+		sed_args+=(
+			-e "/^  subdir('decode')$/d"
+			-e "/^  subdir('encode')$/d"
+			-e "/^  subdir('videoprocess')$/d"
+			-e "/^  subdir('vendor\/intel')$/d"
+			-e "/^  subdir('vendor\/intel\/sfcsample')$/d"
+		)
+	fi
+
+	if ! use putsurface ; then
+		sed_args+=(-e "/^  subdir('putsurface')$/d")
+	fi
+
+	if ! use vainfo ; then
+		sed_args+=(-e "/^subdir('vainfo')$/d")
+	fi
+
+	if [[ ${#sed_args[@]} -gt 0 ]] ; then
+		sed "${sed_args[@]}" -i meson.build || die
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddrm=true
+		$(meson_use X x11)
+		$(meson_use wayland)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use test ; then
+		rm -f "${ED}"/usr/bin/test_va_api || die
+	fi
+}
+
+pkg_postinst() {
+	if use test ; then
+		elog "Tests must be run manually with the test_va_api binary"
+	fi
+}