1 files changed, 57 insertions, 0 deletions
diff --git a/sys-process/btop/btop-1.2.13.ebuild b/sys-process/btop/btop-1.2.13.ebuild
new file mode 100644
index 000000000000..77749296de4f
--- /dev/null
+++ b/sys-process/btop/btop-1.2.13.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs xdg-utils
+
+DESCRIPTION="A monitor of resources"
+HOMEPAGE="https://github.com/aristocratos/btop"
+SRC_URI="https://github.com/aristocratos/btop/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	>=sys-devel/gcc-8
+"
+
+pkg_setup() {
+	if [[ "${MERGE_TYPE}" != "binary" ]]; then
+		if ! tc-is-gcc ; then
+			# https://bugs.gentoo.org/839318
+			die "$(tc-getCXX) is not a supported compiler. Please use sys-devel/gcc instead."
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+	# btop installs README.md to /usr/share/btop by default
+	sed -i '/^.*cp -p README.md.*$/d' Makefile || die
+}
+
+src_compile() {
+	# Disable btop optimization flags, since we have our flags in CXXFLAGS
+	emake VERBOSE=true OPTFLAGS="" CXX="$(tc-getCXX)"
+}
+
+src_install() {
+	emake \
+		PREFIX="${EPREFIX}/usr" \
+		DESTDIR="${D}" \
+		install
+
+	dodoc README.md CHANGELOG.md
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}