blob: 2bd2a8f42353b381e2777902d8249db234b535db (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# EAPI=6 is blocked by Gentoo bugs 497038, 497052.
EAPI=5
inherit autotools epatch latex-package perl-functions sgml-catalog toolchain-funcs vcs-snapshot
DESCRIPTION="A toolset for processing LinuxDoc DTD SGML files"
HOMEPAGE="https://gitlab.com/agmartin/linuxdoc-tools"
SRC_URI="https://gitlab.com/agmartin/${PN}/repository/archive.tar.gz?ref=v${PV} -> ${P}.tar.gz"
LICENSE="GPL-3+ MIT SGMLUG"
SLOT="0"
KEYWORDS="amd64 ~ia64 ppc x86"
IUSE="doc"
RDEPEND="
|| ( app-text/openjade app-text/opensp )
app-text/sgml-common
dev-lang/perl:=
|| ( sys-apps/gawk sys-apps/mawk )
sys-apps/groff
"
DEPEND="${RDEPEND}
sys-devel/flex
doc? (
dev-texlive/texlive-fontsrecommended
virtual/latex-base
)
"
src_prepare() {
[[ ${PATCHES} ]] && epatch -p1 "${PATCHES[@]}"
epatch_user
# Update the build system with Gentoo paths.
sed -i \
-e "s|share/doc/${PN}|share/doc/${PF}|g" \
Makefile.in || die
eautoreconf
}
src_configure() {
perl_set_version
tc-export CC
local myeconfargs=(
--disable-docs
--with-texdir="${TEXMF}/tex/latex/${PN}"
--with-perllibdir="${VENDOR_ARCH}"
--with-installed-iso-entities
)
use doc && myeconfargs+=(--enable-docs="txt pdf html")
econf "${myeconfargs[@]}"
}
src_compile() {
# Prevent access violations from bitmap font files generation.
use doc && export VARTEXFONTS="${T}/fonts"
default_src_compile
}
src_install() {
# Override latex-package.eclass
default_src_install
}
sgml-catalog_cat_include "/etc/sgml/linuxdoc.cat" "/usr/share/${PN}/${PN}.catalog"
pkg_postinst() {
latex-package_pkg_postinst
sgml-catalog_pkg_postinst
}
pkg_postrm() {
latex-package_pkg_postrm
sgml-catalog_pkg_postrm
}
|