blob: 859bcaad2a9bed37de8fb548c6a9ba7a13c2c310 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake desktop xdg
MY_PV="${PV/_/}"
DESCRIPTION="Free cross-platform LaTeX editor (fork from texmakerX)"
HOMEPAGE="https://www.texstudio.org https://github.com/texstudio-org/texstudio"
SRC_URI="https://github.com/texstudio-org/texstudio/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-${MY_PV}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
DEPEND="
app-text/hunspell:=
app-text/poppler:=[qt6]
>=dev-libs/quazip-1.0:0=[qt6(+)]
dev-qt/qt5compat:6
dev-qt/qtbase:6[concurrent,gui,network,widgets,xml]
dev-qt/qtdeclarative:6
dev-qt/qtmultimedia:6
dev-qt/qtsvg:6
dev-qt/qttools:6[widgets]
sys-libs/zlib
x11-libs/libX11
"
RDEPEND="
${DEPEND}
app-text/ghostscript-gpl
app-text/psutils
media-libs/netpbm
virtual/latex-base
"
BDEPEND="
dev-qt/qttools:6[linguist]
virtual/pkgconfig
"
src_prepare() {
local dir
for dir in src/quazip src/hunspell utilities/poppler-data; do
rm -r "${dir}" || die "Failed to delete ${dir}"
done
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DQT_VERSION_MAJOR=6
)
cmake_src_configure
}
src_install() {
cmake_src_install
local i
for i in 16x16 22x22 32x32 48x48 64x64 128x128; do
newicon -s ${i} utilities/${PN}${i}.png ${PN}.png
done
}
|
