blob: 118401efebb8903c103adfb9cef359f1d941285a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
inherit autotools elisp-common
MY_P="${P/_pre/pre}"
DESCRIPTION="Namazu is a full-text search engine"
HOMEPAGE="http://www.namazu.org/"
SRC_URI="http://www.namazu.org/test/${MY_P}.tar.gz"
S="${WORKDIR}"/${MY_P}
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS=""
IUSE="emacs l10n_ja nls static-libs tk"
RDEPEND="dev-perl/File-MMagic
emacs? ( >=app-editors/emacs-23.1:* )
l10n_ja? (
app-i18n/nkf
|| (
dev-perl/Text-Kakasi
app-i18n/kakasi
app-text/chasen
app-text/mecab
)
)
nls? ( virtual/libintl )
tk? (
dev-lang/tk:0
www-client/lynx
)"
DEPEND="${RDEPEND}"
BDEPEND="nls? ( sys-devel/gettext )"
PATCHES=(
"${FILESDIR}"/${PN}-gentoo.patch
"${FILESDIR}"/${PN}-configure.patch
"${FILESDIR}"/${PN}-tests.patch
"${FILESDIR}"/${PN}-underlinking.patch
)
src_prepare() {
default
mv configure.{in,ac} || die
mv tk${PN}/configure.{in,ac} || die
eautoreconf
}
src_configure() {
local myconf=(
$(use_enable nls)
$(use_enable static-libs static)
$(use_enable tk tk${PN})
)
use tk && myconf+=(
--with-${PN}="${EPREFIX}"/usr/bin/${PN}
--with-mknmz="${EPREFIX}"/usr/bin/mknmz
--with-indexdir="${EPREFIX}"/var/lib/${PN}/index
)
econf "${myconf[@]}"
}
src_compile() {
default
if use emacs; then
cd lisp
rm -f browse*
elisp-compile *.el
fi
}
src_install() {
default
find "${ED}" -name '*.la' -delete || die
keepdir /var/lib/${PN}/index
if use emacs; then
elisp-install ${PN} lisp/*.el*
elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el
docinto lisp
dodoc lisp/ChangeLog*
fi
}
pkg_postinst() {
use emacs && elisp-site-regen
}
pkg_postrm() {
use emacs && elisp-site-regen
}
|
