1 files changed, 59 insertions, 0 deletions
diff --git a/net-p2p/ncdc/ncdc-1.23.ebuild b/net-p2p/ncdc/ncdc-1.23.ebuild
new file mode 100644
index 000000000000..dea5357e9c22
--- /dev/null
+++ b/net-p2p/ncdc/ncdc-1.23.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="ncurses directconnect client"
+HOMEPAGE="https://dev.yorhel.nl/ncdc"
+if [[ ${PV} == *9999 ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="git://g.blicky.net/ncdc.git"
+else
+	SRC_URI="https://dev.yorhel.nl/download/${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="geoip"
+
+RDEPEND="
+	app-arch/bzip2
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.32:2
+	>=net-libs/gnutls-3:=
+	sys-libs/ncurses:=[unicode(+)]
+	sys-libs/zlib:=
+	geoip? (
+		dev-libs/geoip
+		dev-libs/libmaxminddb
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/makeheaders
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with geoip)
+	)
+
+	if [[ ${PV} == *9999 ]] ; then
+		myeconfargs+=( --enable-git-version )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}