blob: e9cc621afd8c34e729bd1f150b35def7c2401811 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 2024-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=maturin
DISTUTILS_OPTIONAL=1
PYTHON_COMPAT=( python3_{10..12} )
CRATES=""
inherit cargo distutils-r1
DESCRIPTION="A malware identification and classification tool"
HOMEPAGE="https://virustotal.github.io/yara-x/"
SRC_URI="https://github.com/VirusTotal/yara-x/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" https://github.com/gentoo-crate-dist/${PN}/releases/download/v${PV}/${PN}-v${PV}-crates.tar.xz"
LICENSE="BSD"
# Dependent crate licenses
LICENSE+="
Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD Boost-1.0
CC0-1.0 CDDL EPL-2.0 ISC MIT MPL-2.0 Unicode-DFS-2016 WTFPL-2
"
SLOT="0"
# Note: cranelift dependency only supports amd64, arm64, s390, and riscv64 as of 2025
KEYWORDS="amd64"
IUSE="python"
REQUIRED_USE="
python? ( ${PYTHON_REQUIRED_USE} )
"
RDEPEND="
python? ( ${PYTHON_DEPS} )
"
BDEPEND="
python? (
${PYTHON_DEPS}
${DISTUTILS_DEPS}
)
"
wrap_python() {
local phase=$1
shift
if use python; then
pushd py >/dev/null || die
distutils-r1_${phase} "$@"
popd >/dev/null || die
fi
}
src_prepare() {
default
wrap_python ${FUNCNAME}
}
src_compile() {
cargo_src_compile --workspace
wrap_python ${FUNCNAME}
}
python_test() {
epytest
}
src_test() {
cargo_src_test
wrap_python ${FUNCNAME}
}
src_install() {
dobin "$(cargo_target_dir)"/yr
dolib.so "$(cargo_target_dir)"/*.so
wrap_python ${FUNCNAME}
}
|
