summaryrefslogtreecommitdiff
path: root/net-wireless/gnuradio
diff options
context:
space:
mode:
Diffstat (limited to 'net-wireless/gnuradio')
-rw-r--r--net-wireless/gnuradio/Manifest5
-rw-r--r--net-wireless/gnuradio/gnuradio-3.8.5.0-r1.ebuild225
-rw-r--r--net-wireless/gnuradio/gnuradio-3.8.5.0.ebuild2
-rw-r--r--net-wireless/gnuradio/gnuradio-9999.ebuild2
4 files changed, 230 insertions, 4 deletions
diff --git a/net-wireless/gnuradio/Manifest b/net-wireless/gnuradio/Manifest
index 69e658d432bf..71d84e92de5a 100644
--- a/net-wireless/gnuradio/Manifest
+++ b/net-wireless/gnuradio/Manifest
@@ -1,6 +1,7 @@
DIST gnuradio-3.8.4.0.tar.gz 3395297 BLAKE2B 454724e61306bee4991f8a44c80963080b632f767cbb70e00ee518aa096f150a9bb5c29304b9c30a84ab537b8b19ccd2955806fadb88a6cc4d24a8531e8c0127 SHA512 80d34c6351947f45decf8ba09288d4fc4c411c8d286d2765fad59da421b99c15a4c7b7c25a17c89dacfafd872f13ba8d9a8d84d89a35568e5b088f77fcaaae67
DIST gnuradio-3.8.5.0.tar.gz 3399660 BLAKE2B 19e3eecb40d7cdafe6fe551d3d36c0fcd34bb92ceb316537f4ebdc1c90d3c649daa1383f3642e2f64bba23026ed6638168fa77da0f21db03330b066e3108c880 SHA512 9b367c8afeb278b90e8ddd835e0ba301f07a53da26791e74913c812bde251daaa8f9611f21969938b215c9a110c9e69dfb6ec8b6d0db9c64013707c57596819a
EBUILD gnuradio-3.8.4.0.ebuild 6115 BLAKE2B 95a4129cea2b525222a8cd998765337798aceb7cdf513ddea9d79a69287bb5b9d022121d9e19cc644515616de7f64828a93654ed4e42a39a6ac623a2f416e70a SHA512 00f69d0d140312ae462b26d7deddabd262c9958f76308f3c32b2cd27d418fcb1527cc969af5cf3c0ff6124fd5ce5021c8175b687c1f1881deff4265a872b7135
-EBUILD gnuradio-3.8.5.0.ebuild 6122 BLAKE2B 92fb30d18eb3d954910ff31e8fc7a098f8551230fc9a7288fdf482ff343efd689fe61d0cc857b6dc07f03078f72f9b579c07a203bb50e0f7a4196e52ef635b1d SHA512 b784ab92e33db9d71744ae901964f202468ef17103b6c98cb87aacc8c11f6b43ebdf4cc67c426895292fa7264cbe2e4b2a1a591685fe17c07cc3451708bcf93d
-EBUILD gnuradio-9999.ebuild 5982 BLAKE2B 30f570a9020f7a0684168a83ade51dd024088fefcfbc7048a35f23f4a08a8e55ecf7c1f314741081a443e7239ec0e552ece489a8b1f85c641733e48f530801ad SHA512 3199d0147dfb15218524558d11eb61566e8b8f65b547c9eb0c42b7438f8c6aa751f24a1fa281336a3d0d4dbd2e27ab40c6688b038f7000fadacff668751e0f40
+EBUILD gnuradio-3.8.5.0-r1.ebuild 6179 BLAKE2B 0a80d18deaf566e360a3ac27f9f9be82b1ca77f863e55f63d33e2db2963be501fbb48ff40d803f517ab9d1d6942f70e1308403283ba02994869c583ce8a798cf SHA512 2cb684eb7e6ed1720789adb1a856b0b789d78973f288c02288ecfce734118f7d5d27feda40816981e9633ee925d23d4252317587941983ef1e6829654ffe4b7e
+EBUILD gnuradio-3.8.5.0.ebuild 6125 BLAKE2B 80ff9f450051087bf7d4801115097ca83423c9bb30149c416141bd09fd6b054d6c19a477a09dac84cbfecda14b731d48265e6be0ad50173bf8f47868b4025eab SHA512 5ec39ebc2b28a720a1c19573ad20ff2e7c4a992e3467c7ac999d47044ad212d6ef88f840dcc5cdf7526153656eba58c159c47a2e13c3c61459170788b9e7c74d
+EBUILD gnuradio-9999.ebuild 5985 BLAKE2B 93ab02962149379a688c3db4db570cddb1da16d87fc4955327a22550f1a17eca6b034a69e28d92bafb1915427d659e4292883b231315ce8ed4f002bc35409465 SHA512 3de04e75f3d94d03d21f353ffcf4d8100520772d1864e4f814a6056cd6a5b10abcf3ee6077d28c6dc3126e6989b7993686a279780c2d3a75ceb66c84c9f07dad
MISC metadata.xml 1676 BLAKE2B 9dc4c025e09d54b083b7681f5a06e491375d9621fbb60d0a0b8c218da0e9a3d7cc557aaac86002984bf0b7dbc82848261d3ec0cceeb0cb35ebaed92675cea2a9 SHA512 e52efa5ac1bb1dc576b2802d581741c43622aabfac2133b1e3aefdcec671e2c67631f91c1322d22a4b315e1e12c006cc696dd97aa0f18ebace534cc249251b12
diff --git a/net-wireless/gnuradio/gnuradio-3.8.5.0-r1.ebuild b/net-wireless/gnuradio/gnuradio-3.8.5.0-r1.ebuild
new file mode 100644
index 000000000000..a8da90f2bd12
--- /dev/null
+++ b/net-wireless/gnuradio/gnuradio-3.8.5.0-r1.ebuild
@@ -0,0 +1,225 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+
+CMAKE_BUILD_TYPE="None"
+inherit cmake python-single-r1 virtualx xdg-utils
+
+DESCRIPTION="Toolkit that provides signal processing blocks to implement software radios"
+HOMEPAGE="https://www.gnuradio.org/"
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+
+if [[ ${PV} =~ "9999" ]]; then
+ EGIT_REPO_URI="https://github.com/gnuradio/gnuradio.git"
+ EGIT_BRANCH="maint-3.8"
+ inherit git-r3
+else
+ SRC_URI="https://github.com/gnuradio/gnuradio/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+IUSE="+audio +alsa +analog +digital channels ctrlport doc dtv examples fec +filter grc jack modtool oss performance-counters portaudio +qt5 sdl test trellis uhd vocoder +utils wavelet zeromq"
+
+#RESTRICT="!test? ( test )"
+#Tests are known broken right now
+RESTRICT="test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ audio? ( || ( alsa oss jack portaudio ) )
+ alsa? ( audio )
+ jack? ( audio )
+ oss? ( audio )
+ portaudio? ( audio )
+ analog? ( filter )
+ channels? ( filter analog qt5 )
+ digital? ( filter analog )
+ dtv? ( filter analog fec )
+ modtool? ( utils )
+ qt5? ( filter )
+ trellis? ( analog digital )
+ uhd? ( filter analog )
+ vocoder? ( filter analog )
+ wavelet? ( analog )
+"
+
+RDEPEND="${PYTHON_DEPS}
+ $(python_gen_cond_dep 'dev-libs/boost:0=[python,${PYTHON_USEDEP}]')
+ dev-libs/log4cpp:=
+ $(python_gen_cond_dep 'dev-python/six[${PYTHON_USEDEP}]')
+ sci-libs/fftw:3.0=
+ sci-libs/mpir:=
+ sci-libs/volk:=
+ alsa? ( media-libs/alsa-lib:= )
+ ctrlport? ( $(python_gen_cond_dep 'dev-python/thrift[${PYTHON_USEDEP}]') )
+ fec? (
+ sci-libs/gsl:=
+ dev-python/scipy
+ )
+ filter? (
+ dev-python/scipy
+ $(python_gen_cond_dep 'dev-python/pyqtgraph[${PYTHON_USEDEP}]')
+ )
+ grc? (
+ $(python_gen_cond_dep 'dev-python/mako[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]')
+ x11-libs/gtk+:3[introspection]
+ x11-libs/pango[introspection]
+ )
+ jack? ( virtual/jack )
+ portaudio? ( >=media-libs/portaudio-19_pre )
+ qt5? (
+ $(python_gen_cond_dep 'dev-python/PyQt5[opengl,${PYTHON_USEDEP}]')
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ x11-libs/qwt:6[qt5(+)]
+ dev-qt/qtwidgets:5
+ )
+ sdl? ( >=media-libs/libsdl-1.2.0 )
+ trellis? ( dev-python/scipy )
+ uhd? (
+ $(python_gen_cond_dep '>=net-wireless/uhd-3.9.6:=[${PYTHON_SINGLE_USEDEP}]')
+ )
+ utils? (
+ $(python_gen_cond_dep 'dev-python/click[${PYTHON_USEDEP}]
+ dev-python/click-plugins[${PYTHON_USEDEP}]
+ dev-python/mako[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]')
+ )
+ vocoder? (
+ media-sound/gsm
+ >=media-libs/codec2-0.8.1:=
+ )
+ wavelet? (
+ sci-libs/gsl:=
+ dev-libs/gmp:=
+ sci-libs/lapack
+ )
+ zeromq? ( >=net-libs/zeromq-2.1.11:= )
+"
+
+#That's right, it can't build if gnuradio 3.7 is installed
+#Both due to build failure, and then file collision due to bundled volk
+DEPEND="${RDEPEND}
+ !!<net-wireless/gnuradio-3.8
+ app-text/docbook-xml-dtd:4.2
+ >=dev-lang/swig-3.0.5
+ virtual/pkgconfig
+ doc? (
+ >=app-doc/doxygen-1.5.7.1
+ )
+ grc? ( x11-misc/xdg-utils )
+ oss? ( virtual/os-headers )
+ test? ( >=dev-util/cppunit-1.9.14 )
+ zeromq? ( net-libs/cppzmq )
+"
+
+src_prepare() {
+ xdg_environment_reset #534582
+
+ use !alsa && sed -i 's#version.h#version-nonexistent.h#' cmake/Modules/FindALSA.cmake
+ use !jack && sed -i 's#jack.h#jack-nonexistent.h#' cmake/Modules/FindJACK.cmake
+ use !oss && sed -i 's#soundcard.h#oss-nonexistent.h#g' cmake/Modules/FindOSS.cmake
+ use !portaudio && sed -i 's#portaudio.h#portaudio-nonexistent.h#g' cmake/Modules/FindPORTAUDIO.cmake
+
+ cmake_src_prepare
+}
+
+src_configure() {
+ mycmakeargs=(
+ -DENABLE_DEFAULT=OFF
+ -DENABLE_VOLK=OFF
+ -DENABLE_INTERNAL_VOLK=OFF
+ -DENABLE_GNURADIO_RUNTIME=ON
+ -DENABLE_PYTHON=ON
+ -DENABLE_GR_BLOCKS=ON
+ -DENABLE_GR_FFT=ON
+ -DENABLE_GR_AUDIO=ON
+ -DENABLE_GR_ANALOG="$(usex analog)"
+ -DENABLE_GR_CHANNELS="$(usex channels)"
+ -DENABLE_GR_CTRLPORT="$(usex ctrlport)"
+ -DENABLE_GR_DIGITAL="$(usex digital)"
+ -DENABLE_DOXYGEN="$(usex doc)"
+ -DENABLE_GR_DTV="$(usex dtv)"
+ -DENABLE_GR_FEC="$(usex fec)"
+ -DENABLE_GR_FILTER="$(usex filter)"
+ -DENABLE_GRC="$(usex grc)"
+ -DENABLE_GR_MODTOOL="$(usex modtool)"
+ -DENABLE_PERFORMANCE_COUNTERS="$(usex performance-counters)"
+ -DENABLE_TESTING="$(usex test)"
+ -DENABLE_GR_TRELLIS="$(usex trellis)"
+ -DENABLE_GR_UHD="$(usex uhd)"
+ -DENABLE_GR_UTILS="$(usex utils)"
+ -DENABLE_GR_VOCODER="$(usex vocoder)"
+ -DENABLE_GR_WAVELET="$(usex wavelet)"
+ -DENABLE_GR_QTGUI="$(usex qt5)"
+ -DENABLE_GR_VIDEO_SDL="$(usex sdl)"
+ -DENABLE_GR_ZEROMQ="$(usex zeromq)"
+ -DSYSCONFDIR="${EPREFIX}"/etc
+ -DPYTHON_EXECUTABLE="${PYTHON}"
+ -DGR_PYTHON_DIR="$(python_get_sitedir)"
+ -DGR_PKG_DOC_DIR="${EPREFIX}/usr/share/doc/${PF}"
+ )
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ if use examples ; then
+ dodir /usr/share/doc/${PF}/
+ mv "${ED}"/usr/share/${PN}/examples "${ED}"/usr/share/doc/${PF}/ || die
+ docompress -x /usr/share/doc/${PF}/examples
+ else
+ # It seems that the examples are always installed
+ rm -rf "${ED}"/usr/share/${PN}/examples || die
+ fi
+
+ if use doc || use examples; then
+ #this doesn't appear useful
+ rm -rf "${ED}"/usr/share/doc/${PF}/xml || die
+ fi
+
+ # Remove duplicated icons, MIME and desktop files and installation script
+ rm -rf "${ED}"/usr/share/${PN}/grc/freedesktop || die
+ rm -f "${ED}"/usr/libexec/${PN}/grc_setup_freedesktop || die
+
+ # Install icons, menu items and mime-types for GRC
+ #if use grc ; then
+ # local fd_path="${S}/grc/scripts/freedesktop"
+ # insinto /usr/share/mime/packages
+ # doins "${fd_path}/${PN}-grc.xml"
+
+ # domenu "${fd_path}/"*.desktop
+ # doicon "${fd_path}/"*.png
+ #fi
+
+ python_fix_shebang "${ED}"
+ # Remove incorrectly byte-compiled Python files and replace
+ find "${ED}"/usr/lib* -name "*.py[co]" -exec rm {} \; || die
+ python_optimize
+}
+
+src_test() {
+ virtx cmake_src_test
+}
+
+pkg_postinst() {
+ if use grc ; then
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+ fi
+}
+
+pkg_postrm() {
+ if use grc ; then
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+ fi
+}
diff --git a/net-wireless/gnuradio/gnuradio-3.8.5.0.ebuild b/net-wireless/gnuradio/gnuradio-3.8.5.0.ebuild
index 120d4741d37c..6512288c30b9 100644
--- a/net-wireless/gnuradio/gnuradio-3.8.5.0.ebuild
+++ b/net-wireless/gnuradio/gnuradio-3.8.5.0.ebuild
@@ -2,7 +2,7 @@
# Distributed under the terms of the GNU General Public License v2
EAPI=8
-PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_COMPAT=( python3_{7,8,9,10} )
CMAKE_BUILD_TYPE="None"
inherit cmake python-single-r1 virtualx xdg-utils
diff --git a/net-wireless/gnuradio/gnuradio-9999.ebuild b/net-wireless/gnuradio/gnuradio-9999.ebuild
index c02ce48dcda1..78f7c917fedf 100644
--- a/net-wireless/gnuradio/gnuradio-9999.ebuild
+++ b/net-wireless/gnuradio/gnuradio-9999.ebuild
@@ -2,7 +2,7 @@
# Distributed under the terms of the GNU General Public License v2
EAPI=8
-PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_COMPAT=( python3_{7,8,9,10} )
CMAKE_BUILD_TYPE="None"
inherit cmake python-single-r1 virtualx xdg-utils desktop
generated by cgit v1.2.3 (git 2.25.1) at 2025-01-04 00:01:02 +0000