1 files changed, 50 insertions, 0 deletions
diff --git a/net-vpn/iodine/iodine-0.7.0-r4.ebuild b/net-vpn/iodine/iodine-0.7.0-r4.ebuild
new file mode 100644
index 000000000000..acd02810647f
--- /dev/null
+++ b/net-vpn/iodine/iodine-0.7.0-r4.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info toolchain-funcs
+
+DESCRIPTION="IP over DNS tunnel"
+HOMEPAGE="https://code.kryo.se/iodine/"
+SRC_URI="https://code.kryo.se/${PN}/${P}.tar.gz"
+
+CONFIG_CHECK="~TUN"
+
+LICENSE="ISC GPL-2" #GPL-2 for init script bug #426060
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-TestMessage.patch
+	"${FILESDIR}"/${P}-new-systemd.patch
+)
+
+src_prepare() {
+	default
+
+	sed -e '/^\s@echo \(CC\|LD\)/d' \
+		-e 's:^\(\s\)@:\1:' \
+		-i {,src/}Makefile || die
+
+	tc-export CC
+}
+
+src_install() {
+	# Don't re-run submake
+	sed -e '/^install:/s: all: :' \
+		-i Makefile || die
+	emake prefix="${EPREFIX}"/usr DESTDIR="${D}" install
+	einstalldocs
+
+	newinitd "${FILESDIR}"/iodined-1.init-r1 iodined
+	newconfd "${FILESDIR}"/iodined.conf-r1 iodined
+	keepdir /var/empty
+	fperms 600 /etc/conf.d/iodined
+}