3 files changed, 56 insertions, 47 deletions
diff --git a/net-libs/libdom/Manifest b/net-libs/libdom/Manifest
index 803eb0a57e7f..488e83c142c8 100644
--- a/net-libs/libdom/Manifest
+++ b/net-libs/libdom/Manifest
@@ -1,4 +1,3 @@
 DIST libdom-0.3.3-src.tar.gz 870035 BLAKE2B 6dc77fe0ef31e491810243b461e6e7fbab2d6d2bb56e68730497ed9e0e1acf9dfcc29be024bd0010292e57d25849124153772c24503012fbdf38d24363f35a05 SHA512 3b08b20976b36adf441f088e9feb756b9ce6a43133e57b90fa6d6b8809d74c6d500c7d2a883dd19d520c6ef71d9e04685d9765e6c6a00677a412265ecc6273a8
-DIST netsurf-buildsystem-1.7.tar.gz 38597 BLAKE2B d0981ef282ac0d93d81a1a6a6bee1fc2a0151c962be6ce2900a67843ba8ebc67e00508cded2a7375f6bbe0d45572690f127872936a282de80eb08655ac571603 SHA512 f6a46ac25f41e695ec13d7b2b564250c4cc44a40a688904eb17aa4b547c2df0102cc0effb7a23a2ffa6b9178ae5cf452b63980caf26e06e479168c85803f1e58
-EBUILD libdom-0.3.3.ebuild 1154 BLAKE2B 97f611afccded19c7292e00a39187662116fac41740a7ce5d8afdfb2b92b33e7d412f5ad7eed97d15b83e0e3b46889cdf566017d8bf724c24479a6f4ee064ad4 SHA512 2719a5b91644a7ff0628cfbeb3a9c63e627db62e19a717f308e8b704f04179b8481fe973e2e7168b92113d44f2494717c96493622f9ef7f02a67ca4d4cb20313
+EBUILD libdom-0.3.3-r1.ebuild 1185 BLAKE2B c6de672965f301871fa75fc13f0d00b0d9194a1c31fa6598eadbc2f1bcc218fe96fd583a234d42f09208226e1440ce1e3bf91fd79f4c3d8a1d6bc4b271347a2b SHA512 c89a58ad9f4077eaa68b506934793afce125c41cea3b3fa71bbd0acac6da5ac8f1aaf28de806867061a5ccdf1a9c7eb69062f6bcec7acfd3a4d37fabc57b4c79
 MISC metadata.xml 351 BLAKE2B 874efc4523403eb768a93b6ad01c165fda3ce9e7b55fabba72fbe39efc632c1b9cbdc440819ad959c4ed40383ab7221372e357147eb7e1906474880b7f75dca2 SHA512 b70d3c086edb1523342a001fe46b5a630996047ea46dc9042e6f333ef771a6fd1ccec693fb0f0f842fc8a97300461a32fb363a1110e0f7166d1a0d72270cc6aa
diff --git a/net-libs/libdom/libdom-0.3.3-r1.ebuild b/net-libs/libdom/libdom-0.3.3-r1.ebuild
new file mode 100644
index 000000000000..12f44fe06415
--- /dev/null
+++ b/net-libs/libdom/libdom-0.3.3-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="implementation of the W3C DOM, written in C"
+HOMEPAGE="http://www.netsurf-browser.org/projects/libdom/"
+SRC_URI="https://download.netsurf-browser.org/libs/releases/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~ppc ~m68k-mint"
+IUSE="expat test xml"
+
+RDEPEND="
+	>=dev-libs/libparserutils-0.2.1-r1
+	>=dev-libs/libwapcaplet-0.3.0
+	>=net-libs/libhubbub-0.3.1-r1
+	xml? (
+		expat? ( >=dev-libs/expat-2.1.0-r3 )
+		!expat? ( >=dev-libs/libxml2-2.9.1-r4 )
+	)"
+DEPEND="${RDEPEND}
+	dev-util/netsurf-buildsystem
+	virtual/pkgconfig
+	test? (
+		dev-perl/XML-XPath
+		dev-perl/libxml-perl
+		dev-perl/Switch
+	)"
+
+REQUIRED_USE="test? ( xml )"
+
+_emake() {
+	source /usr/share/netsurf-buildsystem/gentoo-helpers.sh
+	netsurf_define_makeconf
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared \
+		WITH_EXPAT_BINDING=$(usex xml $(usex expat yes no) no) \
+		WITH_LIBXML_BINDING=$(usex xml $(usex expat no yes) no) \
+		$@
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${ED}" install
+}
diff --git a/net-libs/libdom/libdom-0.3.3.ebuild b/net-libs/libdom/libdom-0.3.3.ebuild
deleted file mode 100644
index d245b9d4989f..000000000000
--- a/net-libs/libdom/libdom-0.3.3.ebuild
+++ /dev/null
@@ -1,45 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-NETSURF_BUILDSYSTEM=buildsystem-1.7
-inherit netsurf
-
-DESCRIPTION="implementation of the W3C DOM, written in C"
-HOMEPAGE="http://www.netsurf-browser.org/projects/libdom/"
-
-LICENSE="MIT"
-SLOT="0/${PV}"
-KEYWORDS="~amd64 ~arm ~ppc ~m68k-mint"
-IUSE="expat test xml"
-
-RDEPEND=">=dev-libs/libparserutils-0.2.1-r1[static-libs?,${MULTILIB_USEDEP}]
-	>=dev-libs/libwapcaplet-0.3.0[static-libs?,${MULTILIB_USEDEP}]
-	>=net-libs/libhubbub-0.3.1-r1[static-libs?,${MULTILIB_USEDEP}]
-	xml? (
-		expat? ( >=dev-libs/expat-2.1.0-r3[static-libs?,${MULTILIB_USEDEP}] )
-		!expat? ( >=dev-libs/libxml2-2.9.1-r4[static-libs?,${MULTILIB_USEDEP}] )
-	)"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-	test? ( dev-perl/XML-XPath
-		dev-perl/libxml-perl
-		dev-perl/Switch )"
-
-REQUIRED_USE="test? ( xml )"
-
-src_prepare() {
-	# working around broken netsurf eclass
-	default
-	multilib_copy_sources
-}
-
-src_configure() {
-	netsurf_src_configure
-
-	netsurf_makeconf+=(
-		WITH_EXPAT_BINDING=$(usex xml $(usex expat yes no) no)
-		WITH_LIBXML_BINDING=$(usex xml $(usex expat no yes) no)
-	)
-}