2 files changed, 84 insertions, 0 deletions
diff --git a/sys-apps/cpu-x/Manifest b/sys-apps/cpu-x/Manifest
index 975218be580f..c32cf07ab28f 100644
--- a/sys-apps/cpu-x/Manifest
+++ b/sys-apps/cpu-x/Manifest
@@ -1,3 +1,4 @@
 DIST cpu-x-5.0.1.tar.gz 1973785 BLAKE2B 57f46f68d116fb0aac0323fc1b877b88bf75911fae09170d04c35353885ce341b006614652d4473211e952b594deb253580d1245e661adae744c7f7d64829d35 SHA512 3ded9098c840fa62061ec6b87e1f4a602a97e428f6eaa4bf63de3d6a2e29a9a9ceea199b323546a3f163fcc8a0185815a9dd68623ce46e0b13bee59c33a671c2
+EBUILD cpu-x-5.0.1-r1.ebuild 1823 BLAKE2B b8e7318b93a8603b5d0de8978de442ebda77878f84af965e541c9e5035cb1ccf4fcd9ddd5d3de80c0a84a865b2801c62d07ed356d97011ae00f8e88b98b03381 SHA512 6bddd67ef011623b156fbf44b41a13385675bd0b27b23962390d8d84bd17dabdfcd6abecb9a2e184fca9c1826ea51b0e82458ad13f433ee44dfbd5dd83764912
 EBUILD cpu-x-5.0.1.ebuild 1803 BLAKE2B 126121cc7f3d342a83423693e823140ab53a86c53728a44e192f098b10f85611f4694afe95145de87220794ed8dc15ff2f0641afdae6fe2dba4680a6566643b4 SHA512 69c7277840d99e0400452004c831ce1c9e266637be9e4bcc417b9ca67f28e5d34fc4f5647c93a79ed3656950f9a336713ca382071ebbc1c1c3727fe866d680c7
 MISC metadata.xml 2509 BLAKE2B aeedc670e4097c94603eedbd8c2644c3e9d57441edbe9edba9fbff3695be48f352453dc0c9480975a3d9d058c38da18a5038346e6c3c34b610c7a1c639d3a2ee SHA512 6ae465a1bc12f3979caa2ed10577d4b3f969537594aa43a3ee8b806180b8b4db94908cc5db949055f3fff3c2efed562a5cdaa1fed1e17a3c177646a945729b3a
diff --git a/sys-apps/cpu-x/cpu-x-5.0.1-r1.ebuild b/sys-apps/cpu-x/cpu-x-5.0.1-r1.ebuild
new file mode 100644
index 000000000000..3f9b4fe3e739
--- /dev/null
+++ b/sys-apps/cpu-x/cpu-x-5.0.1-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="CPU-X"
+
+inherit cmake gnome2-utils xdg
+
+DESCRIPTION="A Free software that gathers information on CPU, motherboard and more"
+HOMEPAGE="https://thetumultuousunicornofdarkness.github.io/CPU-X/"
+SRC_URI="https://github.com/TheTumultuousUnicornOfDarkness/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+cpu force-libstatgrab +gpu gui +ncurses +nls opencl +pci test vulkan"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	force-libstatgrab? ( sys-libs/libstatgrab )
+	!force-libstatgrab? ( sys-process/procps:= )
+	gui? ( dev-cpp/gtkmm:3.0
+		>=x11-libs/gtk+-3.12:3 )
+	cpu? ( >=dev-libs/libcpuid-0.6.0:= )
+	gpu? ( >=media-libs/glfw-3.3
+		media-libs/libglvnd )
+	pci? ( sys-apps/pciutils )
+	ncurses? ( sys-libs/ncurses:=[tinfo] )
+	opencl? ( virtual/opencl )
+	vulkan? ( media-libs/vulkan-loader
+		>=dev-util/vulkan-headers-1.3.151 )
+"
+
+DEPEND="
+	test? (
+		sys-apps/grep[pcre]
+		sys-apps/mawk
+		sys-apps/nawk
+	)
+
+	${COMMON_DEPEND}
+"
+
+BDEPEND="
+	dev-lang/nasm
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DFORCE_LIBSTATGRAB=$(usex force-libstatgrab)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_GTK=$(usex gui)
+		-DWITH_LIBCPUID=$(usex cpu)
+		-DWITH_LIBGLFW=$(usex gpu)
+		-DWITH_LIBPCI=$(usex pci)
+		-DWITH_LIBSTATGRAB=OFF
+		-DWITH_NCURSES=$(usex ncurses)
+		-DWITH_OPENCL=$(usex opencl)
+		-DWITH_VULKAN=$(usex vulkan)
+	)
+	use gui && mycmakeargs+=( -DGSETTINGS_COMPILE=OFF )
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}