9 files changed, 514 insertions, 0 deletions
diff --git a/sys-fs/Manifest.gz b/sys-fs/Manifest.gz
index 057594ff4c6b..a47ea3354d8c 100644
--- a/sys-fs/Manifest.gz
+++ b/sys-fs/Manifest.gz
diff --git a/sys-fs/btrfs-progs/Manifest b/sys-fs/btrfs-progs/Manifest
index 693c3b1f8518..732b135cede8 100644
--- a/sys-fs/btrfs-progs/Manifest
+++ b/sys-fs/btrfs-progs/Manifest
@@ -2,10 +2,13 @@ DIST btrfs-progs-v6.10.1.tar.sign 566 BLAKE2B dc18c0048716e422475c6630c26c74e09b
 DIST btrfs-progs-v6.10.1.tar.xz 2670604 BLAKE2B 7a2631b8462bb02be0936861a42b868907bd4f4e365293f9c95744b963e769b81248ba0a290fca517d689ff9f93d8709cc37e217264b2dac1469a47349f97e8c SHA512 cd10747d1f5f9377abfdf209b517791d3eb13b417c0be65fd5c0c044b01063125b4176c178345387bb3deda7a3a379953f31d46d7834854455a5dbfbf967aa97
 DIST btrfs-progs-v6.10.tar.sign 566 BLAKE2B 493260b4854616eabce943135b4990de4a724ad00f8cba43e9d864e5c67e5896890831d17c742456d422ed15267a753c4eaf18ac30a4c7c3da0b254b01becf8b SHA512 62d9721702eec6eec2c0e51eee4624324c4604d3bc76016cde1ade0572c22b46ede71fcb3d9e4ca14ea0196e84116ce4ef9222b399f8bbdf8e5259c18f3a82e8
 DIST btrfs-progs-v6.10.tar.xz 2669760 BLAKE2B 24b66cc6f7118da817e9abca69e8de9a9496de1ec4eb6800fa8f6b13b677e37a553d90562a38618a63b68b71457ab10ff72541dd3e0c169a1fe05509fd62402c SHA512 aa5af67f3816dcd1a128b69bc6f4bd83423c6c2289e3dd3abe2a07bdccb6b7d5e49426a5a0ece643709c23cdcb0908ca52b271f058fee3a3d810cdfcb9c36639
+DIST btrfs-progs-v6.11.tar.sign 566 BLAKE2B 15db44b5db3265eff9d5195ad4842cef5d001c46e1170f219784fca8d049756dccbc1bd95f20fc343fbdf1078c610a166921c043828cdc5f64c0f465323ca0e4 SHA512 a2fdd9100ad3ddd30cb923a72a2b4f70634277e5fbbf0d2cf912c00dc876dad6cd2c24e624f41dbb83aabdda4e3c08aea9c0ae39084bb3481700491df3d47fd5
+DIST btrfs-progs-v6.11.tar.xz 2695752 BLAKE2B 6dec219394e39a821f29858eddf1d501537d3cebad2dc83f0cea6d88d0b0e94c4fe2e660a48a27942ccfb6f3ac0630d5930f44e083168de65b60af36e895b2af SHA512 fad3c7e908e2020a3983f9737a7e87367023e2ad35aea14197e2bfa71c1e0435bc3da3f7e6ef463de47c033323163f8b1b7933013042c6fcea673d0f4723ade1
 DIST btrfs-progs-v6.9.2.tar.sign 566 BLAKE2B 4cd95496d355444c7d3e582a7e6c05fbb55683008b1585a26f38aef6cceb1afd5e80c9611518d6bd92dc1167798d4012c4bcab2f9bda752c459d94cfa6f3c477 SHA512 3fb04e1894e231abde388a39d2f0c90f43c1a1494622c2158fab9b94bb340e064404bcf96e24d913c60aaf5e06ade42fbb91a479949109b329682bb089f66bf2
 DIST btrfs-progs-v6.9.2.tar.xz 2661684 BLAKE2B 38ab189ac8271ba8d68b74e82569159c671cca1cb946f56ccab28b6b206cb6ee5b330d83afc3536b7e0d7399da3fb01e368809c1ef4a64b843ea88796ebd28bd SHA512 1df9d5456d07a035c38c17795996a4fc621eeaa244ef54383d4387205826d2a6e971910e55031d20bb1baf23193efa7439e110312ffd8471f07aaf8c0baca20a
 EBUILD btrfs-progs-6.10.1.ebuild 4299 BLAKE2B 106d47c047766e60a616d1b3fba6caaa0b218672bdb5bc75bd2ec56123e6404d9d050b6cd54980c5d9e61c3e45c3dccca018182b0297568c1595fb1ad206372b SHA512 3b4fde4d50c374b5ef8815cfd1ac46a563755472f3b219bc67a0a840cfdd0bde311392309c5606565a742a18d80884c6c7022d1fccd7656bfe87b160d3b1621e
 EBUILD btrfs-progs-6.10.ebuild 4299 BLAKE2B 106d47c047766e60a616d1b3fba6caaa0b218672bdb5bc75bd2ec56123e6404d9d050b6cd54980c5d9e61c3e45c3dccca018182b0297568c1595fb1ad206372b SHA512 3b4fde4d50c374b5ef8815cfd1ac46a563755472f3b219bc67a0a840cfdd0bde311392309c5606565a742a18d80884c6c7022d1fccd7656bfe87b160d3b1621e
+EBUILD btrfs-progs-6.11.ebuild 4299 BLAKE2B 106d47c047766e60a616d1b3fba6caaa0b218672bdb5bc75bd2ec56123e6404d9d050b6cd54980c5d9e61c3e45c3dccca018182b0297568c1595fb1ad206372b SHA512 3b4fde4d50c374b5ef8815cfd1ac46a563755472f3b219bc67a0a840cfdd0bde311392309c5606565a742a18d80884c6c7022d1fccd7656bfe87b160d3b1621e
 EBUILD btrfs-progs-6.9.2.ebuild 4293 BLAKE2B 4483049cf94bb6e5bcea6f1c660cc4aa98b1f3fd8a944ca810eefc1ea385adb4bb78035c7a40845e742ca647a6587208d60a58b19e180137b6864b08cddc8eb0 SHA512 a9594b762949e6e1578abc610a675922f59e38dbf41bc5c52b7b8aa57894905a93cbe6256de02148fd84209a95166d8690c8c2adb50ecae69d4bcca161ae7ff3
 EBUILD btrfs-progs-9999.ebuild 4299 BLAKE2B 106d47c047766e60a616d1b3fba6caaa0b218672bdb5bc75bd2ec56123e6404d9d050b6cd54980c5d9e61c3e45c3dccca018182b0297568c1595fb1ad206372b SHA512 3b4fde4d50c374b5ef8815cfd1ac46a563755472f3b219bc67a0a840cfdd0bde311392309c5606565a742a18d80884c6c7022d1fccd7656bfe87b160d3b1621e
 MISC metadata.xml 744 BLAKE2B 6c23644af7f970c93a3c3bd1fd1bf82e5290832afac427bec1da93bfd2694799f779bdce3f51742a171218d6e29460a4986452426ab2239ad8ab6627dc45b81d SHA512 06df1d728d39b92384bdd026d0339a494ce1fe3966376a413a80f8dd85bedd5e5d843db9cdd60a9ab29857b79d5a24de24de2330aab70916a0e57acfc01a2e5d
diff --git a/sys-fs/btrfs-progs/btrfs-progs-6.11.ebuild b/sys-fs/btrfs-progs/btrfs-progs-6.11.ebuild
new file mode 100644
index 000000000000..3a777a5c58ba
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-6.11.ebuild
@@ -0,0 +1,188 @@
+# Copyright 2008-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Please bump with dev-python/btrfsutil
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit bash-completion-r1 python-any-r1 udev
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git"
+	EGIT_BRANCH="devel"
+	WANT_LIBTOOL="none"
+	inherit autotools git-r3
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+	inherit verify-sig
+
+	MY_PV="v${PV/_/-}"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="
+		https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${PN}/${MY_P}.tar.xz
+		verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${PN}/${MY_P}.tar.sign )
+	"
+	S="${WORKDIR}"/${PN}-${MY_PV}
+
+	if [[ ${PV} != *_rc* ]] ; then
+		KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+	fi
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.readthedocs.io/en/latest/"
+
+LICENSE="GPL-2"
+SLOT="0/0" # libbtrfs soname
+IUSE="+convert +man experimental reiserfs static static-libs udev +zstd"
+# Could support it with just !systemd => eudev, see mdadm, but let's
+# see if someone asks for it first.
+REQUIRED_USE="static? ( !udev )"
+
+# Tries to mount repaired filesystems
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/lzo:2=
+	sys-apps/util-linux:=[static-libs(+)?]
+	sys-libs/zlib:=
+	convert? (
+		sys-fs/e2fsprogs:=
+		reiserfs? (
+			>=sys-fs/reiserfsprogs-3.6.27
+		)
+	)
+	udev? ( virtual/libudev:= )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="
+	${RDEPEND}
+	>=sys-kernel/linux-headers-5.10
+	convert? ( sys-apps/acl )
+	static? (
+		dev-libs/lzo:2[static-libs(+)]
+		sys-apps/util-linux:0[static-libs(+)]
+		sys-libs/zlib:0[static-libs(+)]
+		convert? (
+			sys-fs/e2fsprogs[static-libs(+)]
+			reiserfs? (
+				>=sys-fs/reiserfsprogs-3.6.27[static-libs(+)]
+			)
+		)
+		zstd? ( app-arch/zstd[static-libs(+)] )
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+	man? (
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]')
+	)
+"
+
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+	python_has_version "dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]"
+}
+
+if [[ ${PV} == 9999 ]]; then
+	BDEPEND+=" sys-devel/gnuconfig"
+else
+	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-dsterba )"
+fi
+
+pkg_setup() {
+	: # Prevent python-any-r1_python_setup
+}
+
+if [[ ${PV} != 9999 ]]; then
+	src_unpack() {
+		# Upstream sign the decompressed .tar
+		if use verify-sig; then
+			einfo "Unpacking ${MY_P}.tar.xz ..."
+			verify-sig_verify_detached - "${DISTDIR}"/${MY_P}.tar.sign \
+				< <(xz -cd "${DISTDIR}"/${MY_P}.tar.xz | tee >(tar -x))
+			assert "Unpack failed"
+		else
+			default
+		fi
+	}
+fi
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999 ]]; then
+		local AT_M4DIR=config
+		eautoreconf
+
+		local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
+		[[ -e ${automakedir} ]] || die "Could not locate automake directory"
+
+		ln -s "${automakedir}"/install-sh config/install-sh || die
+		ln -s "${BROOT}"/usr/share/gnuconfig/config.guess config/config.guess || die
+		ln -s "${BROOT}"/usr/share/gnuconfig/config.sub config/config.sub || die
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/sbin
+
+		--enable-lzo
+		$(use_enable experimental)
+		--disable-python
+		$(use_enable convert)
+		$(use_enable man documentation)
+		$(use_enable elibc_glibc backtrace)
+		$(use_enable static-libs static)
+		$(use_enable udev libudev)
+		$(use_enable zstd)
+
+		# Could support libgcrypt, libsodium, libkcapi, openssl, botan
+		--with-crypto=builtin
+		--with-convert=ext2$(usev reiserfs ',reiserfs')
+	)
+
+	export EXTRA_PYTHON_CFLAGS="${CFLAGS}"
+	export EXTRA_PYTHON_LDFLAGS="${LDFLAGS}"
+
+	if use man; then
+		python_setup
+	fi
+
+	# bash as a temporary workaround for https://github.com/kdave/btrfs-progs/pull/721
+	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake V=1 all $(usev static)
+}
+
+src_test() {
+	emake V=1 -j1 -C tests test
+}
+
+src_install() {
+	local makeargs=(
+		$(usev static install-static)
+	)
+
+	emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+
+	if use experimental; then
+		exeinto /sbin
+		doexe btrfs-corrupt-block
+	fi
+
+	newbashcomp btrfs-completion btrfs
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}
diff --git a/sys-fs/cryptsetup/Manifest b/sys-fs/cryptsetup/Manifest
index 4bc5de58254e..824b1a3399a6 100644
--- a/sys-fs/cryptsetup/Manifest
+++ b/sys-fs/cryptsetup/Manifest
@@ -4,8 +4,10 @@ DIST cryptsetup-2.6.1.tar.xz 11402380 BLAKE2B efd7a64d89d863876de68ff3e89d8c94ad
 DIST cryptsetup-2.7.2.tar.xz 11637316 BLAKE2B 466d7818cf8b6e23f802291ccad205d09f128572c21a85d6ca8e518d2198e49c9d95066c58560ffcb7df5a483aa27592b0e931db1e4daeabd102db9a5543da20 SHA512 06f42f443b91d1f8af8af999dfedd4051ecb12ba5ef291cf2b44b6a5676e2c5cf1e686e19687f5cb6b1fd524dfc1a208cd25a3798367a480d80eac954aa8d6d4
 DIST cryptsetup-2.7.3.tar.xz 11689300 BLAKE2B 6de2c5eb4a0e1108eedb9c81c69ef70696b166ee592641927a0f8e11e566d644e0f7db3436b0446d5df33b3fab55af9592b869bb54d5fa94e67c5003404bc9b8 SHA512 08cff21873aeb7cc5b2561abf5d33cdf0fa814eeaabf6a01f858461726ea9faeef651357da33bce7b347ca2f12d6d02bccdb279893f3749cb781ce1fe5c1571c
 DIST cryptsetup-2.7.4.tar.xz 11695292 BLAKE2B a7e9397342482e83a21177699aedbd7a59c2f841512cdf9c8fdcec34d8d448056b2aca89cceae55e8d01654cf5a6ea260ec44879fc7b7fd15fe613c0ad95bc6a SHA512 3cc601ab1c4d5fd282f990529d7cb95f59c8aa9beb0ebd11de7ebf78cb35c352bcb8c945a2033cb6c53540b37156fdf2824070d431c752f9f7b029e4ec930c21
+DIST cryptsetup-2.7.5.tar.xz 11697476 BLAKE2B 7df7b53f74cbf1a009d2804b8d85c9fea27be994bb4171e1ded70e3666635fd8f265819321bee0d1977548626029ebf75b87225a68cb38b3b79910f991c813dd SHA512 13eca93cdb00a143d2ca60b6f66ede5adc4072ca0c4bfebd8454a3541e69d269fcdb4afc97ad799e87a999b2bd46c1f31fa924a3d616d72a3337970b1e718d55
 EBUILD cryptsetup-2.6.1.ebuild 4146 BLAKE2B 23460c085e6bbde61a42de529440591a74a5f16167d5889037fea97cc589764c2af1b93953e9458cde22fb93a5d347fa8ca80b8d823f34cd871e89c02031422c SHA512 5fc69b8da5b053d95a8fe55cb67d999d022e7e8012dd44dc5bc2ea235eb4b2ebc37fa2e4e2d2f532ba6f3076c040538c79409803c81cfb23acd0aa48ceb795cb
 EBUILD cryptsetup-2.7.2.ebuild 4161 BLAKE2B c2cc271963d87c13487074d0d3ff1abde76d0bc3f3a65d13ad9b5e8250bae8d6c35d8012cc266761ef58bae13c40e047d6dd551a597d80828e5aa1407774a0c3 SHA512 0b041e8967e87ff383f3c044c325c2f14d7ebd43f9d434fb01b5be2dd52b20c607e37939d56c392eb55b521333d5cba636eb8c3dac4e00e5b9920a7c7793931f
 EBUILD cryptsetup-2.7.3.ebuild 4160 BLAKE2B f6959b6ba10257943c2885e3f9d1d00dff3e3ed8f3aa320bd1038572f5e9832f09c74c5967f0c45f36704c2c7128f7020c063f2f0fb6ed91f3823d304a253cd2 SHA512 eb0404b40636ffa1271628057de2c06a6bd1b005f929bc6a3e01172618d598aff6e515c804963a0b193515f21d3127ad03faa1e51b3263bf47f7d892b06cd56b
 EBUILD cryptsetup-2.7.4.ebuild 4160 BLAKE2B f6959b6ba10257943c2885e3f9d1d00dff3e3ed8f3aa320bd1038572f5e9832f09c74c5967f0c45f36704c2c7128f7020c063f2f0fb6ed91f3823d304a253cd2 SHA512 eb0404b40636ffa1271628057de2c06a6bd1b005f929bc6a3e01172618d598aff6e515c804963a0b193515f21d3127ad03faa1e51b3263bf47f7d892b06cd56b
+EBUILD cryptsetup-2.7.5.ebuild 4154 BLAKE2B b52e02a63b4f7b3674d262e4cdf7f48a1f2636897278ee4ab49747154d5700471405afb4fa93e0c5014cdc0ca0185c4899afc5926073e5bef2dc3639607bdaf1 SHA512 685ee4e03b42cd5e951687402f42c9de307dbf4071e69f2a51e65e7b5c489216dc6bcb6e728c59b81f5b4b423f6c132919e71c80172b543fc2c798cc9265dde4
 MISC metadata.xml 1146 BLAKE2B e349364ad14e957f35c1fbe1fdeff46cd6a48535b45363922e071adde6342a60fb30c25e3579b908b6e0c0df80984ef26b319e70d438731d665a57fcc2aa8b81 SHA512 6cec96962ee5da4b2923e1fbce5232d014e25e01ccfdd3ca55d48e23cb8581af592ed9b061f8e24b6408e8c339b9ebfa5e2754c1ead417e41d832f777d4ccb45
diff --git a/sys-fs/cryptsetup/cryptsetup-2.7.5.ebuild b/sys-fs/cryptsetup/cryptsetup-2.7.5.ebuild
new file mode 100644
index 000000000000..d09dd78f2b65
--- /dev/null
+++ b/sys-fs/cryptsetup/cryptsetup-2.7.5.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# TODO: meson
+inherit linux-info tmpfiles
+
+DESCRIPTION="Tool to setup encrypted devices with dm-crypt"
+HOMEPAGE="https://gitlab.com/cryptsetup/cryptsetup"
+SRC_URI="https://www.kernel.org/pub/linux/utils/${PN}/v$(ver_cut 1-2)/${P/_/-}.tar.xz"
+S="${WORKDIR}"/${P/_/-}
+
+LICENSE="GPL-2+"
+SLOT="0/12" # libcryptsetup.so version
+if [[ ${PV} != *_rc* ]] ; then
+	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+fi
+
+CRYPTO_BACKENDS="gcrypt kernel nettle +openssl"
+# we don't support nss since it doesn't allow cryptsetup to be built statically
+# and it's missing ripemd160 support so it can't provide full backward compatibility
+IUSE="${CRYPTO_BACKENDS} +argon2 fips nls pwquality ssh static static-libs test +udev urandom"
+RESTRICT="!test? ( test )"
+# bug #496612, bug #832711, bug #843863
+REQUIRED_USE="
+	^^ ( ${CRYPTO_BACKENDS//+/} )
+	static? ( !ssh !udev !fips )
+	fips? ( !kernel !nettle )
+"
+
+LIB_DEPEND="
+	dev-libs/json-c:=[static-libs(+)]
+	dev-libs/popt[static-libs(+)]
+	>=sys-apps/util-linux-2.31-r1[static-libs(+)]
+	argon2? ( app-crypt/argon2:=[static-libs(+)] )
+	gcrypt? (
+		dev-libs/libgcrypt:0=[static-libs(+)]
+		dev-libs/libgpg-error[static-libs(+)]
+	)
+	nettle? ( >=dev-libs/nettle-2.4[static-libs(+)] )
+	openssl? ( dev-libs/openssl:0=[static-libs(+)] )
+	pwquality? ( dev-libs/libpwquality[static-libs(+)] )
+	ssh? ( net-libs/libssh[static-libs(+)] )
+	sys-fs/lvm2[static-libs(+)]
+"
+# We have to always depend on ${LIB_DEPEND} rather than put behind
+# !static? () because we provide a shared library which links against
+# these other packages. bug #414665
+RDEPEND="
+	static-libs? ( ${LIB_DEPEND} )
+	${LIB_DEPEND//\[static-libs\([+-]\)\]}
+	udev? ( virtual/libudev:= )
+"
+DEPEND="
+	${RDEPEND}
+	static? ( ${LIB_DEPEND} )
+"
+# vim-core needed for xxd in tests
+BDEPEND="
+	virtual/pkgconfig
+	test? ( app-editors/vim-core )
+"
+
+pkg_setup() {
+	local CONFIG_CHECK="~DM_CRYPT ~CRYPTO ~CRYPTO_CBC ~CRYPTO_SHA256"
+	local WARNING_DM_CRYPT="CONFIG_DM_CRYPT:\tis not set (required for cryptsetup)\n"
+	local WARNING_CRYPTO_SHA256="CONFIG_CRYPTO_SHA256:\tis not set (required for cryptsetup)\n"
+	local WARNING_CRYPTO_CBC="CONFIG_CRYPTO_CBC:\tis not set (required for kernel 2.6.19)\n"
+	local WARNING_CRYPTO="CONFIG_CRYPTO:\tis not set (required for cryptsetup)\n"
+	check_extra_config
+}
+
+src_prepare() {
+	default
+
+	sed -i '/^LOOPDEV=/s:$: || exit 0:' tests/{compat,mode}-test || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-internal-argon2
+		--disable-asciidoc
+		--enable-shared
+		--sbindir="${EPREFIX}"/sbin
+		# for later use
+		--with-default-luks-format=LUKS2
+		--with-tmpfilesdir="${EPREFIX}/usr/lib/tmpfiles.d"
+		--with-crypto_backend=$(for x in ${CRYPTO_BACKENDS//+/} ; do usev ${x} ; done)
+		$(use_enable argon2 libargon2)
+		$(use_enable nls)
+		$(use_enable pwquality)
+		$(use_enable !static external-tokens)
+		$(use_enable static static-cryptsetup)
+		$(use_enable static-libs static)
+		$(use_enable udev)
+		$(use_enable !urandom dev-random)
+		$(use_enable ssh ssh-token)
+		$(usev !argon2 '--with-luks2-pbkdf=pbkdf2')
+		$(use_enable fips)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	if [[ ! -e /dev/mapper/control ]] ; then
+		ewarn "No /dev/mapper/control found -- skipping tests"
+		return 0
+	fi
+
+	local p
+	for p in /dev/mapper /dev/loop* ; do
+		addwrite ${p}
+	done
+
+	default
+}
+
+src_install() {
+	default
+
+	if use static ; then
+		mv "${ED}"/sbin/cryptsetup{.static,} || die
+		mv "${ED}"/sbin/veritysetup{.static,} || die
+		mv "${ED}"/sbin/integritysetup{.static,} || die
+
+		if use ssh ; then
+			mv "${ED}"/sbin/cryptsetup-ssh{.static,} || die
+		fi
+	fi
+
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	dodoc docs/v*ReleaseNotes
+
+	newconfd "${FILESDIR}"/2.4.3-dmcrypt.confd dmcrypt
+	newinitd "${FILESDIR}"/2.4.3-dmcrypt.rc dmcrypt
+}
+
+pkg_postinst() {
+	tmpfiles_process cryptsetup.conf
+
+	if use kernel ; then
+		ewarn "Note that kernel backend is very slow for this type of operation"
+		ewarn "and is provided mainly for embedded systems wanting to avoid"
+		ewarn "userspace crypto libraries."
+	fi
+}
diff --git a/sys-fs/vhba/Manifest b/sys-fs/vhba/Manifest
index 1f458305338b..d3a113bbbef4 100644
--- a/sys-fs/vhba/Manifest
+++ b/sys-fs/vhba/Manifest
@@ -1,3 +1,5 @@
 DIST vhba-module-20240202.tar.xz 16168 BLAKE2B 7974f60b73c634528afdd44e94c6da34bdc481d874f19845efc0464435a7e560494dd703b0fb1df34c96fce5f1afb300a1e6e2b3b9730e91c956816905eb2f44 SHA512 fdb9b79feb870bb22ed2182216103c8b87d1b5a471d02def24bdf5782cc2bee2333f1d78e1428b042c3df5a33ff8e07b1d61cbe11414a27db18034f3fbbe2612
+DIST vhba-module-20240917.tar.xz 16204 BLAKE2B 1e6dd176d40e86363eacddf3f97231b07b7428178b6e1792cf3abd15e42f2350db66557b3499c204c47678b4967955670a8839f8b50549614bd6a8ba204b9bb7 SHA512 aa94f88e501f11fe1de9dc9eb315f720947fafa23a12789c8b674b1f7d578cc351c2c1524ea1165b893cb50c7188d016da548006e7a1795c99eeacc92e1ab0de
 EBUILD vhba-20240202.ebuild 1086 BLAKE2B d473e5deb1503059962c9ea2e806805577bbb3aae95996b19a0bf3350c3d4b8c07ff105558762eba2cfcdd7c38ddd33c447ef98060cbb10ae9d962ae1d73a681 SHA512 67133950d564026373ad288bd5e8bf841e538b40320ba5c9da08d36a3db9bd5dd72a575242bebc53c8feb952ef70e598ee08388aca29414a0aafe00d9d6a9fcf
+EBUILD vhba-20240917.ebuild 1088 BLAKE2B 41caec15924e0cee276f78183f3912de23099695dec2c72034efeeaa2dbec7d63cfa54edcb20d43b1c638986e1b2ade6c7028970967fb5743149259698e3868e SHA512 213f02109b6de84b55bd8c7325a35a90bf7ef35c72abd18b71cef628898fcb4bf591bfc57a2e52e6fe03dadbbf882d5275a7d780b8c27893edc5a22fbd6dbc3f
 MISC metadata.xml 333 BLAKE2B 99feb77e860cccd95f60688c7c2104267b6abb6188a8f24e50728b39487892ef29c58e5ddfb7a56578d27c34e9d4bb16371298449d2a3de5e6a79a6a5712e37c SHA512 2a387604d78412e81477271c793d46b197609d4d9037aa55d0146cfbbc9eae01633a7a9ac6908f923174ecfedf7336792147dc6e7c5b13db057855282e45e129
diff --git a/sys-fs/vhba/vhba-20240917.ebuild b/sys-fs/vhba/vhba-20240917.ebuild
new file mode 100644
index 000000000000..4c97a5404e45
--- /dev/null
+++ b/sys-fs/vhba/vhba-20240917.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-mod-r1 udev
+
+MY_P=vhba-module-${PV}
+DESCRIPTION="Virtual (SCSI) Host Bus Adapter kernel module for the CDEmu suite"
+HOMEPAGE="https://cdemu.sourceforge.io/"
+SRC_URI="https://download.sourceforge.net/cdemu/vhba-module/${MY_P}.tar.xz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	virtual/udev
+"
+DEPEND="
+	${RDEPEND}
+"
+
+CONFIG_CHECK="~BLK_DEV_SR ~CHR_DEV_SG"
+
+src_compile() {
+	local modlist=( vhba )
+	local modargs=( KDIR="${KV_OUT_DIR}" )
+
+	linux-mod-r1_src_compile
+}
+
+src_prepare() {
+	default
+	# Avoid -Werror problems
+	sed -i -e '/ccflags/s/-Werror/-Wall/' Makefile || die "sed failed"
+}
+
+src_install() {
+	linux-mod-r1_src_install
+
+	einfo "Generating udev rules ..."
+	udev_newrules - 69-vhba.rules <<-EOF
+		# do not edit this file, it will be overwritten on update
+		#
+		KERNEL=="vhba_ctl", SUBSYSTEM=="misc", TAG+="uaccess"
+	EOF
+}
+
+pkg_postinst() {
+	linux-mod-r1_pkg_postinst
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}
diff --git a/sys-fs/xfsprogs/Manifest b/sys-fs/xfsprogs/Manifest
index d1be1b993868..7fbd6e0b1d09 100644
--- a/sys-fs/xfsprogs/Manifest
+++ b/sys-fs/xfsprogs/Manifest
@@ -2,9 +2,11 @@ AUX xfsprogs-5.18.0-docdir.patch 278 BLAKE2B 5277fff17f26b4da946535a430878bfe1e9
 AUX xfsprogs-5.3.0-libdir.patch 1137 BLAKE2B 7e455b8b82c553a819155fb4c1fee3d5c31bef0fa4c7ab0bf4ad4558a9a5b0b2f408138558c3601deb3ba85d465ab2dae5248bc20a4ba83f08cf733b27a796a1 SHA512 eaec31b6dab500c2e9c4fe7d5d82e60a40f3073cff99af0ae2aa817f6e4541f6a3de0a48f9151a274c6dd97e99ca26192b95b920aea1c5227d75232b808c98fa
 AUX xfsprogs-6.10.0-c++-void.patch 1651 BLAKE2B dafb054348f0b2362976d74c55821a2440ac98a80197af532facb4b65bb8947fa77ec52795b90a58196b77778078b2bf887b7b9d05d420c26193c8e63b98fe4d SHA512 09df6b846621c0bea65628e38c286935eb1fc2d7d1a3a08877c3121cc012df9345a53dc12e4ec43785500d890767d02e5e9ba144c2bfb67d2bf5812ba2987bcf
 DIST xfsprogs-6.10.0.tar.xz 1449872 BLAKE2B dc02fb14cd07e20d618070358700003a0990125ce3d8b15fa0248c6d494a89bbfb51c267583fc863edeee0d84069c7016f7992e750faa357618cd0d7f5748d2e SHA512 ec80eedfd3471c836e99eb8507c0de2895f261d36316145b02f2effbcc1bb5a52eae3ad2148d45bc49f1a30e0267aa4e3f3176a5e01ec84b2da24b3fb430ffce
+DIST xfsprogs-6.10.1.tar.xz 1449932 BLAKE2B e9ed15b2d4a9026e0079adfb38578721e13498290a5d9590edae1fd41c9ee0338f9b823568677394952709d82bdc8ade36905a2266ffe64803901adbadfa5643 SHA512 b9fd7b7eaf038772ee4a9602bf38f714db7077731ec8904e0959d28b0103d443be8ae67720869012b90737c1ff440fbce44b3b23b662939c9a90c6d3be3fab08
 DIST xfsprogs-6.8.0.tar.xz 1367196 BLAKE2B 8c296698da1170bb7ff369c2bf5f156e812ddf43ee817369029ad951d6c1e18c20d093db385b9a523f6cb7ba3e01f8924eb3540b71efa4bec8bf3defe2418562 SHA512 f5b5c6d8da70cc0f3361b3420982aabfabb0bc54b9eb60b93a9aaeedb33a9ecede4061d5c1300b96d7aba7d44a4207672c4a33e115bf0f5c711a151f3fc65e0d
 DIST xfsprogs-6.9.0.tar.xz 1383116 BLAKE2B d952603716cc4022a935c426630b0b7838573476a730c6832f36ef0274a640e64667d3e3a2dd9fd2c5f2c12cdb348fd93abfef5c49e5c5fe2d5a83945dfc7894 SHA512 c597453759c400690810971f0b2daf0e4e22c74270b0f9800e2235da5e5c1383b59bc1176c5bba0023f74b623020fb51c62f0e98a74885cf3a8336e0b81c9023
 EBUILD xfsprogs-6.10.0-r2.ebuild 2859 BLAKE2B 527366c51df7a215fce8b0e7d2d366e6d587dc37b86b379488aaa31e668eb495af757af8baf6d436a2ef760affd6fe7b2d47afe8a6088f5b6d130c9cbc098cd0 SHA512 9b8d76a07e4d5ffb26453b58f18f8739d95d4e9c3f6ff89d9e7222fbd7aa261570c63b7f1af49a5e001bc337c7e90ec2fca019ef429eae0bd617f82d25d8040c
+EBUILD xfsprogs-6.10.1.ebuild 2803 BLAKE2B 4fbe8eeb2394c091fe1325cc7d5c44c9e7133c51bce00cfd354c002edefc54d5f29bad76e037e29b2340aa4ce8443ba27828bdb8dbf7d4000968bc7d6108e001 SHA512 ce765292785775fff276ba2f5f113e9e7398b2208a83d48c31ddd925921fefcc4712bd0d1acef6b00b7b8dcf9207c3292d992e06b68d87ca8779019728da2e82
 EBUILD xfsprogs-6.8.0.ebuild 2589 BLAKE2B 724a51c203639b6ef3a1e60e04705ca46084acf58c59bed0ae8615fdfe60b8ba473092eb33b72b1276ca86b81a9dcdfcbda613a4c0643b061e1877ea139600d8 SHA512 9c2a1aadc1a5122e48768cbe60d6179c1e172960a92218767fcdf03adcf5a64b694798591c620e5045d131da61058a8651333607abe6ae237b607bddf8d1a5e7
 EBUILD xfsprogs-6.9.0.ebuild 2597 BLAKE2B 38ba299dc0db1edac052fa0336a4723f395e0c7a1372c66269f0c012a2ccc17e11c929f050d1dab935bb976ff5702cfc4f9399893aa322a347ad73fa2651911f SHA512 29071b95a57a12e68fdcfb0641d5fb0a357aff1b77aebe607f777e6ded28d1472764f6bcb01987dcd3296cef20c50bce820cc1f166255650adfae6ebe834e9a2
 MISC metadata.xml 339 BLAKE2B b7d67fc8bcf854e7a2453c23e5d5d8c193525ccd16a643e80415a103d2d22c892458ea6ada32653d04b3d471c780f07b2b0537a317d9e64468130e065c6f5ab1 SHA512 445b4f6d853a272cc6bf8fde42745adf226512fa310f9af4bbabad4cfa5a6888b2c2215dfc0896c07b800820b69417c6d408bb21ed17a5224b5c9e3412c5f62d
diff --git a/sys-fs/xfsprogs/xfsprogs-6.10.1.ebuild b/sys-fs/xfsprogs/xfsprogs-6.10.1.ebuild
new file mode 100644
index 000000000000..30de84a18b56
--- /dev/null
+++ b/sys-fs/xfsprogs/xfsprogs-6.10.1.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic systemd udev
+
+DESCRIPTION="XFS filesystem utilities"
+HOMEPAGE="https://xfs.wiki.kernel.org/ https://git.kernel.org/pub/scm/fs/xfs/xfsprogs-dev.git/"
+SRC_URI="https://www.kernel.org/pub/linux/utils/fs/xfs/${PN}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="icu libedit nls selinux static-libs"
+
+RDEPEND="
+	dev-libs/inih
+	dev-libs/userspace-rcu:=
+	>=sys-apps/util-linux-2.17.2
+	icu? ( dev-libs/icu:= )
+	libedit? ( dev-libs/libedit )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+RDEPEND+=" selinux? ( sec-policy/selinux-xfs )"
+
+src_prepare() {
+	default
+
+	# Fix doc dir
+	sed -i \
+		-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
+		include/builddefs.in || die
+
+	# Don't install compressed docs
+	sed 's@\(CHANGES\)\.gz[[:space:]]@\1 @' -i doc/Makefile || die
+}
+
+src_configure() {
+	# include/builddefs.in will add FCFLAGS to CFLAGS which will
+	# unnecessarily clutter CFLAGS (and fortran isn't used)
+	unset FCFLAGS
+
+	# If set in user env, this breaks configure
+	unset PLATFORM
+
+	export DEBUG=-DNDEBUG
+
+	# Package is honoring CFLAGS; No need to use OPTIMIZER anymore.
+	# However, we have to provide an empty value to avoid default
+	# flags.
+	export OPTIMIZER=" "
+
+	# Avoid automagic on libdevmapper (bug #709694)
+	export ac_cv_search_dm_task_create=no
+
+	# bug 903611
+	use elibc_musl && append-flags -D_LARGEFILE64_SOURCE
+
+	# Build fails with -O3 (bug #712698)
+	replace-flags -O3 -O2
+
+	# Upstream does NOT support --disable-static anymore,
+	# https://www.spinics.net/lists/linux-xfs/msg30185.html
+	# https://www.spinics.net/lists/linux-xfs/msg30272.html
+	local myconf=(
+		--enable-static
+		# Doesn't do anything beyond adding -flto (bug #930947).
+		--disable-lto
+		# The default value causes double 'lib'
+		--localstatedir="${EPREFIX}/var"
+		--with-crond-dir="${EPREFIX}/etc/cron.d"
+		--with-systemd-unit-dir="$(systemd_get_systemunitdir)"
+		--with-udev-rule-dir="$(get_udevdir)/rules.d"
+		$(use_enable icu libicu)
+		$(use_enable nls gettext)
+		$(use_enable libedit editline)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	emake V=1
+}
+
+src_install() {
+	# XXX: There's a missing dep in the install-dev target, so split it
+	emake DIST_ROOT="${ED}" HAVE_ZIPPED_MANPAGES=false install
+	emake DIST_ROOT="${ED}" HAVE_ZIPPED_MANPAGES=false install-dev
+
+	# Not actually used but --localstatedir causes this empty dir
+	# to be installed.
+	rmdir "${ED}"/var/lib/xfsprogs "${ED}"/var/lib || die
+
+	if ! use static-libs; then
+		rm "${ED}/usr/$(get_libdir)/libhandle.a" || die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postrm() {
+	udev_reload
+}
+
+pkg_postinst() {
+	udev_reload
+}