4 files changed, 52 insertions, 72 deletions
diff --git a/x11-misc/menulibre/Manifest b/x11-misc/menulibre/Manifest
index 4c5d9d64b39c..70ef75421b3e 100644
--- a/x11-misc/menulibre/Manifest
+++ b/x11-misc/menulibre/Manifest
@@ -1,3 +1,3 @@
-DIST menulibre-2.2.1.tar.gz 453217 BLAKE2B 86b3d2d8b20bfc7dcfcba380f656ec1e99f1d5dbc3779eadb9e7cc3a2b8c96afc0c2efe72802d0c93833f6c705c67d05a4ba6cc6cf9b95e0c9b9850ae4424fee SHA512 cf1425d604af26b7bde92106aa758a1f7dcc66ad1fbcdcd4c23db90bc7b6de5fe1160b917035f1d949daa1af8ba6b1145d7376ae637c8937a25cb108bf8cd15f
-EBUILD menulibre-2.2.1-r2.ebuild 1742 BLAKE2B d25bf7116c57ba82b6e0c098d7cb75bb9af830d593e58eb2f2fbb12543c707c0031a77435e5b4e6573fac0e9f1a7db92fcacd44067a94575c79657cd06cda052 SHA512 040ee792748927b61600afc471204a46b87b9e97c618e48934908266d7bd59636cc4a6201ee7a38dac3f12d809232de6029ee296a93545f4d770bfdfda2c1730
-MISC metadata.xml 245 BLAKE2B f53d462a766351a01a088771a316e1c8cc2feda1c84c685f63db726e29d3d273cd2875094a09668e8dd0ec670aa09c78158210db650d182b6fbf9faf8bb3c303 SHA512 8f0d7807f84fcb60bf43c9a2c8814b9e5d0648555bd2c8c5dde907e8e815507c2501838ef7ecfd5052ac3b2fcff5374852daa6ae5d6706bea7b896ade0268032
+DIST menulibre-2.2.3.tar.gz 488117 BLAKE2B 2bb157f6f8fb1af8c5059bfa2f93dbf99eb3a0cf9b3072cae28284d50c6a7d847da7a7dc5905ff59386f7d69029f7ffd7c39cb9137e029355fea2f52741283c6 SHA512 bd554606ad35cdd41272ed656427ae3f610d6aacfc9e91e4de6ed342034e1bb6070812017a1372d04b0df4008ae1cd7207ca243142a874b6abb0a00893740da3
+EBUILD menulibre-2.2.3.ebuild 1288 BLAKE2B a3e2b1dac107ad89a35177d1b71458cd879e3ec3f555e2bb8365e7c8836c222dcc65b3b23046a97b26c2a82517c36c0c9258419d2c7657b8ff73c0669d461984 SHA512 dc3620e7a1292f4a4d83ab3fee7c6be7ce373e56caa9fce05d16087722ccded183a3e66c63a6010ba6612b2008c7bcd64a85aaa59bde19da42653574dab251e1
+MISC metadata.xml 276 BLAKE2B 5ae33ec24b361408186426738ecfc12a6a3ae761e023050d59a02b6bdf5f4dd788ac33ef6c9ff0c0c27e415fb369aa3cf8118bdc6268d95c3a33e75a5341140e SHA512 f186b9f746afb87c00b913f67250ed8a6f9563df447b2caab6717b212c7a8e09ae78b7dcce76bf4acdff238ff12d1faf3b997991a38ba34beae17f734b37b060
diff --git a/x11-misc/menulibre/menulibre-2.2.1-r2.ebuild b/x11-misc/menulibre/menulibre-2.2.1-r2.ebuild
deleted file mode 100644
index 1cd6aaa6ce46..000000000000
--- a/x11-misc/menulibre/menulibre-2.2.1-r2.ebuild
+++ /dev/null
@@ -1,68 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7..9} )
-PYTHON_REQ_USE="xml"
-DISTUTILS_IN_SOURCE_BUILD=1
-inherit distutils-r1 xdg-utils
-
-DESCRIPTION="Advanced freedesktop.org compliant menu editor"
-HOMEPAGE="https://bluesabre.org/menulibre/"
-SRC_URI="https://launchpad.net/${PN}/$(ver_cut 1-2)/${PV}/+download/${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="amd64 x86"
-
-DEPEND="
-	dev-python/python-distutils-extra[${PYTHON_USEDEP}]
-"
-RDEPEND="
-	dev-libs/gobject-introspection
-	dev-python/psutil[${PYTHON_USEDEP}]
-	dev-python/pygobject:3[${PYTHON_USEDEP}]
-	dev-python/pyxdg[${PYTHON_USEDEP}]
-	gnome-base/gnome-menus[introspection]
-	x11-libs/gdk-pixbuf-xlib
-	>=x11-libs/gdk-pixbuf-2.42.0:2[introspection]
-	x11-libs/gtk+:3[X,introspection]
-	x11-libs/gtksourceview:3.0[introspection]
-	x11-themes/hicolor-icon-theme
-"
-
-python_prepare_all() {
-	# too many categories
-	sed -i \
-		-e 's/X-GNOME-Settings-Panel;X-GNOME-PersonalSettings;DesktopSettings;X-XFCE;//' \
-		-e '/^OnlyShowIn/d' \
-		menulibre.desktop.in || die
-
-	local i
-	# fix incorrect behavior when LINGUAS is set to an empty string
-	# https://bugs.launchpad.net/python-distutils-extra/+bug/1133594
-	if [[ -n "${LINGUAS+x}" ]] ; then # if LINGUAS is set
-		for i in $(cd "${S}"/po ; for p in *.po ; do echo ${p%.po} ; done) ; do # for every supported language
-			if ! has ${i} ${LINGUAS} ; then # if language is disabled
-				rm po/${i}.po || die
-			fi
-		done
-	fi
-
-	distutils-r1_python_prepare_all
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	python_optimize
-	rm -r "${ED}"/usr/share/doc/${PN} || die
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-}
diff --git a/x11-misc/menulibre/menulibre-2.2.3.ebuild b/x11-misc/menulibre/menulibre-2.2.3.ebuild
new file mode 100644
index 000000000000..6f10b016ac78
--- /dev/null
+++ b/x11-misc/menulibre/menulibre-2.2.3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml(+)"
+inherit distutils-r1 xdg
+
+DESCRIPTION="Advanced freedesktop.org compliant menu editor"
+HOMEPAGE="https://bluesabre.org/menulibre/"
+SRC_URI="https://github.com/bluesabre/menulibre/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]')
+	gnome-base/gnome-menus:3[introspection]
+	x11-libs/gdk-pixbuf:2[introspection]
+	x11-libs/gtk+:3[introspection]
+	x11-themes/hicolor-icon-theme"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/python-distutils-extra[${PYTHON_USEDEP}]')"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# show desktop entry in all DEs
+	sed -i '/^OnlyShowIn/d' menulibre.desktop.in || die
+
+	# workaround incorrect behavior when LINGUAS is set to an empty string
+	# https://bugs.launchpad.net/python-distutils-extra/+bug/1133594
+	! [[ -v LINGUAS && -z ${LINGUAS} ]] || rm po/*.po || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/share/doc/${PN} || die
+}
diff --git a/x11-misc/menulibre/metadata.xml b/x11-misc/menulibre/metadata.xml
index 4079a9f1f642..dad0ffbbf1e1 100644
--- a/x11-misc/menulibre/metadata.xml
+++ b/x11-misc/menulibre/metadata.xml
@@ -2,7 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<!-- maintainer-needed -->
+	<stabilize-allarches/>
 	<upstream>
-		<remote-id type="launchpad">menulibre</remote-id>
+		<remote-id type="github">bluesabre/menulibre</remote-id>
 	</upstream>
 </pkgmetadata>