blob: 6e4bd1846cbe369b372f6f0d605e99dfabb7bede (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools latex-package perl-functions sgml-catalog-r1 toolchain-funcs
DESCRIPTION="A toolset for processing LinuxDoc DTD SGML files"
HOMEPAGE="https://gitlab.com/agmartin/linuxdoc-tools"
SRC_URI="https://gitlab.com/agmartin/linuxdoc-tools/-/archive/${PV}/${P}.tar.bz2"
LICENSE="GPL-3+ MIT SGMLUG"
SLOT="0"
KEYWORDS="amd64 ppc ~sparc x86"
IUSE="doc"
RDEPEND="
|| ( app-text/openjade app-text/opensp )
app-text/sgml-common
dev-lang/perl:=
sys-apps/groff
"
DEPEND="${RDEPEND}"
BDEPEND="
app-alternatives/awk
app-alternatives/lex
doc? (
dev-texlive/texlive-fontsrecommended
virtual/latex-base
)
"
PATCHES=(
"${FILESDIR}"/${PN}-0.9.82-configure-clang16.patch
)
src_prepare() {
default
# Pregenerated configure scripts fail.
eautoreconf
}
src_configure() {
perl_set_version
tc-export CC
local myeconfargs=(
--disable-docs
--with-texdir="${TEXMF}/tex/latex/${PN}"
--with-perllibdir="${VENDOR_ARCH}"
--with-installed-iso-entities
)
use doc && myeconfargs+=(--enable-docs="txt pdf html")
econf "${myeconfargs[@]}"
}
src_compile() {
# Prevent access violations from bitmap font files generation.
use doc && export VARTEXFONTS="${T}/fonts"
default
}
src_install() {
# Makefile ignores docdir configuration option.
emake DESTDIR="${D}" docdir="${EPREFIX}/usr/share/doc/${PF}" install
dodoc ChangeLog README
insinto /etc/sgml
newins - linuxdoc.cat <<-EOF
CATALOG "${EPREFIX}/usr/share/linuxdoc-tools/linuxdoc-tools.catalog"
EOF
}
pkg_preinst() {
# work around sgml-catalog.eclass removing it
cp "${ED}"/etc/sgml/linuxdoc.cat "${T}" || die
}
pkg_postinst() {
local backup=${T}/linuxdoc.cat
local real=${EROOT}/etc/sgml/linuxdoc.cat
if ! cmp -s "${backup}" "${real}"; then
cp "${backup}" "${real}" || die
fi
latex-package_pkg_postinst
sgml-catalog-r1_pkg_postinst
}
pkg_postrm() {
latex-package_pkg_postrm
sgml-catalog-r1_pkg_postrm
}
|
