1 files changed, 0 insertions, 75 deletions
diff --git a/net-misc/yt-dlp/yt-dlp-2024.03.10.ebuild b/net-misc/yt-dlp/yt-dlp-2024.03.10.ebuild
deleted file mode 100644
index b7afca90955e..000000000000
--- a/net-misc/yt-dlp/yt-dlp-2024.03.10.ebuild
+++ /dev/null
@@ -1,75 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{10..12} )
-inherit bash-completion-r1 distutils-r1 optfeature wrapper
-
-DESCRIPTION="youtube-dl fork with additional features and fixes"
-HOMEPAGE="https://github.com/yt-dlp/yt-dlp/"
-SRC_URI="
-	https://github.com/yt-dlp/yt-dlp/releases/download/${PV}/${PN}.tar.gz
-		-> ${P}.tar.gz
-"
-S="${WORKDIR}/${PN}"
-
-LICENSE="Unlicense"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 ~hppa ppc ppc64 ~riscv x86 ~arm64-macos ~x64-macos"
-
-RDEPEND="
-	dev-python/pycryptodome[${PYTHON_USEDEP}]
-	!net-misc/youtube-dl[-yt-dlp(-)]
-"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	# adjust pycryptodome and drop optional dependencies (bug #828466)
-	sed -Ei pyproject.toml \
-		-e 's/("pycryptodome)x/\1/' \
-		-e '/"(brotli.*|certifi|mutagen|requests|urllib3|websockets)/d' || die
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# fails with FEATURES=distcc, bug #915614
-		test/test_networking.py::TestYoutubeDLNetworking::test_proxy\[None-expected2\]
-	)
-
-	epytest -m 'not download'
-}
-
-python_install_all() {
-	dodoc README.md Changelog.md supportedsites.md
-	doman yt-dlp.1
-
-	dobashcomp completions/bash/yt-dlp
-
-	insinto /usr/share/fish/vendor_completions.d
-	doins completions/fish/yt-dlp.fish
-
-	insinto /usr/share/zsh/site-functions
-	doins completions/zsh/_yt-dlp
-
-	rm -r "${ED}"/usr/share/doc/yt_dlp || die
-
-	make_wrapper youtube-dl "yt-dlp --compat-options youtube-dl"
-}
-
-pkg_postinst() {
-	optfeature "various features (merging tracks, streamed content)" media-video/ffmpeg
-	has_version media-video/atomicparsley || # allow fallback but don't advertise
-		optfeature "embedding metadata thumbnails in MP4/M4A files" media-libs/mutagen
-	optfeature "decrypting cookies from Chromium-based browsers" dev-python/secretstorage
-
-	if [[ ! ${REPLACING_VERSIONS} ]]; then
-		elog 'A wrapper using "yt-dlp --compat-options youtube-dl" was installed'
-		elog 'as "youtube-dl". This is strictly for compatibility and it is'
-		elog 'recommended to use "yt-dlp" directly, it may be removed in the future.'
-	fi
-}